Merge branch 'addmainunit4-altlink-sharedstmt-dieref-dwz3-inlinebug-testcategory...
[lldb.git] / llvm / CMakeLists.txt
1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
2
3 cmake_minimum_required(VERSION 3.13.4)
4
5 set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
6
7 if(NOT DEFINED LLVM_VERSION_MAJOR)
8   set(LLVM_VERSION_MAJOR 12)
9 endif()
10 if(NOT DEFINED LLVM_VERSION_MINOR)
11   set(LLVM_VERSION_MINOR 0)
12 endif()
13 if(NOT DEFINED LLVM_VERSION_PATCH)
14   set(LLVM_VERSION_PATCH 0)
15 endif()
16 if(NOT DEFINED LLVM_VERSION_SUFFIX)
17   set(LLVM_VERSION_SUFFIX git)
18 endif()
19
20 if (NOT PACKAGE_VERSION)
21   set(PACKAGE_VERSION
22     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
23 endif()
24
25 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
26   message(WARNING "Visual Studio generators use the x86 host compiler by "
27                   "default, even for 64-bit targets. This can result in linker "
28                   "instability and out of memory errors. To use the 64-bit "
29                   "host compiler, pass -Thost=x64 on the CMake command line.")
30 endif()
31
32 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
33   # Some CMake features like object libraries get confused if you don't
34   # explicitly specify an architecture setting with the Xcode generator.
35   set(CMAKE_OSX_ARCHITECTURES "x86_64")
36 endif()
37
38 project(LLVM
39   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
40   LANGUAGES C CXX ASM)
41
42 set(CMAKE_CXX_STANDARD 14 CACHE STRING "C++ standard to conform to")
43 set(CMAKE_CXX_STANDARD_REQUIRED YES)
44 if (CYGWIN)
45   # Cygwin is a bit stricter and lack things like 'strdup', 'stricmp', etc in
46   # c++xx mode.
47   set(CMAKE_CXX_EXTENSIONS YES)
48 else()
49   set(CMAKE_CXX_EXTENSIONS NO)
50 endif()
51
52 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
53   message(STATUS "No build type selected, default to Debug")
54   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
55 endif()
56
57 # Side-by-side subprojects layout: automatically set the
58 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
59 # This allows an easy way of setting up a build directory for llvm and another
60 # one for llvm+clang+... using the same sources.
61 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libc;libclc;libcxx;libcxxabi;libunwind;lld;lldb;mlir;openmp;parallel-libs;polly;pstl")
62 # The flang project is not yet part of "all" projects (see C++ requirements)
63 set(LLVM_EXTRA_PROJECTS "flang")
64 # List of all known projects in the mono repo
65 set(LLVM_KNOWN_PROJECTS "${LLVM_ALL_PROJECTS};${LLVM_EXTRA_PROJECTS}")
66 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
67         "Semicolon-separated list of projects to build (${LLVM_KNOWN_PROJECTS}), or \"all\".")
68 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
69   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
70 endif()
71 if ("flang" IN_LIST LLVM_ENABLE_PROJECTS AND NOT "mlir" IN_LIST LLVM_ENABLE_PROJECTS)
72   message(STATUS "Enabling MLIR as a dependency to flang")
73   list(APPEND LLVM_ENABLE_PROJECTS "mlir")
74 endif()
75
76 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
77 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
78 # several reasons:
79 #
80 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
81 # source of truth for which projects to build. This means we will ignore user
82 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
83 # them.
84 #
85 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
86 # non-empty list but now the user wishes to disable building all other projects
87 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
88 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
89 # building all the projects that were previously enabled.
90 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
91 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
92
93 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
94   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
95   foreach(proj ${LLVM_KNOWN_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
96     string(TOUPPER "${proj}" upper_proj)
97     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
98     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
99       message(STATUS "${proj} project is enabled")
100       set(SHOULD_ENABLE_PROJECT TRUE)
101       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
102       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
103         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
104       endif()
105       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
106         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
107       else()
108         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
109       endif()
110     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
111       message(STATUS "${proj} project is enabled")
112       set(SHOULD_ENABLE_PROJECT TRUE)
113     else()
114       message(STATUS "${proj} project is disabled")
115       set(SHOULD_ENABLE_PROJECT FALSE)
116     endif()
117     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
118     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
119     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
120     # we should deprecate allowing users to set these variables by turning them
121     # into normal CMake variables rather than cache variables.
122     set(LLVM_TOOL_${upper_proj}_BUILD
123       ${SHOULD_ENABLE_PROJECT}
124       CACHE
125       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
126     )
127   endforeach()
128 endif()
129 unset(SHOULD_ENABLE_PROJECT)
130
131 # Build llvm with ccache if the package is present
132 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
133 if(LLVM_CCACHE_BUILD)
134   find_program(CCACHE_PROGRAM ccache)
135   if(CCACHE_PROGRAM)
136       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
137       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
138       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
139           CACHE STRING "Parameters to pass through to ccache")
140
141       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
142       if (LLVM_CCACHE_MAXSIZE)
143         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
144       endif()
145       if (LLVM_CCACHE_DIR)
146         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
147       endif()
148       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
149   else()
150     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
151   endif()
152 endif()
153
154 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
155
156 # Some features of the LLVM build may be disallowed when dependency debugging is
157 # enabled. In particular you cannot use ccache because we want to force compile
158 # operations to always happen.
159 if(LLVM_DEPENDENCY_DEBUGGING)
160   if(NOT CMAKE_HOST_APPLE)
161     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
162   endif()
163   if(LLVM_CCACHE_BUILD)
164     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
165   endif()
166 endif()
167
168 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
169 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
170 if(LLVM_ENABLE_GISEL_COV)
171   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
172 endif()
173
174 # Add path for custom modules
175 set(CMAKE_MODULE_PATH
176   ${CMAKE_MODULE_PATH}
177   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
178   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
179   )
180
181 # Generate a CompilationDatabase (compile_commands.json file) for our build,
182 # for use by clang_complete, YouCompleteMe, etc.
183 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
184
185 option(LLVM_INSTALL_BINUTILS_SYMLINKS
186   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
187
188 option(LLVM_INSTALL_CCTOOLS_SYMLINKS
189   "Install symlinks from the cctools tool names to the corresponding LLVM tools." OFF)
190
191 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
192
193 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
194
195 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
196 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
197 # the installation by default. See llvm.org/PR31905.
198 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
199
200 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
201 if ( LLVM_USE_FOLDERS )
202   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
203 endif()
204
205 include(VersionFromVCS)
206
207 option(LLVM_APPEND_VC_REV
208   "Embed the version control system revision in LLVM" ON)
209
210 set(PACKAGE_NAME LLVM)
211 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
212 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
213
214 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
215   "Default URL where bug reports are to be submitted.")
216
217 # Configure CPack.
218 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
219 set(CPACK_PACKAGE_VENDOR "LLVM")
220 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
221 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
222 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
223 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
224 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
225 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
226 if(WIN32 AND NOT UNIX)
227   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
228   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
229   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
230   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
231   set(CPACK_NSIS_MODIFY_PATH "ON")
232   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
233   if( CMAKE_CL_64 )
234     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
235   endif()
236 endif()
237 include(CPack)
238
239 # Sanity check our source directory to make sure that we are not trying to
240 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
241 # sure that we don't have any stray generated files lying around in the tree
242 # (which would end up getting picked up by header search, instead of the correct
243 # versions).
244 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
245   message(FATAL_ERROR "In-source builds are not allowed.
246 Please create a directory and run cmake from there, passing the path
247 to this source directory as the last argument.
248 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
249 Please delete them.")
250 endif()
251
252 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
253
254 if (CMAKE_BUILD_TYPE AND
255     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
256   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
257 endif()
258
259 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
260
261 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
262 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
263
264 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
265     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
266 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
267
268 # They are used as destination of target generators.
269 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
270 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
271 if(WIN32 OR CYGWIN)
272   # DLL platform -- put DLLs into bin.
273   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
274 else()
275   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
276 endif()
277
278 # Each of them corresponds to llvm-config's.
279 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
280 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
281 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
282 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
283 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
284
285 # Note: LLVM_CMAKE_PATH does not include generated files
286 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
287 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
288 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
289
290 # List of all targets to be built by default:
291 set(LLVM_ALL_TARGETS
292   AArch64
293   AMDGPU
294   ARM
295   AVR
296   BPF
297   Hexagon
298   Lanai
299   Mips
300   MSP430
301   NVPTX
302   PowerPC
303   RISCV
304   Sparc
305   SystemZ
306   WebAssembly
307   X86
308   XCore
309   )
310
311 # List of targets with JIT support:
312 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
313
314 set(LLVM_TARGETS_TO_BUILD "all"
315     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
316
317 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
318   CACHE STRING "Semicolon-separated list of experimental targets to build.")
319
320 option(BUILD_SHARED_LIBS
321   "Build all libraries as shared libraries instead of static" OFF)
322
323 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
324 if(LLVM_ENABLE_BACKTRACES)
325   set(ENABLE_BACKTRACES 1)
326 endif()
327
328 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
329
330 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
331 if(LLVM_ENABLE_CRASH_OVERRIDES)
332   set(ENABLE_CRASH_OVERRIDES 1)
333 endif()
334
335 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
336
337 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
338 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
339 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
340
341 set(LLVM_TARGET_ARCH "host"
342   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
343
344 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
345
346 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
347
348 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
349
350 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
351
352 # On z/OS, threads cannot be used because TLS is not supported.
353 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
354   option(LLVM_ENABLE_THREADS "Use threads if available." OFF)
355 else()
356   option(LLVM_ENABLE_THREADS "Use threads if available." ON)
357 endif()
358
359 set(LLVM_ENABLE_ZLIB "ON" CACHE STRING "Use zlib for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
360
361 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
362
363 option(LLVM_ENABLE_Z3_SOLVER
364   "Enable Support for the Z3 constraint solver in LLVM."
365   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
366 )
367
368 if (LLVM_ENABLE_Z3_SOLVER)
369   find_package(Z3 4.7.1)
370
371   if (LLVM_Z3_INSTALL_DIR)
372     if (NOT Z3_FOUND)
373       message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
374     endif()
375   endif()
376
377   if (NOT Z3_FOUND)
378     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
379   endif()
380
381   set(LLVM_WITH_Z3 1)
382 endif()
383
384 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
385
386
387 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
388   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
389 endif()
390
391 set(LLVM_TARGETS_TO_BUILD
392    ${LLVM_TARGETS_TO_BUILD}
393    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
394 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
395
396 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
397 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
398 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
399   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
400 else()
401   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
402 endif()
403 option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
404 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
405 option(LLVM_STATIC_LINK_CXX_STDLIB "Statically link the standard library." OFF)
406 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
407 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
408 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
409
410 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
411
412 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
413   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
414 else()
415   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
416 endif()
417
418 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
419
420 # While adding scalable vector support to LLVM, we temporarily want to
421 # allow an implicit conversion of TypeSize to uint64_t, and to allow
422 # code to get the fixed number of elements from a possibly scalable vector.
423 # This CMake flag enables a more strict mode where it asserts that the type
424 # is not a scalable vector type.
425 #
426 # Enabling this flag makes it easier to find cases where the compiler makes
427 # assumptions on the size being 'fixed size', when building tests for
428 # SVE/SVE2 or other scalable vector architectures.
429 option(LLVM_ENABLE_STRICT_FIXED_SIZE_VECTORS
430        "Enable assertions that type is not scalable in implicit conversion from TypeSize to uint64_t and calls to getNumElements" OFF)
431
432 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
433   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
434
435 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
436        "Set to ON to force using an old, unsupported host toolchain." OFF)
437
438 set(LLVM_LOCAL_RPATH "" CACHE FILEPATH
439   "If set, an absolute path added as rpath on binaries that do not already contain an executable-relative rpath.")
440
441 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
442        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
443
444 option(LLVM_USE_INTEL_JITEVENTS
445   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
446   OFF)
447
448 if( LLVM_USE_INTEL_JITEVENTS )
449   # Verify we are on a supported platform
450   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
451     message(FATAL_ERROR
452       "Intel JIT API support is available on Linux and Windows only.")
453   endif()
454 endif( LLVM_USE_INTEL_JITEVENTS )
455
456 option(LLVM_USE_OPROFILE
457   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
458
459 option(LLVM_EXTERNALIZE_DEBUGINFO
460   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
461
462 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
463   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
464
465 # If enabled, verify we are on a platform that supports oprofile.
466 if( LLVM_USE_OPROFILE )
467   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
468     message(FATAL_ERROR "OProfile support is available on Linux only.")
469   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
470 endif( LLVM_USE_OPROFILE )
471
472 option(LLVM_USE_PERF
473   "Use perf JIT interface to inform perf about JIT code" OFF)
474
475 # If enabled, verify we are on a platform that supports perf.
476 if( LLVM_USE_PERF )
477   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
478     message(FATAL_ERROR "perf support is available on Linux only.")
479   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
480 endif( LLVM_USE_PERF )
481
482 set(LLVM_USE_SANITIZER "" CACHE STRING
483   "Define the sanitizer used to build binaries and tests.")
484 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
485 set(LLVM_UBSAN_FLAGS
486     "-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
487     CACHE STRING
488     "Compile flags set to enable UBSan. Only used if LLVM_USE_SANITIZER contains 'Undefined'.")
489 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
490   "Path to fuzzing library for linking with fuzz targets")
491
492 option(LLVM_USE_SPLIT_DWARF
493   "Use -gsplit-dwarf when compiling llvm." OFF)
494
495 # Define an option controlling whether we should build for 32-bit on 64-bit
496 # platforms, where supported.
497 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT (WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX"))
498   # TODO: support other platforms and toolchains.
499   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
500 endif()
501
502 # Define the default arguments to use with 'lit', and an option for the user to
503 # override.
504 set(LIT_ARGS_DEFAULT "-sv")
505 if (MSVC_IDE OR XCODE)
506   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
507 endif()
508 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
509
510 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
511 if( WIN32 AND NOT CYGWIN )
512   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
513 endif()
514
515 set(LLVM_INTEGRATED_CRT_ALLOC "" CACHE PATH "Replace the Windows CRT allocator with any of {rpmalloc|mimalloc|snmalloc}. Only works with /MT enabled.")
516 if(LLVM_INTEGRATED_CRT_ALLOC)
517   if(NOT WIN32)
518     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC is only supported on Windows.")
519   endif()
520   if(LLVM_USE_SANITIZER)
521     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC cannot be used along with LLVM_USE_SANITIZER!")
522   endif()
523   if(CMAKE_BUILD_TYPE AND uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
524     message(FATAL_ERROR "The Debug target isn't supported along with LLVM_INTEGRATED_CRT_ALLOC!")
525   endif()
526 endif()
527
528 # Define options to control the inclusion and default build behavior for
529 # components which may not strictly be necessary (tools, examples, and tests).
530 #
531 # This is primarily to support building smaller or faster project files.
532 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
533 option(LLVM_BUILD_TOOLS
534   "Build the LLVM tools. If OFF, just generate build targets." ON)
535
536 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
537 option(LLVM_BUILD_UTILS
538   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
539
540 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
541 option(LLVM_BUILD_RUNTIMES
542   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
543
544 option(LLVM_BUILD_RUNTIME
545   "Build the LLVM runtime libraries." ON)
546 option(LLVM_BUILD_EXAMPLES
547   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
548 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
549
550 if(LLVM_BUILD_EXAMPLES)
551   add_definitions(-DBUILD_EXAMPLES)
552 endif(LLVM_BUILD_EXAMPLES)
553
554 option(LLVM_BUILD_TESTS
555   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
556 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
557 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
558
559 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
560 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
561 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
562
563 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
564 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
565 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
566 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
567 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
568 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
569
570 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
571     CACHE STRING "Doxygen-generated HTML documentation install directory")
572 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
573     CACHE STRING "OCamldoc-generated HTML documentation install directory")
574
575 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
576   "Build compiler-rt as an external project." OFF)
577
578 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
579   "Show target and host info when tools are invoked with --version." ON)
580
581 # You can configure which libraries from LLVM you want to include in the
582 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
583 # list of LLVM components. All component names handled by llvm-config are valid.
584 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
585   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
586     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
587 endif()
588
589 if(MSVC)
590   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
591   # Set this variable to OFF here so it can't be set with a command-line
592   # argument.
593   set (LLVM_LINK_LLVM_DYLIB OFF)
594   if (BUILD_SHARED_LIBS)
595     message(FATAL_ERROR "BUILD_SHARED_LIBS options is not supported on Windows.")
596   endif()
597 else()
598   option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
599   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
600   set(LLVM_BUILD_LLVM_DYLIB_default OFF)
601   if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
602     set(LLVM_BUILD_LLVM_DYLIB_default ON)
603   endif()
604   option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
605 endif()
606
607 if (LLVM_LINK_LLVM_DYLIB AND BUILD_SHARED_LIBS)
608   message(FATAL_ERROR "Cannot enable BUILD_SHARED_LIBS with LLVM_LINK_LLVM_DYLIB.  We recommend disabling BUILD_SHARED_LIBS.")
609 endif()
610
611 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
612 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
613   set(LLVM_USE_HOST_TOOLS ON)
614 endif()
615
616 if (MSVC_IDE)
617   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
618 endif()
619
620 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
621     LLVM_ENABLE_IR_PGO)
622   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
623     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
624     # for spining disks. Anything higher may only help on slower mediums.
625     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
626   endif()
627   if(NOT LLVM_PROFILE_FILE_PATTERN)
628     if(NOT LLVM_PROFILE_DATA_DIR)
629       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
630     endif()
631     file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
632   endif()
633   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
634     if(NOT LLVM_CSPROFILE_DATA_DIR)
635       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
636     endif()
637     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
638   endif()
639 endif()
640
641 if (LLVM_BUILD_STATIC)
642   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
643   # Remove shared library suffixes from use in find_library
644   foreach (shared_lib_suffix ${CMAKE_SHARED_LIBRARY_SUFFIX} ${CMAKE_IMPORT_LIBRARY_SUFFIX})
645     list(FIND CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix} shared_lib_suffix_idx)
646     if(NOT ${shared_lib_suffix_idx} EQUAL -1)
647       list(REMOVE_AT CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix_idx})
648     endif()
649   endforeach()
650 endif()
651
652 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
653 if(CMAKE_HOST_APPLE AND APPLE)
654   include(UseLibtool)
655 endif()
656
657 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
658 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
659 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
660
661 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
662   "Enable per-target runtimes directory")
663
664 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
665   "Profiling data file to use when compiling in order to improve runtime performance.")
666
667 # All options referred to from HandleLLVMOptions have to be specified
668 # BEFORE this include, otherwise options will not be correctly set on
669 # first cmake run
670 include(config-ix)
671
672 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
673   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
674 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
675
676 # By default, we target the host, but this can be overridden at CMake
677 # invocation time.
678 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
679   "Default target for which LLVM will generate code." )
680 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
681 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
682 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
683
684 if(WIN32 OR CYGWIN)
685   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
686     set(LLVM_ENABLE_PLUGINS_default ON)
687   else()
688     set(LLVM_ENABLE_PLUGINS_default OFF)
689   endif()
690 else()
691   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
692 endif()
693 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
694
695 set(ENABLE_EXPERIMENTAL_NEW_PASS_MANAGER FALSE CACHE BOOL
696   "Enable the experimental new pass manager by default.")
697
698 include(HandleLLVMOptions)
699
700 find_package(Python3 REQUIRED COMPONENTS Interpreter)
701
702 ######
703
704 # Configure all of the various header file fragments LLVM uses which depend on
705 # configuration variables.
706 set(LLVM_ENUM_TARGETS "")
707 set(LLVM_ENUM_ASM_PRINTERS "")
708 set(LLVM_ENUM_ASM_PARSERS "")
709 set(LLVM_ENUM_DISASSEMBLERS "")
710 foreach(t ${LLVM_TARGETS_TO_BUILD})
711   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
712
713   list(FIND LLVM_ALL_TARGETS ${t} idx)
714   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
715   # At this point, LLVMBUILDTOOL already checked all the targets passed in
716   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
717   # this test just makes sure that any experimental targets were passed via
718   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
719   if( idx LESS 0 AND idy LESS 0 )
720     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
721       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
722   else()
723     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
724   endif()
725
726   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
727   if( asmp_file )
728     set(LLVM_ENUM_ASM_PRINTERS
729       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
730   endif()
731   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
732     set(LLVM_ENUM_ASM_PARSERS
733       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
734   endif()
735   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
736     set(LLVM_ENUM_DISASSEMBLERS
737       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
738   endif()
739 endforeach(t)
740
741 # Produce the target definition files, which provide a way for clients to easily
742 # include various classes of targets.
743 configure_file(
744   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
745   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
746   )
747 configure_file(
748   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
749   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
750   )
751 configure_file(
752   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
753   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
754   )
755 configure_file(
756   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
757   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
758   )
759
760 # They are not referenced. See set_output_directory().
761 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
762 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
763 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
764
765 # For up-to-date instructions for installing the Tensorflow dependency, refer to
766 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/master/buildbot/buildbot_init.sh
767 # In this case, the latest C API library is available for download from
768 # https://www.tensorflow.org/install/lang_c.
769 # We will expose the conditional compilation variable,
770 # LLVM_HAVE_TF_API, through llvm-config.h, so that a user of the LLVM library may
771 # also leverage the dependency.
772 set(TENSORFLOW_C_LIB_PATH "" CACHE PATH "Path to TensorFlow C library install")
773 if (TENSORFLOW_C_LIB_PATH)
774   find_library(tensorflow_c_api tensorflow PATHS ${TENSORFLOW_C_LIB_PATH}/lib NO_DEFAULT_PATH REQUIRED)
775   set(LLVM_HAVE_TF_API "ON" CACHE BOOL "Full Tensorflow API available")
776   include_directories(${TENSORFLOW_C_LIB_PATH}/include)
777 endif()
778
779 # For up-to-date instructions for installing the Tensorflow dependency, refer to
780 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/master/buildbot/buildbot_init.sh
781 # Specifically, assuming python3 is installed:
782 # python3 -m pip install --upgrade pip && python3 -m pip install --user tf_nightly==2.3.0.dev20200528
783 # Then set TENSORFLOW_AOT_PATH to the package install - usually it's ~/.local/lib/python3.7/site-packages/tensorflow
784 #
785 set(TENSORFLOW_AOT_PATH "" CACHE PATH "Path to TensorFlow pip install dir")
786
787 if (NOT TENSORFLOW_AOT_PATH STREQUAL "")
788   set(LLVM_HAVE_TF_AOT "ON" CACHE BOOL "Tensorflow AOT available")
789   set(TENSORFLOW_AOT_COMPILER
790     "${TENSORFLOW_AOT_PATH}/../../../../bin/saved_model_cli"
791     CACHE PATH "Path to the Tensorflow AOT compiler")
792   include_directories(${TENSORFLOW_AOT_PATH}/include)
793   add_subdirectory(${TENSORFLOW_AOT_PATH}/xla_aot_runtime_src
794     ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/tf_runtime)
795 endif()
796
797 # Keep the legacy CMake flag ENABLE_EXPERIMENTAL_NEW_PASS_MANAGER for
798 # compatibility.
799 set(LLVM_ENABLE_NEW_PASS_MANAGER ${ENABLE_EXPERIMENTAL_NEW_PASS_MANAGER})
800
801 # Configure the three LLVM configuration header files.
802 configure_file(
803   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
804   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
805 configure_file(
806   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
807   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
808 configure_file(
809   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
810   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
811
812 # Add target for generating source rpm package.
813 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
814     CACHE FILEPATH ".spec file to use for srpm generation")
815 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
816 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
817
818 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
819 string(LENGTH "${revision}" revision_length)
820 set(LLVM_RPM_SPEC_REVISION "${revision}")
821
822 configure_file(
823   ${LLVM_SRPM_USER_BINARY_SPECFILE}
824   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
825
826 add_custom_target(srpm
827   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
828   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
829 set_target_properties(srpm PROPERTIES FOLDER "Misc")
830
831 if(APPLE AND DARWIN_LTO_LIBRARY)
832   set(CMAKE_EXE_LINKER_FLAGS
833     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
834   set(CMAKE_SHARED_LINKER_FLAGS
835     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
836   set(CMAKE_MODULE_LINKER_FLAGS
837     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
838 endif()
839
840 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
841 # break things. In this case we need to enable the large-file API as well.
842 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
843           add_definitions("-D_XOPEN_SOURCE=700")
844           add_definitions("-D_LARGE_FILE_API")
845
846   # CMake versions less than 3.16 set default linker flags to include -brtl, as
847   # well as setting -G when building libraries, so clear them out. Note we only
848   # try to clear the form that CMake will set as part of its initial
849   # configuration, it is still possible the user may force it as part of a
850   # compound option.
851   if(CMAKE_VERSION VERSION_LESS 3.16)
852     string(REGEX REPLACE "(^|[ \t]+)-Wl,-brtl([ \t]+|$)" " " CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS}")
853     string(REGEX REPLACE "(^|[ \t]+)-Wl,-brtl([ \t]+|$)" " " CMAKE_SHARED_LINKER_FLAGS  "${CMAKE_SHARED_LINKER_FLAGS}")
854     string(REGEX REPLACE "(^|[ \t]+)-Wl,-brtl([ \t]+|$)" " " CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS}")
855     string(REGEX REPLACE "(^|[ \t]+)(-Wl,)?-G([ \t]+|$)" " " CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS
856       "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS}")
857     string(REGEX REPLACE "(^|[ \t]+)(-Wl,)?-G([ \t]+|$)" " " CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS
858       "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS}")
859     string(REGEX REPLACE "(^|[ \t]+)(-Wl,)?-G([ \t]+|$)" " " CMAKE_SHARED_LIBRARY_CREATE_ASM_FLAGS
860       "${CMAKE_SHARED_LIBRARY_CREATE_ASM_FLAGS}")
861     string(REGEX REPLACE "(^|[ \t]+)-Wl,-G," " -Wl," CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS
862       "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS}")
863     string(REGEX REPLACE "(^|[ \t]+)-Wl,-G," " -Wl," CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS
864       "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS}")
865     string(REGEX REPLACE "(^|[ \t]+)-Wl,-G," " -Wl," CMAKE_SHARED_LIBRARY_CREATE_ASM_FLAGS
866       "${CMAKE_SHARED_LIBRARY_CREATE_ASM_FLAGS}")
867   endif()
868
869   # Modules should be built with -shared -Wl,-G, so we can use runtime linking
870   # with plugins.
871   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -shared -Wl,-G")
872
873   # Also set the correct flags for building shared libraries.
874   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -shared")
875 endif()
876
877 # Build with _XOPEN_SOURCE on z/OS.
878 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
879   add_definitions("-D_XOPEN_SOURCE=600")
880   add_definitions("-D_OPEN_SYS") # Needed for process information.
881   add_definitions("-D_OPEN_SYS_FILE_EXT") # Needed for EBCDIC I/O.
882 endif()
883
884 # Build with _FILE_OFFSET_BITS=64 on Solaris to match g++ >= 9.
885 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
886           add_definitions("-D_FILE_OFFSET_BITS=64")
887 endif()
888
889 set(CMAKE_INCLUDE_CURRENT_DIR ON)
890
891 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
892
893 # when crosscompiling import the executable targets from a file
894 if(LLVM_USE_HOST_TOOLS)
895   include(CrossCompile)
896   llvm_create_cross_target(LLVM NATIVE "" Release)
897 endif(LLVM_USE_HOST_TOOLS)
898 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
899 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
900 # (this is a variable that CrossCompile sets on recursive invocations)
901 endif()
902
903 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
904    # special hack for Solaris to handle crazy system sys/regset.h
905    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
906 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
907
908 # Make sure we don't get -rdynamic in every binary. For those that need it,
909 # use export_executable_symbols(target).
910 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
911
912 include(AddLLVM)
913 include(TableGen)
914
915 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
916   # People report that -O3 is unreliable on MinGW. The traditional
917   # build also uses -O2 for that reason:
918   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
919 endif()
920
921 # Put this before tblgen. Else we have a circular dependence.
922 add_subdirectory(lib/Demangle)
923 add_subdirectory(lib/Support)
924 add_subdirectory(lib/TableGen)
925
926 add_subdirectory(utils/TableGen)
927
928 add_subdirectory(include/llvm)
929
930 add_subdirectory(lib)
931
932 if( LLVM_INCLUDE_UTILS )
933   add_subdirectory(utils/FileCheck)
934   add_subdirectory(utils/PerfectShuffle)
935   add_subdirectory(utils/count)
936   add_subdirectory(utils/not)
937   add_subdirectory(utils/yaml-bench)
938 else()
939   if ( LLVM_INCLUDE_TESTS )
940     message(FATAL_ERROR "Including tests when not building utils will not work.
941     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
942   endif()
943 endif()
944
945 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
946 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
947   add_subdirectory(utils/LLVMVisualizers)
948 endif()
949
950 foreach( binding ${LLVM_BINDINGS_LIST} )
951   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
952     add_subdirectory(bindings/${binding})
953   endif()
954 endforeach()
955
956 add_subdirectory(projects)
957
958 if( LLVM_INCLUDE_TOOLS )
959   add_subdirectory(tools)
960 endif()
961
962 if( LLVM_INCLUDE_RUNTIMES )
963   add_subdirectory(runtimes)
964 endif()
965
966 if( LLVM_INCLUDE_EXAMPLES )
967   add_subdirectory(examples)
968 endif()
969
970 if( LLVM_INCLUDE_TESTS )
971   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
972     include(LLVMExternalProjectUtils)
973     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
974       USE_TOOLCHAIN
975       EXCLUDE_FROM_ALL
976       NO_INSTALL
977       ALWAYS_CLEAN)
978   endif()
979   add_subdirectory(utils/lit)
980   add_subdirectory(test)
981   add_subdirectory(unittests)
982   if( LLVM_INCLUDE_UTILS )
983     add_subdirectory(utils/unittest)
984   endif()
985
986   if (WIN32)
987     # This utility is used to prevent crashing tests from calling Dr. Watson on
988     # Windows.
989     add_subdirectory(utils/KillTheDoctor)
990   endif()
991
992   # Add a global check rule now that all subdirectories have been traversed
993   # and we know the total set of lit testsuites.
994   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
995   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
996   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
997   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
998   get_property(LLVM_ADDITIONAL_TEST_TARGETS
999                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
1000   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
1001                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
1002   add_lit_target(check-all
1003     "Running all regression tests"
1004     ${LLVM_LIT_TESTSUITES}
1005     PARAMS ${LLVM_LIT_PARAMS}
1006     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
1007     ARGS ${LLVM_LIT_EXTRA_ARGS}
1008     )
1009   if(TARGET check-runtimes)
1010     add_dependencies(check-all check-runtimes)
1011   endif()
1012   add_custom_target(test-depends
1013                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
1014   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
1015 endif()
1016
1017 if (LLVM_INCLUDE_DOCS)
1018   add_subdirectory(docs)
1019 endif()
1020
1021 add_subdirectory(cmake/modules)
1022
1023 # Do this last so that all lit targets have already been created.
1024 if (LLVM_INCLUDE_UTILS)
1025   add_subdirectory(utils/llvm-lit)
1026 endif()
1027
1028 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1029   install(DIRECTORY include/llvm include/llvm-c
1030     DESTINATION include
1031     COMPONENT llvm-headers
1032     FILES_MATCHING
1033     PATTERN "*.def"
1034     PATTERN "*.h"
1035     PATTERN "*.td"
1036     PATTERN "*.inc"
1037     PATTERN "LICENSE.TXT"
1038     )
1039
1040   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1041     DESTINATION include
1042     COMPONENT llvm-headers
1043     FILES_MATCHING
1044     PATTERN "*.def"
1045     PATTERN "*.h"
1046     PATTERN "*.gen"
1047     PATTERN "*.inc"
1048     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1049     PATTERN "CMakeFiles" EXCLUDE
1050     PATTERN "config.h" EXCLUDE
1051     )
1052
1053   if (LLVM_INSTALL_MODULEMAPS)
1054     install(DIRECTORY include/llvm include/llvm-c
1055             DESTINATION include
1056             COMPONENT llvm-headers
1057             FILES_MATCHING
1058             PATTERN "module.modulemap"
1059             )
1060     install(FILES include/llvm/module.install.modulemap
1061             DESTINATION include/llvm
1062             COMPONENT llvm-headers
1063             RENAME "module.extern.modulemap"
1064             )
1065   endif(LLVM_INSTALL_MODULEMAPS)
1066
1067   # Installing the headers needs to depend on generating any public
1068   # tablegen'd headers.
1069   add_custom_target(llvm-headers DEPENDS intrinsics_gen omp_gen)
1070   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1071
1072   if (NOT LLVM_ENABLE_IDE)
1073     add_llvm_install_targets(install-llvm-headers
1074                              DEPENDS llvm-headers
1075                              COMPONENT llvm-headers)
1076   endif()
1077
1078   # Custom target to install all libraries.
1079   add_custom_target(llvm-libraries)
1080   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1081
1082   if (NOT LLVM_ENABLE_IDE)
1083     add_llvm_install_targets(install-llvm-libraries
1084                              DEPENDS llvm-libraries
1085                              COMPONENT llvm-libraries)
1086   endif()
1087
1088   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1089   if(LLVM_LIBS)
1090     list(REMOVE_DUPLICATES LLVM_LIBS)
1091     foreach(lib ${LLVM_LIBS})
1092       add_dependencies(llvm-libraries ${lib})
1093       if (NOT LLVM_ENABLE_IDE)
1094         add_dependencies(install-llvm-libraries install-${lib})
1095         add_dependencies(install-llvm-libraries-stripped install-${lib}-stripped)
1096       endif()
1097     endforeach()
1098   endif()
1099 endif()
1100
1101 # This must be at the end of the LLVM root CMakeLists file because it must run
1102 # after all targets are created.
1103 include(LLVMDistributionSupport)
1104 llvm_distribution_add_targets()
1105 process_llvm_pass_plugins(GEN_CONFIG)
1106
1107 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1108 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1109   include(InstallRequiredSystemLibraries)
1110 endif()
1111
1112 if (LLVM_INCLUDE_BENCHMARKS)
1113   # Override benchmark defaults so that when the library itself is updated these
1114   # modifications are not lost.
1115   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1116   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1117   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1118   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1119   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1120   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1121   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1122
1123   add_subdirectory(utils/benchmark)
1124   add_subdirectory(benchmarks)
1125 endif()
1126
1127 if (LLVM_INCLUDE_UTILS AND LLVM_INCLUDE_TOOLS)
1128   add_subdirectory(utils/llvm-locstats)
1129 endif()