Revert https://reviews.llvm.org/D23279 because the tests have failed on several platforms
[lldb.git] / clang-tools-extra / test / CMakeLists.txt
1 # Test runner infrastructure for Clang-based tools. This configures the Clang
2 # test trees for use by Lit, and delegates to LLVM's lit test handlers.
3 #
4 # Note that currently we don't support stand-alone builds of Clang, you must
5 # be building Clang from within a combined LLVM+Clang checkout..
6
7 set(CLANG_TOOLS_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/..")
8 set(CLANG_TOOLS_BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}/..")
9
10 if (CMAKE_CFG_INTDIR STREQUAL ".")
11   set(LLVM_BUILD_MODE ".")
12 else ()
13   set(LLVM_BUILD_MODE "%(build_mode)s")
14 endif ()
15
16 string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} CLANG_TOOLS_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
17
18 configure_lit_site_cfg(
19   ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
20   ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
21   )
22
23 configure_lit_site_cfg(
24   ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
25   ${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
26   )
27
28 option(CLANG_TOOLS_TEST_USE_VG "Run Clang tools' tests under Valgrind" OFF)
29 if(CLANG_TOOLS_TEST_USE_VG)
30   set(CLANG_TOOLS_TEST_EXTRA_ARGS ${CLANG_TEST_EXTRA_ARGS} "--vg")
31 endif()
32
33 set(CLANG_TOOLS_TEST_DEPS
34   # Base line deps.
35   FileCheck count not
36
37   # clang-tidy tests require it.
38   clang-headers
39
40   # For the clang-tidy libclang integration test.
41   c-index-test
42
43   # Individual tools we test.
44   clang-apply-replacements
45   clang-include-fixer
46   clang-query
47   clang-rename
48   clang-tidy
49   find-all-symbols
50   modularize
51   pp-trace
52
53   # Unit tests
54   ExtraToolsUnitTests
55   )
56
57 add_lit_testsuite(check-clang-tools "Running the Clang extra tools' regression tests"
58   ${CMAKE_CURRENT_BINARY_DIR}
59   DEPENDS ${CLANG_TOOLS_TEST_DEPS}
60   ARGS ${CLANG_TOOLS_TEST_EXTRA_ARGS}
61   )
62 set_target_properties(check-clang-tools PROPERTIES FOLDER "Clang extra tools' tests")
63