# $Id$
# Source file to generate "./configure" to prepare package for compilation
# Copyright (C) 2002-2003 Jan Kratochvil <project-captive@jankratochvil.net>
# 
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; exactly version 2 of June 1991 is required
# 
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
# 
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA


AC_INIT(src/libcaptive/Makefile-libcaptive.am)
dnl 2.53 for AM_GLIB_GNU_GETTEXT:
AC_PREREQ(2.53)
AM_INIT_AUTOMAKE(captive,1.0.2cvs)
AM_CONFIG_HEADER(config.h)
AM_MAINTAINER_MODE
dnl Call AC_PROG_CC before AC_ISC_POSIX.
AC_PROG_CC(gcc3 gcc-3.0 gcc cc)
AC_TRY_CPP([
#if __GNUC__ >= 3
#else
#error "GCC version 3.0+ required at least for ReactOS anonymous unions"
#endif
],,[AC_MSG_ERROR([Captive requires GCC version 3.0+.])])
dnl Prevent "AC_TRY_COMPILE was called before AC_ISC_POSIX":
AC_ISC_POSIX
AC_SYS_LARGEFILE
AM_PROG_AS
AM_DISABLE_STATIC
AM_ENABLE_SHARED
AM_PROG_LIBTOOL

dnl Workaround for autoconf-2.57:
m4_pattern_allow([AC_MSG_WARN])
m4_pattern_allow([AC_CHECK_LIB])
m4_pattern_allow([AC_CHECK_HEADERS])

dnl gettext localization.
dnl Use simpler AM_GLIB_GNU_GETTEXT instead of AM_GNU_GETTEXT
dnl as we depend on glib and glib requires system installed gettext anyway.
dnl http://lists.gnome.org/archives/gtk-devel-list/2003-April/msg00066.html
dnl Special 'GETTEXT_PACKAGE' is required by glib gettext.
ALL_LINGUAS="cs"
GETTEXT_PACKAGE="$PACKAGE"
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT

GTK_DOC_CHECK
dnl AM_CONDITIONAL needs to be here explicitely for doc/apiref/Makefile rebuild
AM_CONDITIONAL(ENABLE_GTK_DOC,[test x$enable_gtk_doc = xyes])
AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL,[test -n "$LIBTOOL"])

dnl Do not discard 'CFLAGS' settings as they may have been passed us by rpmbuild(8)

dnl Define MAINTAINER_MODE in config.h.
if test "$USE_MAINTAINER_MODE" = "yes";then
	AC_DEFINE(MAINTAINER_MODE,,[Turn even some software behaviour according to MAINTAINER_MODE.])
	CFLAGS="$CFLAGS -ggdb3 -Wall -Wstrict-prototypes -Wsign-compare"  ## FIXME: fix all sources: -Wsign-compare
	fi
dnl Some Makefiles use additional tests etc.
AM_CONDITIONAL(MAINTAINER_MODE,[test "$USE_MAINTAINER_MODE" = "yes"])


AC_ARG_ENABLE(man-pages,
		[  --enable-man-pages=no/yes/auto   pod2man(1) required for man pages (def.=yes)],,enable_man_pages=yes)
AC_ARG_ENABLE(sbin-mountdir,
		[  --enable-sbin-mountdir=DIR       mount(8) 'mount.captive' directory (def.=/sbin)],,
		[ enable_sbin_mountdir="/sbin" ])
AC_ARG_ENABLE(sbin-mount-fs,
		[  --enable-sbin-mount-fs=FS1:FS2   sbin-mount pre-installed symlinks (def.=ntfs:fastfat:cdfs:ext2fsd)],,
		[ enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd" ])
AC_ARG_ENABLE(sandbox-setuid,
		[  --enable-sandbox-setuid=USER     non-privileged user  for captive-sandbox-server (def.=captive)],
		[ CAPTIVE_SANDBOX_SETUID="$enableval" ],[ CAPTIVE_SANDBOX_SETUID="captive" ])
AC_ARG_ENABLE(sandbox-setgid,
		[  --enable-sandbox-setgid=GROUP    non-privileged group for captive-sandbox-server (def.=captive)],
		[ CAPTIVE_SANDBOX_SETGID="$enableval" ],[ CAPTIVE_SANDBOX_SETGID="captive" ])
AC_ARG_ENABLE(sandbox-chroot,
		[  --enable-sandbox-chroot=DIR      root-owned directory for captive-sandbox-server (def.=/var/lib/captive)],
		[ CAPTIVE_SANDBOX_CHROOT="$enableval" ],[ CAPTIVE_SANDBOX_CHROOT="/var/lib/captive" ])
AC_ARG_ENABLE(bug-replay,
		[  --enable-bug-replay=no/yes/auto  compile debugging tool (def.=auto)],,enable_bug_replay=auto)
AC_ARG_ENABLE(lufs,
		[  --enable-lufs=no/yes/auto        compile LUFS filesystem module (def.=auto)],,enable_lufs=auto)
AC_ARG_ENABLE(install-pkg,
		[  --enable-install-pkg=no/yes/auto compile installation utils (def.=auto)],,enable_install_pkg=auto)


# AC_ARG_ENABLE(sbin-mountdir,[--enable-sbin-mountdir=DIR],,[enable_sbin_mountdir="/sbin"])
AM_CONDITIONAL(ENABLE_SBIN_MOUNT,[test "$enable_sbin_mount" != "no"])
AC_SUBST(enable_sbin_mountdir)

# AC_ARG_ENABLE(sbin-mount-fs,[--enable-sbin-mount-fs=FS1:FS2],,[enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd"])
AC_SUBST(enable_sbin_mount_fs)

# AC_ARG_ENABLE(sandbox-setuid,[--enable-sandbox-setuid=USER],,[CAPTIVE_SANDBOX_SETUID="captive"])
AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETUID,"$CAPTIVE_SANDBOX_SETUID",
		[non-privileged user  for captive-sandbox-server])

# AC_ARG_ENABLE(sandbox-setgid,[--enable-sandbox-setgid=GROUP],,[CAPTIVE_SANDBOX_SETGID="captive"])
AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETGID,"$CAPTIVE_SANDBOX_SETGID",
		[non-privileged group for captive-sandbox-server])

# AC_ARG_ENABLE(sandbox-chroot,[--enable-sandbox-chroot=DIR],,[CAPTIVE_SANDBOX_CHROOT="/var/lib/captive"])
AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_CHROOT,"$CAPTIVE_SANDBOX_CHROOT",
		[root-owned directory for captive-sandbox-server])
AC_SUBST(CAPTIVE_SANDBOX_CHROOT)

dnl Permit 'if NEVER' for Makefile.am-s; symbol 'FALSE' forbidden by automake
AM_CONDITIONAL(NEVER,false)

PERL=
AC_PATH_PROGS(PERL,perl5 perl)
if test '!' -f ./src/libcaptive/ke/exports.c -a -z "$PERL";then
	AC_MSG_ERROR([perl(1) required as './src/libcaptive/ke/exports.c' is not found.])
fi
AM_CONDITIONAL(HAVE_PERL,test -n "$PERL")

POD2MAN=
AC_PATH_PROGS(POD2MAN,pod2man)
AM_CONDITIONAL(HAVE_POD2MAN,[ test -n "$POD2MAN" ])
if test x$enable_man_pages = xyes;then
	if test -z "$POD2MAN";then
		AC_MSG_ERROR([captive requires pod2man(1) for man pages; try --disable-man-pages.])
	fi
	if test -z "$PERL";then
		AC_MSG_ERROR([captive requires perl(1) for man pages; try --disable-man-pages.])
	fi
elif test x$enable_man_pages != xno;then
	if test -z "$POD2MAN";then
		AC_MSG_WARN([captive requires pod2man(1) for man pages by --enable-man-pages; mans will not be installed.])
	fi
	if test -z "$PERL";then
		AC_MSG_WARN([captive requires perl(1) for man pages by --enable-man-pages; mans will not be installed.])
	fi
fi
AM_CONDITIONAL(ENABLE_MAN_PAGES,[ test x$enable_man_pages != xno -a -n "$POD2MAN" -a -n "$PERL" ])

dnl Separate 'acconfig.h' is no longer recommended by autoconf
AH_TOP([
#ifndef _CAPTIVE_CONFIG_H
#define _CAPTIVE_CONFIG_H 1
])
AH_BOTTOM([
/* Do not place any stuff to AH_TOP as some of its includes
 * would discard the effect of _FILE_OFFSET_BITS by AC_SYS_LARGEFILE.
 */

#ifdef ENABLE_NLS
/* <libintl.h> is taken from "$(top_srcdir)/intl" if system doesn't provide intl */
#	include <libintl.h>
#ifdef LIBCAPTIVE
#	define _(String) dgettext (PACKAGE,String)
#else
#	define _(String) gettext (String)
#endif /* LIBCAPTIVE */
#	ifdef gettext_noop
#		define N_(String) gettext_noop (String)
#	else
#		define N_(String) (String)
#	endif
#else /* !ENABLE_NLS */
/* Stubs that do something close enough.  */
#	define textdomain(String) (String)
#	define gettext(String) (String)
#	define dgettext(Domain,Message) (Message)
#	define dcgettext(Domain,Message,Type) (Message)
#	define bindtextdomain(Domain,Directory) (Domain)
#	define _(String) (String)
#	define N_(String) (String)
#endif /* !ENABLE_NLS */

#include <glib/gtypes.h>	/* for 'gchar' */
#define G_LOG_DOMAIN ((const gchar *)"Captive")

/* Ensure we have proper -I options: */
#if defined(CAPTIVE_USE_GNOME_VFS_MODULE) || defined(CAPTIVE_USE_GNOME_VFS)
#ifndef HAVE_GNOME_VFS_READ_ENTIRE_FILE
#include <libgnomevfs/gnome-vfs-result.h>
GnomeVFSResult gnome_vfs_read_entire_file(const char *uri,int *file_size,char **file_contents);
#endif
#endif

/* Supplemental definitions not possible in this file. */
#ifdef LIBCAPTIVE
#include "captive/config2.h"
#endif

#endif /* !_CAPTIVE_CONFIG_H */
])

dnl Do not use PKG_CHECK_MODULES() as it would not set 'GLIB_GENMARSHAL' etc.
AM_PATH_GLIB_2_0(,,[AC_MSG_ERROR([Captive requires glib-2.0 library.])],[gmodule gobject gthread])
dnl Force glib for the whole package
CFLAGS="$CFLAGS $GLIB_CFLAGS"
LIBS="$LIBS $GLIB_LIBS"

dnl popt
AC_CHECK_LIB(popt,poptParseArgvString,[POPT_LIBS="-lpopt"],[AC_MSG_ERROR([Captive requires popt library.])])
AC_SUBST(POPT_LIBS)

AC_ARG_WITH(readline,[  --with-readline=[no/yes/auto]	clients with line editing (def.=auto)],,with_readline=auto)
AC_CHECK_HEADERS(readline/history.h)
dnl Check for libraries, if needed by configuration options.
if test "$with_readline" != "no"
then
	if test -d "/usr/lib/termcap"
	then
		READLINE_LDFLAGS="$READLINE_LDFLAGS -L/usr/lib/termcap"
	fi
	have_libreadline=false
	need_failed=""
	for need in "" termcap ncurses; do
		if test "x$need" != "x"
		then
			captive_save_LIBS="$LIBS"
			AC_CHECK_LIB($need,main,,
				[ need_failed="$need_failed $need"
				continue ]
				)
			LIBS="$captive_save_LIBS"
			lneed="-l$need"
		else
			lneed=""
		fi
		dnl Prevent AC_CHECK_LIB() here as it would _cache_ the value ignoring
		dnl our ever-changing "additiona libraries" parameter
		captive_save_LIBS="$LIBS"
		LIBS="-lreadline $lneed $READLINE_LIBS"
		AC_TRY_LINK(,[ main() ],
			[ have_libreadline=true
			READLINE_LIBS="$LIBS" ])
		LIBS="$captive_save_LIBS"
		if $have_libreadline
		then
			break
		fi
	done
	if $have_libreadline
	then
		AC_DEFINE(HAVE_LIBREADLINE,,[Use functions from libreadline?])
		AC_CHECK_LIB(readline,add_history,
			AC_DEFINE(HAVE_ADD_HISTORY,,[Use 'history' extension of libreadline?]),,
			$READLINE_LIBS)
	else
		for need in $need_failed; do
			AC_MSG_WARN(captive recommends $need library as your readline library
			probably needs it.)
		done
		if test "$with_readline" = "yes"
		then
			AC_MSG_ERROR([captive did not find the requested readline library for its client line editing capability.])
		else
			AC_MSG_WARN([captive recommends readline library for its client line editing capability.])
		fi
	fi
fi
AC_SUBST(READLINE_LIBS)
AC_SUBST(READLINE_LDFLAGS)

PKG_CHECK_MODULES(GNOME_VFS_MODULE,gnome-vfs-module-2.0)
GNOME_VFS_MODULE_CFLAGS="$GNOME_VFS_MODULE_CFLAGS -DCAPTIVE_USE_GNOME_VFS_MODULE=1"
AC_SUBST(GNOME_VFS_MODULE_CFLAGS)
AC_SUBST(GNOME_VFS_MODULE_LIBS)
PKG_CHECK_MODULES(GNOME_VFS,gnome-vfs-2.0)
GNOME_VFS_CFLAGS="$GNOME_VFS_CFLAGS -DCAPTIVE_USE_GNOME_VFS=1"
AC_SUBST(GNOME_VFS_CFLAGS)
AC_SUBST(GNOME_VFS_LIBS)

# AC_ARG_ENABLE(bug-replay,[--enable-bug-replay=[no/yes/auto]],,enable_bug_replay=auto)
dnl Check for 2.5.9 for: http://bugzilla.gnome.org/show_bug.cgi?id=117702
dnl Check the version - impossible to reliably check the missing feature.
PKG_CHECK_MODULES(LIBXML,libxml-2.0 >= 2.5.9,[ have_libxml_buffering=true ],[
	dnl Disable bug-replay(1) build if not met; --bug-pathname would be still OK.
	PKG_CHECK_MODULES(LIBXML,libxml-2.0,[ have_libxml_buffering=false ])
	])
dnl We also condition 'HAVE_LIBXML_XMLREADER_H' by 'HAVE_LIBXML_BUFFERING'
dnl as we have no use for xmlreader without working libxml buffering of 2.5.9.
AM_CONDITIONAL(ENABLE_BUG_REPLAY,[$have_libxml_buffering && test x$enable_bug_replay != xno])
if $have_libxml_buffering;then
	AC_DEFINE(HAVE_LIBXML_BUFFERING,,[libxml2 correctly reads textnodes by its xmlTextReader.])
else
	if test x$enable_bug_replay = xyes;then
		AC_MSG_ERROR([captive require libxml2 at least 2.5.9 for --enable-bug-replay feature.])
	elif test x$enable_bug_replay != xno;then
		AC_MSG_WARN([libxml2 at least 2.5.9 required --enable-bug-replay feature; disabled now.])
	fi
fi
AC_SUBST(LIBXML_CFLAGS)
AC_SUBST(LIBXML_LIBS)

PKG_CHECK_MODULES(OPENSSL,openssl,,[
	dnl At least Debian-3.0r1 has openssl but without its .pc module.
	AC_CHECK_LIB(crypto,MD5,[
		OPENSSL_CFLAGS=""
		OPENSSL_LIBS="-lcrypto"
		],[AC_MSG_ERROR([Captive requires crypto library (of openssl).])])
	])
AC_SUBST(OPENSSL_CFLAGS)
AC_SUBST(OPENSSL_LIBS)

# AC_ARG_ENABLE(lufs,[--enable-lufs=[no/yes/auto]],,enable_lufs=auto)
have_lufs_includes=false
PATH_LUFSMOUNT=""
if test x$enable_lufs != no;then
	have_lufs_includes=true
	dnl If ACTION-IF-NOT-FOUND is given, it is executed when one of the header
	dnl files is not found.
	AC_CHECK_HEADERS(lufs/fs.h lufs/proto.h,,[ have_lufs_includes=false ])
	if test x$have_lufs_includes = xfalse;then
		if test x$enable_lufs = xyes;then
			AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no LUFS include files were found. Install 'lufs-*-*captive*' package.])
		else
			AC_MSG_WARN([LUFS client not being compiled as no LUFS include files were found. Install 'lufs-*-*captive*' package.])
		fi
	fi
	AC_CHECK_TYPES([struct lufs_sbattr],,[
		dnl FIXME: Include 'lufs' version when 'lufs_sbattr' gets integrated:
		if $have_lufs_includes && test x$enable_lufs = xyes;then
			AC_MSG_ERROR([Although LUFS include files were found they are too old. You may also use --enable-lufs=auto.])
		else
			AC_MSG_WARN([Although LUFS include files were found they are too old. df(1) will not show available NTFS disk space.])
		fi
		],[#include <lufs/proto.h>])
	AC_PATH_PROGS(PATH_LUFSMOUNT,lufsmount)
	if test x$PATH_LUFSMOUNT = x;then
		if test x$enable_lufs = xyes;then
			AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no lufsmount(1) binary was found. Install 'lufs-*-*captive*' package.])
		else
			AC_MSG_WARN([LUFS client not being compiled as no lufsmount(1) binary was found. Install 'lufs-*-*captive*' package.])
		fi
	fi
fi
AM_CONDITIONAL(ENABLE_LUFS,[ $have_lufs_includes && test x$PATH_LUFSMOUNT != x -a x$enable_lufs != no ])
AC_SUBST(PATH_LUFSMOUNT)

dnl for $(top_srcdir)/src/libcaptive/client/
dnl Do not use '[client server]' as $4 to prevent: configure: test: too many arguments
dnl  - currently this argument is not used by 'orbit2-config' in any way anyway
dnl Do not use PKG_CHECK_MODULES() as it would not set 'ORBIT_IDL' etc.
AM_PATH_ORBIT2(,,[AC_MSG_ERROR([Captive requires ORBit2 library.])])

AC_ARG_WITH(orbit-line,[  --with-orbit-line=[link/linc/auto]	Use 'link' for ORBit2 >=2.7.x+ (def.=auto)],,with_orbit_line=auto)
captive_save_CFLAGS="$CFLAGS"
captive_save_LIBS="$LIBS"
CFLAGS="$CFLAGS $ORBIT_CFLAGS"
LIBS="$LIBS $ORBIT_LIBS"
AC_CHECK_FUNC(link_get_tmpdir,[
		AC_DEFINE(HAVE_ORBIT_LINK,,[ORBit2 is 2.7.x+ and therefore includes its own 'link' library])
		found_orbit_line=link
		],
	found_orbit_line=linc
	)
CFLAGS="$captive_save_CFLAGS"
LIBS="$captive_save_LIBS"
if test "x$with_orbit_line" != "xauto" -a "x$with_orbit_line" != "x$found_orbit_line";then
	AC_MSG_ERROR([--with-orbit-line=$with_orbit_line specified but the detected line is $found_orbit_line])
fi

if test "x$found_orbit_line" = "xlinc";then
	PKG_CHECK_MODULES(LINC,linc)
fi

# AC_ARG_ENABLE(install-pkg,[--enable-install-pkg=[no/yes/auto]],,enable_install_pkg=auto)
GLADE_W_INIT([
	./src/install/acquire/ui-gnome-interface.c
	./src/install/acquire/ui-gnome-interface.h
	./src/install/acquire/ui-gnome-callbacks.h
	./src/install/acquire/ui-gnome-support.c
	./src/install/acquire/ui-gnome-support.h
	],[$enable_install_pkg],[
		AC_CHECK_LIB(ntfs,ntfs_mount,[
			LIBNTFS_LIBS="-lntfs"

			have_libntfs_includes=true
			AC_CHECK_HEADERS
			# '#include "config.h"' may be required by <ntfs/*> include files.
			test -r config.h || touch config.h
			captive_save_CPPFLAGS="$CPPFLAGS"
			CPPFLAGS="$CPPFLAGS -I."	# for "config.h" touched above
			AC_CHECK_HEADERS(ntfs/types.h ntfs/volume.h,,[ have_libntfs_includes=false ])
			CPPFLAGS="$captive_save_CPPFLAGS"
			if $have_libntfs_includes;then

				captive_save_CPPFLAGS="$CPPFLAGS"
				CPPFLAGS="$CPPFLAGS $LIBXML_CFLAGS"
				AC_CHECK_HEADERS(libxml/xmlreader.h,
					[ glade_addon=yes ],
					[ AC_MSG_WARN([Captive requires libxml >= 2.4.29 for --enable-install-pkg.]) ])
				CPPFLAGS="$captive_save_CPPFLAGS"

			else
				AC_MSG_WARN([Captive requires ntfs/* include files (of ntfsprogs-devel) for --enable-install-pkg.])
			fi
			],[ AC_MSG_WARN([Captive requires libntfs (of ntfsprogs-devel) for --enable-install-pkg.]) ])
		])
AC_SUBST(GNOMEUI_CFLAGS)
AC_SUBST(GNOMEUI_LIBS)
AC_SUBST(LIBNTFS_LIBS)
dnl Do not: AM_CONDITIONAL(HAVE_LIBNTFS,[ test -n "$LIBNTFS_LIBS" ])
dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
AM_CONDITIONAL(HAVE_GLADE_WRITESOURCE,[ test "x$PATH_GLADE" != "x" ])
dnl Do not: AM_CONDITIONAL(BUILD_GLADESRC,[ test "xyes" = "x$BUILD_GLADESRC" ])
dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
GNOME_ADDON_LIBS=""
if test "x$BUILD_GLADESRC_TRUE" = "x"
then
	AC_CHECK_LIB(Xi,XOpenDevice,GNOME_ADDON_LIBS="$GNOME_ADDON_LIBS -lXi")
fi
AC_SUBST(GNOME_ADDON_LIBS)
dnl $BUILD_GLADESRC is already conditioned by $enable_install_pkg by GLADE_W_INIT()
AM_CONDITIONAL(ENABLE_INSTALL_PKG,[ test "xyes" = "x$BUILD_GLADESRC" ])

dnl Do not use AC_REPLACE_FUNCS() as we need to link it selectively:
GNOME_VFS_READ_ENTIRE_FILE_O=""
captive_save_CFLAGS="$CFLAGS"
captive_save_LIBS="$LIBS"
CFLAGS="$CFLAGS $GNOME_VFS_MODULE_CFLAGS"
LIBS="$LIBS $GNOME_VFS_MODULE_LIBS"
AC_CHECK_FUNCS(gnome_vfs_read_entire_file,,
	[ GNOME_VFS_READ_ENTIRE_FILE_O='gnome_vfs_read_entire_file.$(OBJEXT)' ])
CFLAGS="$captive_save_CFLAGS"
LIBS="$captive_save_LIBS"
AC_SUBST(GNOME_VFS_READ_ENTIRE_FILE_O)

AC_SUBST(CFLAGS)
AC_SUBST(LIBS)

dnl "Makefile" output files MUST have pathnames incl./excl. "./" prefix as specified!
dnl FIXME: Why the rule above was written here?
AC_OUTPUT([
captive.spec
./src/libcaptive/captive.pod.pl
./src/libcaptive/client/options.pod.pl
./src/client/cmdline/captive-cmdline.pod.pl
./src/client/lufs/lufs-captivefs.pod.pl
./src/client/lufs/mount.captive.pod.pl
./src/client/lufs/mount.captive
./src/client/sandbox-server/captive-sandbox-server.pod.pl
./src/install/fstab/captive-install-fstab.pod.pl
./src/install/acquire/captive-install-acquire.pod.pl
./src/client/gnomevfs/captive.conf
./po/Makefile.in
./macros/glade-w.sh
./debian/changelog
Makefile
./macros/Makefile
./src/Makefile
./src/libcaptive/Makefile
./src/libcaptive/include/Makefile
./src/libcaptive/include/captive/Makefile
./src/libcaptive/include/reactos/Makefile
./src/libcaptive/include/reactos/ddk/Makefile
./src/libcaptive/include/reactos/ddk/i386/Makefile
./src/libcaptive/include/reactos/internal/Makefile
./src/libcaptive/include/reactos/internal/i386/Makefile
./src/libcaptive/include/reactos/napi/Makefile
./src/libcaptive/include/reactos/ntos/Makefile
./src/libcaptive/reactos/Makefile
./src/libcaptive/reactos/include/Makefile
./src/libcaptive/reactos/hal/Makefile
./src/libcaptive/reactos/hal/halx86/Makefile
./src/libcaptive/reactos/ntoskrnl/Makefile
./src/libcaptive/reactos/ntoskrnl/dbg/Makefile
./src/libcaptive/reactos/ntoskrnl/ex/Makefile
./src/libcaptive/reactos/ntoskrnl/fs/Makefile
./src/libcaptive/reactos/ntoskrnl/io/Makefile
./src/libcaptive/reactos/ntoskrnl/ke/Makefile
./src/libcaptive/reactos/ntoskrnl/ldr/Makefile
./src/libcaptive/reactos/ntoskrnl/mm/Makefile
./src/libcaptive/reactos/ntoskrnl/nt/Makefile
./src/libcaptive/reactos/ntoskrnl/ob/Makefile
./src/libcaptive/reactos/ntoskrnl/ps/Makefile
./src/libcaptive/reactos/ntoskrnl/rtl/Makefile
./src/libcaptive/reactos/ntoskrnl/rtl/i386/Makefile
./src/libcaptive/reactos/ntoskrnl/se/Makefile
./src/libcaptive/halcaptive/Makefile
./src/libcaptive/cc/Makefile
./src/libcaptive/cm/Makefile
./src/libcaptive/ex/Makefile
./src/libcaptive/fs/Makefile
./src/libcaptive/io/Makefile
./src/libcaptive/kd/Makefile
./src/libcaptive/ke/Makefile
./src/libcaptive/ldr/Makefile
./src/libcaptive/mm/Makefile
./src/libcaptive/nt/Makefile
./src/libcaptive/ob/Makefile
./src/libcaptive/po/Makefile
./src/libcaptive/ps/Makefile
./src/libcaptive/rtl/Makefile
./src/libcaptive/se/Makefile
./src/libcaptive/storage/Makefile
./src/libcaptive/sandbox/Makefile
./src/libcaptive/client/Makefile
./src/client/Makefile
./src/client/bug-replay/Makefile
./src/client/cmdline/Makefile
./src/client/gnomevfs/Makefile
./src/client/lufs/Makefile
./src/client/sandbox-server/Makefile
./src/install/Makefile
./src/install/libcaptive-install/Makefile
./src/install/fstab/Makefile
./src/install/acquire/Makefile
./src/TraceFS/Makefile
./src/w32-mod/Makefile
./doc/Makefile
./doc/apiref/Makefile
])

dnl FIXME: Why is "po/POTFILES" being substituted?
make -C src distfiles DISTFILES_PRINT=1 \
		|sed -n 's/^:DISTFILES: *\(.*\)$/\1/p'|tr ' ' '\n'|grep . >po/POTFILES.in
make -C po Makefile

echo done.