Web.pm

   1 # $Id$
   2 # Common functions for HTML/XHTML output generation
   3 # Copyright (C) 2003-2005 Jan Kratochvil <project-www.jankratochvil.net@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 package My::Web;
  20 require 5.6.0;  # at least 'use warnings;' but we need some 5.6.0+ modules anyway
  21 our $VERSION=do { my @r=(q$Revision$=~/\d+/g); sprintf "%d.".("%03d"x$#r),@r; };
  22 our $CVS_ID=q$Id$;
  23 use strict;
  24 use warnings;
  25
  26 use Exporter;
  27 sub Wrequire($);
  28 sub Wuse($@);
  29 our $W;
  30 our @EXPORT=qw(
  31                 &Wrequire &Wuse
  32                 &path_web &path_abs_disk
  33                 &uri_escaped
  34                 &a_href &a_href_cz
  35                 &vskip
  36                 &img &centerimg &rightimg
  37                 $W
  38                 &input_hidden_persistents
  39                 );
  40 our @ISA=qw(Tie::Handle Exporter);
  41
  42 my %packages_used_hash;
  43 my %packages_used_array;
  44
  45 BEGIN
  46 {
  47         use Carp qw(cluck confess);
  48         $W->{"__My::Web_init"}=1;
  49
  50         sub Wrequire ($)
  51         {
  52         my($file)=@_;
  53
  54 #               print STDERR "Wrequire $file\n";
  55                 $file=~s#/#::#g;
  56                 $file=~s/[.]pm$//;
  57                 my $class=$file;
  58                 $file=~s#::#/#g;
  59                 $file.=".pm";
  60                 my %callers;
  61                 for (my $depth=0;defined caller($depth);$depth++) {
  62                         $callers{caller($depth)}=1;
  63                         }
  64                 my $selfpkg=__PACKAGE__;
  65                 $callers{$selfpkg}=1;
  66                 for my $target ($class,__PACKAGE__) {
  67                         for my $caller (keys(%callers)) {
  68                                 next if $caller eq $target;
  69                                 next if $packages_used_hash{$caller}{$target}++;
  70                                 push @{$packages_used_array{$caller}},$target;
  71                                 }
  72                         }
  73                 eval { CORE::require "$file"; } or confess $@;
  74                 1;      # Otherwise 'require' would already file above.
  75         }
  76
  77         sub Wuse ($@)
  78         {
  79         my($file,@list)=@_;
  80
  81 #               print STDERR "Wuse $file\n";
  82                 Wrequire $file;
  83                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  84                 $file->import(@list);
  85                 1;
  86         }
  87
  88         sub import
  89         {
  90         my($class,@rest)=@_;
  91
  92                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  93                 Wrequire("$class");
  94                 return $class->SUPER::import(@rest);
  95         }
  96 }
  97
  98 use WebConfig;  # see also below: Wuse 'WebConfig';
  99 require CGI;    # for &escapeHTML
 100 require Image::Size;    # for &imgsize
 101 use File::Basename;     # &basename
 102 use Carp qw(cluck confess);
 103 use URI::Escape;
 104 require HTTP::BrowserDetect;
 105 require HTTP::Negotiate;
 106 my $have_Geo_IP; BEGIN { $have_Geo_IP=eval { require Geo::IP; 1; }; }
 107 # Do not: use ModPerl::Util qw(exit);
 108 # to prevent in mod_perl2: "exit" is not exported by the ModPerl::Util module
 109 # I do not know why.
 110 use POSIX qw(strftime);
 111 use Tie::Handle;
 112 use Apache2::Const qw(HTTP_MOVED_TEMPORARILY OK);
 113 use URI;
 114 use URI::QueryParam;
 115 use Cwd;
 116
 117
 118 #our $W;
 119                 # $W->{"title"}
 120                 # $W->{"head"}
 121                 # $W->{"force_charset"}
 122                 # $W->{"heading_done"}
 123                 # $W->{"footer_passed"}
 124                 # %{$W->{"headers"}}
 125                 # %{$W->{"headers_lc"}} # maps lc($headers_key)=>$headers_key
 126                 # %{$W->{"args"}}
 127
 128 sub cleanup($)
 129 {
 130 my($apache_request)=@_;
 131
 132         # Sanity protection.
 133         $W=undef();
 134         return OK;
 135 }
 136
 137 sub init ($%)
 138 {
 139 my($class,%args)=@_;
 140
 141         print STDERR "$class->init ".Apache2::RequestUtil->request()->unparsed_uri()."\n";
 142
 143         # We need to track package dependencies, so we need to call it from &init.
 144         # We cannot do it in BEGIN { } block
 145         # as it would not be tracked for each of the toplevel users later.
 146         Wuse 'WebConfig';
 147         Wrequire 'My::Hash::Sub';
 148
 149         $W={};
 150         tie %$W,"My::Hash::Sub";
 151         %$W=(%WebConfig,%args); # override %WebConfig settings
 152         $W->{"__PACKAGE__"}||=caller();
 153
 154         # {"__PACKAGE__"} is mandatory for mod_perl-2.0;
 155         # $Apache2::Registry::curstash is no longer supported.
 156         do { cluck "No $_" if !$W->{$_}; } for "__PACKAGE__";
 157
 158         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_ent");
 159         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_js");
 160         do { $W->{$_}=1  if !defined $W->{$_}; } for ("have_css");      # AFAIK it does not hurt anyone.
 161         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer");
 162         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_delimit");
 163         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_ids");
 164         do { $W->{$_}=1  if !defined $W->{$_}; } for ("indexme");
 165         do { $W->{$_}="" if !defined $W->{$_}; } for ("head");
 166         do { $W->{$_}="" if !defined $W->{$_}; } for ("body_attr");
 167         do { $W->{$_}="en-US" if !defined $W->{$_}; } for ("language");
 168
 169         my $footer_any=0;
 170         for (qw(footer_ids)) {
 171                 $W->{$_}=0 if !$W->{"footer"};
 172                 $footer_any=1 if $W->{$_};
 173                 }
 174         $W->{"footer"}=0 if !$footer_any;
 175         $W->{"footer_delimit"}=0 if !$W->{"footer"};
 176
 177         $W->{"r"}=Apache2::RequestUtil->request();
 178
 179         $W->{"r"}->push_handlers("PerlCleanupHandler"=>\&cleanup);
 180
 181         $W->{"web_hostname"}||=$W->{"r"}->hostname();
 182
 183         tie *STDOUT,$W->{"r"};
 184         select *STDOUT;
 185         $|=1;
 186
 187         $W->{"QUERY_STRING"}=$W->{"r"}->args() || "";
 188         if ($W->{"detect_ent"}) {
 189                          if ($W->{"QUERY_STRING"}=~/[&]amp;have_ent/)
 190                         { $W->{"have_ent"}=0; }
 191                 elsif ($W->{"QUERY_STRING"}=~    /[&]have_ent/)
 192                         { $W->{"have_ent"}=1; }
 193                 else
 194                         { delete $W->{"have_ent"}; }
 195                 if (!defined $W->{"have_ent"} && $W->{"r"}->method() eq "GET") {
 196                         $W->{"head"}.='<meta http-equiv="Refresh" content="0; URL='
 197                                         .escapeHTML("http://".$W->{"web_hostname"}."/".($W->{"r"}->uri()=~m#^/*(.*)$#)[0]
 198                                                         ."?".($W->{"QUERY_STRING"} || "detect_ent_glue=1").'&have_ent=detect')
 199                                         .'" />'."\n";
 200                         }
 201                 }
 202         $W->{"QUERY_STRING"}=~s/([&])amp;/$1/g;
 203         $W->{"r"}->args($W->{"QUERY_STRING"});
 204         # Workaround: &CGI::Vars behaves weird if strings passed both as POST data and in: $QUERY_STRING
 205         do { $W->{"r"}->args(""); delete $ENV{"QUERY_STRING"}; } if $W->{"r"}->method() eq "POST";
 206         # Do not: $W->{"r"}->args()
 207         # as it parses only QUERY_STRING (not POST data).
 208         $W->{"args"}={ CGI->new($W->{"r"})->Vars() };
 209         for my $name (keys(%{$W->{"args"}})) {
 210                 my @vals=split /\x00/,$W->{"args"}{$name};
 211                 next if @vals<=1;
 212                 $W->{"args"}{$name}=[@vals];
 213                 }
 214
 215         do { $W->{$_}=$W->{"r"}->headers_in()->{"Accept"}         if !defined $W->{$_}; } for ("accept");
 216         do { $W->{$_}=$W->{"r"}->headers_in()->{"User-Agent"}||"" if !defined $W->{$_}; } for ("user_agent");
 217
 218         $W->{"browser"}=HTTP::BrowserDetect->new($W->{"user_agent"});
 219
 220         if (!defined $W->{"have_style"}) {
 221                 $W->{"have_style"}=(!$W->{"browser"}->netscape() || ($W->{"browser"}->major() && $W->{"browser"}->major()>4) ? 1 : 0);
 222                 }
 223
 224         $W->{"have_js"}=($W->{"args"}{"have_js"} ? 1 : 0);
 225         if ($W->{"detect_js"} && !$W->{"have_js"}) {
 226                 $W->{"head"}.='<script type="text/javascript" src="'.path_web('/have_js.pm').'"></script>'."\n";
 227                 }
 228
 229         do { args_check(%$_) if $_; } for ($W->{"args_check"});
 230
 231         return bless $W,$class;
 232 }
 233
 234 # Although we have &tie-d *STDOUT we try to not to be dependent on it in My::Web itself.
 235 # Do not: Wprint $W->{"heading"},"undef"=>1;
 236 # as we would need to undef() it to turn it off and it would get defaulted in such case.
 237 # Do not: exists $W->{"heading"}
 238 # as we use a lot of 'for $W->{"heading"}' which instantiates it with the value: undef()
 239 sub Wprint($%)
 240 {
 241 my($text,%args)=@_;
 242
 243         cluck "undef Wprint" if !defined $text && !$args{"undef"};
 244         delete $args{"undef"};
 245         cluck join(" ","Invalid arguments:",keys(%args)) if keys(%args);
 246         $W->{"r"}->puts($text) if defined $text;
 247 }
 248
 249 sub escapeHTML($)
 250 {
 251 my($text)=@_;
 252
 253         # Use &eval to prevent: Global $r object is not available. Set:\n\tPerlOptions +GlobalRequest\nin ...
 254         # CGI requires valid "r": check it beforehand here.
 255         confess "Calling dynamic URL generator from a static code" if !eval { Apache2::RequestUtil->request(); };
 256         return CGI::escapeHTML($text);
 257 }
 258
 259 # local *FH;
 260 # tie *FH,ref($W),$W;
 261 sub TIEHANDLE($)
 262 {
 263 my($class,$W)=@_;
 264
 265         my $self={};
 266         $self->{"W"}=$W or confess "Missing W";
 267         return bless $self,$class;
 268 }
 269
 270 sub WRITE
 271 {
 272 my($self,$scalar,$length,$offset)=@_;
 273
 274         Wprint substr($scalar,0,$length);
 275 }
 276
 277 # /home/user/www/webdir
 278 sub dir_top_abs_disk()
 279 {
 280         our $dir_top_abs_disk;
 281         if (!$dir_top_abs_disk) {
 282                 my $selfpkg_relpath=__PACKAGE__;
 283                 $selfpkg_relpath=~s{::}{/}g;
 284                 $selfpkg_relpath.=".pm";
 285                 my $selfpkg_abspath=$INC{$selfpkg_relpath} or do {
 286                         cluck "Unable to find self package $selfpkg_relpath";
 287                         return;
 288                         };
 289                 $selfpkg_abspath=~s{/*\Q$selfpkg_relpath\E$}{} or do {
 290                         cluck "Unable to strip myself \"$selfpkg_relpath\" from the abspath: $selfpkg_abspath";
 291                         return;
 292                         };
 293                 cluck "INC{myself} is relative?: $selfpkg_abspath" if $selfpkg_abspath!~m{^/};
 294                 $dir_top_abs_disk=$selfpkg_abspath;
 295                 }
 296         return $dir_top_abs_disk;
 297 }
 298
 299 sub unparsed_uri()
 300 {
 301         if (!$W->{"unparsed_uri"}) {
 302                 # Do not: $W->{"r"}
 303                 # as we may be called before &init from: &My::Project::init
 304                 my $r=Apache2::RequestUtil->request();
 305                 cluck "Calling ".'&unparsed_uri'." from a static code, going to fail" if !$r;
 306                 my $uri_string=$r->unparsed_uri() or cluck "Valid 'r' missing unparsed_uri()?";
 307                 my $uri=URI->new_abs($uri_string,"http://".$W->{"web_hostname"}."/");
 308                 $W->{"unparsed_uri"}=$uri;
 309                 }
 310         return $W->{"unparsed_uri"};
 311 }
 312
 313 sub in_to_uri_abs($)
 314 {
 315 my($in)=@_;
 316
 317         # Otherwise we may have been already processed and thus legally relativized.
 318         # FIXME data: Currently disabled, all the data are too violating such rule.
 319         if (0 && !ref $in) {
 320                 my $uri_check=URI->new($in);
 321                 $uri_check->scheme() || $in=~m{^\Q./\E} || $in=~m{^/}
 322                                 or cluck "Use './' or '/' prefix for all the local references: $in";
 323                 }
 324         my $uri=URI->new_abs($in,unparsed_uri());
 325         $uri=$uri->canonical();
 326         return $uri;
 327 }
 328
 329 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 330 # $args{"abs"}=1;
 331 sub path_web($%)
 332 {
 333 my($in,%args)=@_;
 334
 335         cluck if !$args{"uri_as_in"} && ref $in;
 336         my $uri=in_to_uri_abs($in);
 337         if (uri_is_local($uri)) {
 338                 # Prefer the $uri values over "args_persistent" values.
 339                 $uri->query_form_hash({
 340                                 map({
 341                                         my $key=$_;
 342                                         my $val=$W->{"args"}{$key};
 343                                         (!defined $val ? () : ($key=>$val));
 344                                         } keys(%{$W->{"args_persistent"}})),
 345                                 %{$uri->query_form_hash()},
 346                                 });
 347                 }
 348         return $uri->abs(unparsed_uri()) if $W->{"args"}{"Wabs"} || $args{"abs"};
 349         return $uri->rel(unparsed_uri());
 350 }
 351
 352 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 353 sub path_abs_disk($%)
 354 {
 355 my($in,%args)=@_;
 356
 357         cluck if !$args{"uri_as_in"} && ref $in;
 358         my $uri=in_to_uri_abs($in);
 359         cluck if !uri_is_local($uri);
 360         my $path=$uri->path();
 361         cluck "URI compatibility: ->path() not w/leading slash of URI \"$uri\"; path: $path" if $path!~m{^/};
 362         return dir_top_abs_disk().$path;
 363 }
 364
 365 sub fatal (;$);
 366
 367 sub args_check (%)
 368 {
 369 my(%tmpl)=@_;
 370
 371         while (my($name,$regex)=each(%tmpl)) {
 372                 my $name_html="Parameter <span class=\"quote\">".escapeHTML($name)."</span>";
 373                 $W->{"args"}{$name}="" if !defined $W->{"args"}{$name};
 374                 $W->{"args"}{$name}=[ $W->{"args"}{$name} ] if !ref $W->{"args"}{$name} && ref $regex;
 375                 fatal "$name_html passed as multivar although singlevar expected"
 376                                 if ref $W->{"args"}{$name} && !ref $regex;
 377                 $regex=$regex->[0] if ref $regex;
 378                 for my $val (!ref $W->{"args"}{$name} ? $W->{"args"}{$name} : @{$W->{"args"}{$name}}) {
 379                         $val="" if !defined $val;
 380                         fatal "$name_html <span class=\"quote\">".escapeHTML($val)."</span>"
 381                                                         ." does not match the required regex <span class=\"quote\">".escapeHTML($regex)."</span> "
 382                                         if $regex ne "" && $val!~/$regex/;
 383                         }
 384                 }
 385 }
 386
 387 sub vskip (;$)
 388 {
 389 my($height)=@_;
 390
 391         return '<p'.(!defined $height ? "" : ' style="height: '.$height.';"').'>&nbsp;</p>'."\n";
 392 }
 393
 394 sub fatal (;$)
 395 {
 396 my($msg)=@_;
 397
 398         $msg="UNKNOWN" if !$msg;
 399         cluck "FATAL: $msg";
 400
 401         # Do not send it unconditionally.
 402         # The intial duplicated '<?xml...' crashes Gecko parser.
 403         $W->{"heading_done"}=0 if $W->{"header_only"};
 404         # Do not send it unconditionally.
 405         # Prevents warn: Headers already sent
 406         if (!$W->{"heading_done"}) {
 407                 $W->{"indexme"}=0;      # For the case no heading was sent yet.
 408                 $W->{"header_only"}=0;  # assurance for &heading
 409                 My::Web->heading();
 410                 }
 411         Wprint "\n".vskip("3ex")."<hr /><h1 class=\"error\">FATAL ERROR: $msg!</h1>\n"
 412                         ."<p>You can report this problem's details to"
 413                         ." ".a_href("mailto:".$W->{"admin_mail"},"admin of this website").".</p>\n";
 414         footer();
 415 }
 416
 417 sub footer (;$)
 418 {
 419         exit 1 if $W->{"footer_passed"}++;      # deadlock prevention:
 420
 421         Wprint vskip if $W->{"footer_delimit"};
 422
 423         do { Wprint $_ if $_; } for $W->{"footing_delimit"};
 424
 425         Wprint "<hr />\n" if $W->{"footer"};
 426
 427         my $packages_used=$packages_used_array{$W->{"__PACKAGE__"}};
 428
 429         if ($W->{"footer_ids"}) {
 430                 Wprint '<p class="cvs-id">';
 431                 Wprint join("<br />\n",map({ my $package=$_;
 432                         my $cvs_id=(eval('$'.$package."::CVS_ID")
 433 #                                       || $package     # debug
 434                                         );
 435                         if (!$cvs_id) {
 436                                 ();
 437                                 }
 438                         else {
 439                                 $cvs_id='$'.$cvs_id.'$';        # Eaten by 'q' operator.
 440                                 my @cvs_id_split=split / +/,$cvs_id;
 441                                 if (@cvs_id_split==8) {
 442                                         my $file=$package;
 443                                         $file=~s#::#/#g;
 444                                         my $ext;
 445                                         my @tried;
 446                                         for (qw(.pm)) {
 447                                                 $ext=$_;
 448                                                 my $path_abs_disk=path_abs_disk("/$file$ext");
 449                                                 push @tried,$path_abs_disk;
 450                                                 last if -r $path_abs_disk;
 451                                                 cluck "Class file $file not found; tried: ".join(" ",@tried) if !$ext;
 452                                                 }
 453                                         $file.=$ext;
 454                                         $cvs_id_split[2]=""
 455                                                         .a_href((map({ my $s=$_; $s=~s#/viewcvs/#$&~checkout~/#; $s; } $W->{"viewcvs"}))[0]."$file?rev=".$cvs_id_split[2],
 456                                                                         $cvs_id_split[2]);
 457                                         $cvs_id_split[1]=a_href($W->{"viewcvs"}.$file,
 458                                                         ($package!~/^Apache2::/ ? $package : $cvs_id_split[1]));
 459                                         $cvs_id_split[5]=&{$W->{"cvs_id_author_sub"}}($cvs_id_split[5]);
 460                                         }
 461                                 join " ",@cvs_id_split;
 462                                 }
 463                         } @$packages_used));
 464                 Wprint "</p>\n";
 465                 }
 466
 467         for my $package (@$packages_used) {
 468                 my $cvs_id=(eval('$'.$package."::CVS_ID")
 469 #                               || $package     # debug
 470                                 );
 471                 Wprint '<!-- '.$package.' - $'.$cvs_id.'$ -->'."\n" if $cvs_id;
 472                 }
 473
 474         do { Wprint $_ if $_; } for $W->{"footing"};
 475
 476         Wprint "</body></html>\n";
 477         exit 0;
 478 }
 479
 480 sub header (%)
 481 {
 482 my(%pairs)=@_;
 483
 484         while (my($key,$val)=each(%pairs)) {
 485                 do { cluck "Headers already sent"; next; } if $W->{"heading_done"};
 486                 for ($W->{"headers_lc"}{lc $key} || ()) {
 487                         delete $W->{"headers"}{$_};
 488                         }
 489                 $W->{"headers_lc"}{lc $key}=$key;
 490                 $W->{"headers"}{$key}=$val;
 491                 }
 492 }
 493
 494 sub size_display ($)
 495 {
 496 my($size)=@_;
 497
 498            if ($size<4096)
 499                 {}
 500         elsif ($size<1024*1024)
 501                 { $size=sprintf "%.1fK",$size/1024; }
 502         else
 503                 { $size=sprintf "%.1fM",$size/1024/1024; }
 504         $size.="B";
 505         return $size;
 506 }
 507
 508 sub uri_is_local($)
 509 {
 510 my($in)=@_;
 511
 512         my $uri_rel=in_to_uri_abs($in)->rel(unparsed_uri());
 513         # Do not: defined $uri_rel->("userinfo"|"host"|"port")();
 514         # as they fail to be called for schemes not supporting them.
 515         return 0 if $uri_rel->scheme();
 516         return 0 if $uri_rel->authority();
 517         return 1;
 518 }
 519
 520 # &path_web still may be required for &uri_escaped !
 521 sub uri_escaped($)
 522 {
 523 my($uri)=@_;
 524
 525         cluck if !ref $uri;
 526         my $urient=escapeHTML($uri);
 527         return $uri    if $uri eq $urient;
 528         return $urient if uri_is_local $uri;
 529         return $uri    if defined $W->{"have_ent"} && !$W->{"have_ent"};        # non-ent client
 530         return $urient if $W->{"have_ent"};     # ent client
 531         # Unknown client, &escapeHTML should not be needed here:
 532         return escapeHTML(path_web('/Redirect.pm?location='.uri_escape($uri->abs(unparsed_uri()))));
 533 }
 534
 535 our $a_href_inhibited;
 536 sub a_href($;$%)
 537 {
 538 my($in,$contents,%args)=@_;
 539
 540         do { $$_=1 if !defined $$_; } for (\$args{"size"});
 541         if (!defined $contents) {
 542                 $contents=$in;
 543                 $contents=File::Basename::basename($contents) if $args{"basename"};
 544                 $contents=escapeHTML($contents);
 545                 }
 546         $contents=~s#<a\b[^>]*>##gi;
 547         $contents=~s#</a>##gi;
 548         return $contents if $a_href_inhibited;
 549
 550         my $path_web=path_web $in,%args;
 551         my $r="";
 552         $r.='<a href="';
 553         $r.=uri_escaped $path_web;
 554         $r.='"';
 555         do { $r.=" $_" if $_; } for ($args{"attr"});
 556         $r.='>'.$contents.'</a>';
 557         if ($args{"size"} && uri_is_local($in) && ($args{"size"}>=2 || $in=~/[.](?:gz|Z|rpm|zip|deb|lha)/)) {   # Downloadable?
 558                 my $path_abs_disk=path_abs_disk $in,%args;
 559                 cluck "File not readable: $path_abs_disk" if !-r $path_abs_disk;
 560                 $r.='&nbsp;('.size_display((stat($path_abs_disk))[7]).')';
 561                 }
 562         return $r;
 563 }
 564
 565 sub a_href_inhibit($$;@)
 566 {
 567 my($self,$sub,@sub_args)=@_;
 568
 569         local $a_href_inhibited=1;
 570         return &{$sub}(@sub_args);
 571 }
 572
 573 sub input_hidden_persistents()
 574 {
 575         return join("",map({
 576                 my $key=$_;
 577                 my $val=$W->{"args"}{$key};
 578                 (!defined $val ? () : '<input type="hidden"'
 579                                 .' name="'.escapeHTML($key).'"'
 580                                 .' value="'.escapeHTML($val).'"'
 581                                 .' />'."\n");
 582                 } (keys(%{$W->{"args_persistent"}}))));
 583 }
 584
 585 sub http_moved($$;$)
 586 {
 587 my($self,$url,$status)=@_;
 588
 589         $url=path_web($url,"abs"=>1);
 590         $status||=HTTP_MOVED_TEMPORARILY;
 591         $W->{"r"}->status($status);
 592         $W->{"r"}->headers_out()->{"Location"}=$url;
 593         $W->{"header_only"}=1;
 594         My::Web->heading();
 595         exit;
 596         die "NOTREACHED";
 597 }
 598
 599 sub remote_ip ()
 600 {
 601         # Do not: PerlModule                 Apache2::ForwardedFor
 602         #         PerlPostReadRequestHandler Apache2::ForwardedFor
 603         # As 'Apache2::ForwardedFor' takes the first of $ENV{"HTTP_X_FORWARDED_FOR"}
 604         # while the contents is '127.0.0.1, 213.220.195.171' if client has its own proxy.
 605         # We must take the last item ourselves.
 606         my $r=$W->{"r"}->headers_in()->{"X-Forwarded-For"} || $W->{"r"}->get_remote_host();
 607         $r=~s/^.*,\s*//;
 608         return $r;
 609 }
 610
 611 sub is_cz ()
 612 {
 613         return 0 if !$have_Geo_IP;
 614         return "CZ" eq Geo::IP->new()->country_code_by_addr(remote_ip());
 615 }
 616
 617 sub a_href_cz ($$;%)
 618 {
 619 my($url,$contents,%args)=@_;
 620
 621         return a_href $url,$contents,%args if is_cz();
 622         return $contents;
 623 }
 624
 625 sub make ($)
 626 {
 627 my($cmd)=@_;
 628
 629         # FIXME: &alarm, --timeout is now infinite.
 630         # FIXME: Try to remove bash(1).
 631         # FIXME: Use: @PATH_FLOCK@
 632         my @argv=('flock',dir_top_abs_disk(),'bash','-c',$cmd.' >&2');
 633         print STDERR join(" ","SPAWN:",@argv)."\n";
 634         system @argv;
 635 }
 636
 637 sub make_file($$)
 638 {
 639 my($self,$file)=@_;
 640
 641         cluck "Pathname not absolute: $file" if $file!~m{^/};
 642         return if -f $file;
 643         # TODO: Somehow quickly check dependencies?
 644         return make('make -s --no-print-directory'
 645                                         .' -C '."'".File::Basename::dirname($file)."' '".File::Basename::basename($file)."'");
 646 }
 647
 648 sub img_size ($$)
 649 {
 650 my($width,$height)=@_;
 651
 652         cluck if !defined $width || !defined $height;
 653         return ($W->{"have_style"} ? "style=\"border:0;width:${width}px;height:${height}px\"" : "border=\"0\"")
 654                         ." width=\"$width\" height=\"$height\"";
 655 }
 656
 657 sub negotiate_variant (%)
 658 {
 659 my(%args)=@_;
 660
 661         my @fields=("id","qs","content-type","encoding","charset","lang","size");
 662         return [ map(($args{$_}),@fields) ];
 663 }
 664
 665 # Input: $self is required!
 666 # Input: Put the fallback variant as the first one.
 667 # Returns: always only scalar!
 668 sub Negotiate_choose($$)
 669 {
 670 my($self,$variants)=@_;
 671
 672         my $best=HTTP::Negotiate::choose($variants,
 673                         # Do not: $W->{"r"}
 674                         # to prevent: Can't locate object method "scan" via package "Apache2::RequestRec" at HTTP/Negotiate.pm line 84.
 675                         # Do not: $W->{"r"}->headers_in()
 676                         # to prevent: Can't locate object method "scan" via package "APR::Table" at HTTP/Negotiate.pm line 84.
 677                         # Do not: HTTP::Headers->new($W->{"r"}->headers_in());
 678                         # to prevent empty result or even: Odd number of elements in anonymous hash
 679                         HTTP::Headers->new(%{$W->{"r"}->headers_in()}));
 680         $best||=$variants->[0][0];      # $variants->[0]{"id"}; &HTTP::Negotiate::choose failed?
 681         return $best;
 682 }
 683
 684 my @img_variants=(
 685                 { "id"=>"png","qs"=>0.9,"content-type"=>"image/png" },
 686                 { "id"=>"gif","qs"=>0.7,"content-type"=>"image/gif" },
 687                 );
 688 my $img_variants_re='[.](?:'.join('|',"jpeg",map(($_->{"id"}),@img_variants)).')$';
 689
 690 # Returns: ($path_web,$path_abs_disk)
 691 # URI path segments support ignored here. Where it is used? (';' path segment options)
 692 sub _img_src($%)
 693 {
 694 my($in,%args)=@_;
 695
 696         cluck if !uri_is_local $in;
 697         my $uri=in_to_uri_abs $in;
 698         my $path_abs_disk=path_abs_disk $uri,%args,"uri_as_in"=>1;
 699
 700         # Known image extension?
 701         return path_web($uri,%args,"uri_as_in"=>1),$path_abs_disk if $uri->path()=~m#$img_variants_re#o;
 702
 703         my @nego_variants;
 704         for my $var (@img_variants) {
 705                 my $path_abs_disk_variant=$path_abs_disk.".".$var->{"id"};
 706                 __PACKAGE__->make_file($path_abs_disk_variant);
 707                 push @nego_variants,negotiate_variant(
 708                                 %$var,
 709                                 "size"=>(stat $path_abs_disk_variant)[7],
 710                                 );
 711                 }
 712         my $ext=__PACKAGE__->Negotiate_choose(\@nego_variants);
 713
 714         $uri->path($uri->path().".$ext");
 715         return path_web($uri,%args,"uri_as_in"=>1),path_abs_disk($uri,%args,"uri_as_in"=>1);
 716 }
 717
 718 # $args{"attr"}
 719 sub img ($$%)
 720 {
 721 my($in,$alt,%args)=@_;
 722
 723         my($path_web,$path_abs_disk)=_img_src($in,%args);
 724         my($width,$height)=Image::Size::imgsize($path_abs_disk);
 725         $alt=~s/<[^>]*>//g;
 726         $alt=escapeHTML($alt);
 727         my $content="<img src=\"".uri_escaped($path_web)."\" alt=\"$alt\" title=\"$alt\" ".img_size($width,$height)
 728                         .(!$args{"attr"} ? "" : " ".$args{"attr"})." />";
 729         do { return a_href((_img_src($_))[0],$content,"uri_as_in"=>1) if $_; } for $args{"a_href_img"};
 730         do { return a_href $_,$content if $_; } for $args{"a_href"};
 731         return $content;
 732 }
 733
 734 sub centerimg
 735 {
 736         my $r="";
 737         $r.='<table border="0" width="100%"><tr>'."\n";
 738         @_=( [@_] ) if !ref $_[0];
 739         for (@_) {
 740                 $r.="\t".'<td align="center">'.&{\&img}(@$_).'</td>'."\n";
 741                 }
 742         $r.='</tr></table>'."\n";
 743         return $r;
 744 }
 745
 746 sub rightimg
 747 {
 748 my($text,@args_img)=@_;
 749
 750         # FIXME: Workaround bug of 'Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)':
 751         #        <col width="@{[ (!$W->{"browser"}->ie() ? "1*" : "90%" ) ]}" />
 752         #        <col width="@{[ (!$W->{"browser"}->ie() ? "0*" : "10%" ) ]}" />
 753         # causes whole invisible projects in: Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.7.10) Gecko/20050719 Galeon/1.3.21
 754         return <<"HERE";
 755 <table border="0" width="100%">
 756         <tr>
 757                 <td align="left">
 758                         @{[ $text ]}
 759                 </td>
 760                 <td align="right">
 761                         @{[ &{\&img}(@args_img) ]}
 762                 </td>
 763         </tr>
 764 </table>
 765 HERE
 766 }
 767
 768 sub readfile($$)
 769 {
 770 my($class,$filename)=@_;
 771
 772         local *F;
 773         open F,$filename or cluck "Cannot open \"$filename\": $!";
 774         my $F=do { local $/=undef(); <F>; };
 775         close F or cluck "Cannot close \"$filename\": $!";
 776         return $F;
 777 }
 778
 779 sub no_cache($)
 780 {
 781 my($self)=@_;
 782
 783         header("Expires"=>"Mon, 26 Jul 1997 05:00:00 GMT");     # date in the past
 784         header("Last-Modified"=>strftime("%a, %d %b %Y %H:%M:%S GMT",gmtime()));        # always modified
 785         header("Cache-Control"=>"no-cache, must-revalidate");   # HTTP/1.1
 786         header("Pragma"=>"no-cache");   # HTTP/1.0
 787 }
 788
 789 sub heading()
 790 {
 791 my($class)=@_;
 792
 793         # $ENV{"CLIENT_CHARSET"} ignored (mod_czech support dropped!)
 794         my $client_charset=$W->{"force_charset"} || "us-ascii";
 795         header("Content-Style-Type"=>"text/css");
 796         header("Content-Script-Type"=>"text/javascript");
 797         do { header("Content-Language"=>$_) if $_; } for $W->{"language"};
 798         $class->no_cache() if $W->{"no_cache"};
 799
 800         while (my($key,$val)=each(%{$W->{"headers"}})) {
 801                 $W->{"r"}->headers_out()->{$key}=$val;
 802                 }
 803         exit if $W->{"r"}->header_only();
 804         return if $W->{"header_only"};
 805         # We still can append headers before we put out some text.
 806         # FIXME: It is not clean to still append them without overwriting.
 807         return if $W->{"heading_done"}++;
 808
 809         # Workaround bug
 810         #   https://bugzilla.mozilla.org/show_bug.cgi?id=120556
 811         # of at least
 812         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
 813         my $mime;
 814         # http://validator.w3.org/ does not send ANY "Accept" headers!
 815         $mime||="application/xhtml+xml" if !$W->{"accept"} && $W->{"user_agent"}=~m{^W3C_Validator/}i;
 816         $mime||=$class->Negotiate_choose([
 817                         # Put the fallback variant as the first one.
 818                         # Rate both variants the same to prefer "text/html" for undecided clients.
 819                         # At least
 820                         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
 821                         # prefers "application/xhtml+xml" over "text/html" itself:
 822                         #   text/xml,application/xml,application/xhtml+xml,text/html;q=0.9,text/plain;q=0.8,image/png,*/*;q=0.5
 823                         negotiate_variant(
 824                                         "id"=>"text/html",
 825                                         "content-type"=>"text/html",
 826                                         "qs"=>0.6,
 827                                         "charset"=>$client_charset,
 828                                         "lang"=>$W->{"language"},
 829                                         ),
 830                         negotiate_variant(
 831                                         "id"=>"application/xhtml+xml",
 832                                         "content-type"=>"application/xhtml+xml",
 833                                         "qs"=>0.6,
 834                                         "charset"=>$client_charset,
 835                                         "lang"=>$W->{"language"},
 836                                         ),
 837                         # application/xml ?
 838                         # text/xml ?
 839                         ]);
 840         $W->{"r"}->content_type("$mime; charset=$client_charset");
 841         Wprint '<?xml version="1.0" encoding="'.$client_charset.'"?>'."\n" if $mime=~m{^application/\w+[+]xml$};
 842         return if $W->{"xml_header_only"};
 843         Wprint '<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN" "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">'."\n";
 844         Wprint '<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="'.$W->{"language"}.'">'."\n";
 845         my $title=$W->{"title_prefix"}.join("",map({ ': '.$_; } ($W->{"title"} || ())));
 846         # Do not: cluck if $title=~/[<>]/;
 847         # as it is not solved just by: &a_href_inhibit
 848         # as sometimes titles use also: <i>...</i>
 849         $title=~s#<[^>]*>##g;
 850         Wprint "<head>";
 851         Wprint "<title>$title</title>\n";
 852         if ($W->{"have_css"}) {
 853                 # Everything can get overriden later.
 854                 for my $css ("/My/Web.css",map((!$_ ? () : ("ARRAY" ne ref($_) ? $_ : @$_)),$W->{"css_push"})) {
 855                         Wprint <<"HERE";
 856 <link rel="stylesheet" type="text/css" href="@{[ uri_escaped(path_web $css) ]}" />
 857 HERE
 858                         }
 859                 }
 860         Wprint '<meta name="robots" content="'.($W->{"indexme"} ? "" : "no" ).'index,follow" />'."\n";
 861         Wprint $W->{"head"};
 862         for my $type (qw(prev next index contents start up)) {
 863                 do { Wprint '<link rel="'.$type.'" href="'.uri_escaped(path_web $_).'" />'."\n" if $_; }
 864                                 for ($W->{"rel_$type"});
 865                 }
 866         Wprint "</head><body";
 867 #       Wprint ' bgcolor="black" text="white" link="aqua" vlink="teal"'
 868 #                       if $W->{"browser"}->netscape() && (!$W->{"browser"}->major() || $W->{"browser"}->major()<=4);
 869         Wprint $W->{"body_attr"};
 870         Wprint ">\n";
 871
 872         do { Wprint $_ if $_; } for $W->{"heading"};
 873 }
 874
 875 BEGIN {
 876         delete $W->{"__My::Web_init"};
 877         }
 878
 879 1;