# $Id$
# Source file to generate "./configure" to prepare package for compilation
# Copyright (C) 2002 Jan Kratochvil <project-captive@jankratochvil.net>
# 
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; exactly version 2 of June 1991 is required
# 
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
# 
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA


AC_INIT(src/libcaptive/Makefile-libcaptive.am)
AM_INIT_AUTOMAKE(captive,0.1cvs)
AM_CONFIG_HEADER(config.h)
AM_MAINTAINER_MODE
#AM_ACLOCAL_INCLUDE(macros)
dnl Prevent "AC_TRY_COMPILE was called before AC_ISC_POSIX":
AC_ISC_POSIX
AC_PROG_CC
AM_ENABLE_STATIC
AM_DISABLE_SHARED
AM_PROG_LIBTOOL

dnl gettext localization.
dnl FIXME: should we use AM_GLIB_GNU_GETTEXT of glib-gettext.m4 ?
ALL_LINGUAS="cs"
AM_GNU_GETTEXT

AM_PATH_GLIB_2_0(,,[AC_MSG_ERROR([Captive requires glib-2.0 library.])])

GTK_DOC_CHECK

dnl discard -g -O2 settings
CFLAGS=

dnl Define MAINTAINER_MODE in config.h.
if test "$USE_MAINTAINER_MODE" = "yes";then
	AC_DEFINE(MAINTAINER_MODE,,[Turn even some software behaviour according to MAINTAINER_MODE.])
	CFLAGS="$CFLAGS -Wall -Wstrict-prototypes -Wsign-compare"  ## FIXME: fix all sources: -Wsign-compare
	fi
dnl Some Makefiles use additional tests etc.
AM_CONDITIONAL(MAINTAINER_MODE,[test "$USE_MAINTAINER_MODE" = "yes"])

dnl Permit 'if IS_FALSE' for Makefile.am-s; symbol 'FALSE' forbidden by automake
AM_CONDITIONAL(IS_FALSE,false)

AC_ARG_ENABLE(debug,[  --enable-debug=[no/yes]	turn on debugging messages [default=yes]],,enable_debug=yes)

if test "$enable_debug" != "no";then
	CFLAGS="$CFLAGS -ggdb3"
	fi

dnl Separate 'acconfig.h' is no longer recommended by autoconf
AH_TOP([
#ifndef _CAPTIVE_CONFIG_H
#define _CAPTIVE_CONFIG_H 1
])
AH_BOTTOM([
#endif /* !_CAPTIVE_CONFIG_H */
])

dnl ENABLE_NLS_HOOK name to guarantee inclusion AFTER '#undef ENABLE_NLS'
AH_VERBATIM([ENABLE_NLS_HOOK],[
#ifdef ENABLE_NLS
/* <libintl.h> is taken from "$(top_srcdir)/intl" if system doesn't provide intl */
#	include <libintl.h>
#ifdef LIBCAPTIVE
#	define _(String) dgettext (PACKAGE,String)
#else
#	define _(String) gettext (String)
#endif /* LIBSURPRISE */
#	ifdef gettext_noop
#		define N_(String) gettext_noop (String)
#	else
#		define N_(String) (String)
#	endif
#else /* !ENABLE_NLS */
/* Stubs that do something close enough.  */
#	define textdomain(String) (String)
#	define gettext(String) (String)
#	define dgettext(Domain,Message) (Message)
#	define dcgettext(Domain,Message,Type) (Message)
#	define bindtextdomain(Domain,Directory) (Domain)
#	define _(String) (String)
#	define N_(String) (String)
#endif /* !ENABLE_NLS */
])

dnl Force glib for the whole package
CFLAGS="$CFLAGS $GLIB_CFLAGS"
AC_SUBST(CFLAGS)
LIBS="$LIBS $GLIB_LIBS"
AC_SUBST(LIBS)

dnl "Makefile" output files MUST have pathnames incl./excl. "./" prefix as specified!
AC_OUTPUT([
captive.spec
Makefile
./macros/Makefile
./po/Makefile.in
./intl/Makefile
./m4/Makefile
./src/Makefile
./src/libcaptive/Makefile
./src/libcaptive/include/Makefile
./src/libcaptive/include/captive/Makefile
./src/libcaptive/include/reactos/Makefile
./src/libcaptive/include/reactos/ddk/Makefile
./src/libcaptive/include/reactos/ddk/i386/Makefile
./src/libcaptive/include/reactos/internal/Makefile
./src/libcaptive/include/reactos/internal/i386/Makefile
./src/libcaptive/include/reactos/napi/Makefile
./src/libcaptive/include/reactos/ntos/Makefile
./src/libcaptive/reactos/Makefile
./src/libcaptive/reactos/include/Makefile
./src/libcaptive/reactos/ntoskrnl/Makefile
./src/libcaptive/reactos/ntoskrnl/dbg/Makefile
./src/libcaptive/reactos/ntoskrnl/ex/Makefile
./src/libcaptive/reactos/ntoskrnl/io/Makefile
./src/libcaptive/reactos/ntoskrnl/ke/Makefile
./src/libcaptive/reactos/ntoskrnl/ldr/Makefile
./src/libcaptive/reactos/ntoskrnl/ob/Makefile
./src/libcaptive/reactos/ntoskrnl/ps/Makefile
./src/libcaptive/reactos/ntoskrnl/rtl/Makefile
./src/libcaptive/reactos/ntoskrnl/se/Makefile
./src/libcaptive/halcaptive/Makefile
./src/libcaptive/kd/Makefile
./src/libcaptive/ke/Makefile
./src/libcaptive/ldr/Makefile
./src/libcaptive/mm/Makefile
./src/libcaptive/ps/Makefile
./src/libcaptive/rtl/Makefile
./src/libcaptive/client/Makefile
./src/client/Makefile
./src/client/cmdline/Makefile
./doc/Makefile
./doc/apiref/Makefile
])

dnl FIXME: Why is "po/POTFILES" being substituted?
make -C src distfiles DISTFILES_PRINT=1 \
		|sed -n 's/^:DISTFILES: *\(.*\)$/\1/p'|tr ' ' '\n'|grep . >po/POTFILES.in
cat po/POTFILES.in >po/POTFILES

echo done.