Merge branch 'addmainunit4-altlink-sharedstmt-dieref-dwz3-inlinebug-testcategory...
[lldb.git] / compiler-rt / CMakeLists.txt
1 # CMake build for CompilerRT.
2 #
3 # An important constraint of the build is that it only produces libraries
4 # based on the ability of the host toolchain to target various platforms.
5
6 cmake_minimum_required(VERSION 3.13.4)
7
8 # Check if compiler-rt is built as a standalone project.
9 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR OR COMPILER_RT_STANDALONE_BUILD)
10   project(CompilerRT C CXX ASM)
11   set(COMPILER_RT_STANDALONE_BUILD TRUE)
12   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
13 endif()
14
15 # Add path for custom compiler-rt modules.
16 list(INSERT CMAKE_MODULE_PATH 0
17   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
18   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
19   )
20
21 if(CMAKE_CONFIGURATION_TYPES)
22   set(CMAKE_CFG_RESOLVED_INTDIR "${CMAKE_CFG_INTDIR}/")
23 else()
24   set(CMAKE_CFG_RESOLVED_INTDIR "")
25 endif()
26
27 include(base-config-ix)
28 include(CompilerRTUtils)
29
30 option(COMPILER_RT_BUILD_BUILTINS "Build builtins" ON)
31 mark_as_advanced(COMPILER_RT_BUILD_BUILTINS)
32 option(COMPILER_RT_BUILD_CRT "Build crtbegin.o/crtend.o" ON)
33 mark_as_advanced(COMPILER_RT_BUILD_CRT)
34 option(COMPILER_RT_CRT_USE_EH_FRAME_REGISTRY "Use eh_frame in crtbegin.o/crtend.o" ON)
35 mark_as_advanced(COMPILER_RT_CRT_USE_EH_FRAME_REGISTRY)
36 option(COMPILER_RT_BUILD_SANITIZERS "Build sanitizers" ON)
37 mark_as_advanced(COMPILER_RT_BUILD_SANITIZERS)
38 option(COMPILER_RT_BUILD_XRAY "Build xray" ON)
39 mark_as_advanced(COMPILER_RT_BUILD_XRAY)
40 option(COMPILER_RT_BUILD_LIBFUZZER "Build libFuzzer" ON)
41 mark_as_advanced(COMPILER_RT_BUILD_LIBFUZZER)
42 option(COMPILER_RT_BUILD_PROFILE "Build profile runtime" ON)
43 mark_as_advanced(COMPILER_RT_BUILD_PROFILE)
44 option(COMPILER_RT_BUILD_MEMPROF "Build memory profiling runtime" ON)
45 mark_as_advanced(COMPILER_RT_BUILD_MEMPROF)
46 option(COMPILER_RT_BUILD_XRAY_NO_PREINIT "Build xray with no preinit patching" OFF)
47 mark_as_advanced(COMPILER_RT_BUILD_XRAY_NO_PREINIT)
48
49 set(COMPILER_RT_ASAN_SHADOW_SCALE ""
50     CACHE STRING "Override the shadow scale to be used in ASan runtime")
51
52 if (NOT COMPILER_RT_ASAN_SHADOW_SCALE STREQUAL "")
53   # Check that the shadow scale value is valid.
54   if (NOT (COMPILER_RT_ASAN_SHADOW_SCALE GREATER -1 AND
55            COMPILER_RT_ASAN_SHADOW_SCALE LESS 8))
56     message(FATAL_ERROR "
57       Invalid ASan Shadow Scale '${COMPILER_RT_ASAN_SHADOW_SCALE}'.")
58   endif()
59
60   set(COMPILER_RT_ASAN_SHADOW_SCALE_LLVM_FLAG
61       -mllvm -asan-mapping-scale=${COMPILER_RT_ASAN_SHADOW_SCALE})
62   set(COMPILER_RT_ASAN_SHADOW_SCALE_DEFINITION
63       ASAN_SHADOW_SCALE=${COMPILER_RT_ASAN_SHADOW_SCALE})
64   set(COMPILER_RT_ASAN_SHADOW_SCALE_FLAG
65       -D${COMPILER_RT_ASAN_SHADOW_SCALE_DEFINITION})
66 endif()
67
68 set(COMPILER_RT_HWASAN_WITH_INTERCEPTORS ON CACHE BOOL
69     "Enable libc interceptors in HWASan (testing mode)")
70
71 set(COMPILER_RT_BAREMETAL_BUILD OFF CACHE BOOL
72   "Build for a bare-metal target.")
73
74 if (COMPILER_RT_STANDALONE_BUILD)
75   load_llvm_config()
76   if (TARGET intrinsics_gen)
77     # Loading the llvm config causes this target to be imported so place it
78     # under the appropriate folder in an IDE.
79     set_target_properties(intrinsics_gen PROPERTIES FOLDER "Compiler-RT Misc")
80   endif()
81
82   find_package(Python3 COMPONENTS Interpreter)
83   if(NOT Python3_Interpreter_FOUND)
84     message(WARNING "Python3 not found, using python2 as a fallback")
85     find_package(Python2 COMPONENTS Interpreter REQUIRED)
86     if(Python2_VERSION VERSION_LESS 2.7)
87       message(SEND_ERROR "Python 2.7 or newer is required")
88     endif()
89
90     # Treat python2 as python3
91     add_executable(Python3::Interpreter IMPORTED)
92     set_target_properties(Python3::Interpreter PROPERTIES
93       IMPORTED_LOCATION ${Python2_EXECUTABLE})
94     set(Python3_EXECUTABLE ${Python2_EXECUTABLE})
95   endif()
96
97   # Ensure that fat libraries are built correctly on Darwin
98   if(APPLE)
99     include(UseLibtool)
100   endif()
101
102   # Define default arguments to lit.
103   set(LIT_ARGS_DEFAULT "-sv")
104   if (MSVC OR XCODE)
105     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
106   endif()
107   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
108   set(LLVM_LIT_OUTPUT_DIR "${COMPILER_RT_EXEC_OUTPUT_DIR}")
109 endif()
110
111 construct_compiler_rt_default_triple()
112 if ("${COMPILER_RT_DEFAULT_TARGET_TRIPLE}" MATCHES ".*hf$")
113   if (${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "^arm")
114     set(COMPILER_RT_DEFAULT_TARGET_ARCH "armhf")
115     CHECK_SYMBOL_EXISTS (__thumb__ "" COMPILER_RT_ARM_THUMB)
116   endif()
117 endif()
118 if ("${COMPILER_RT_DEFAULT_TARGET_TRIPLE}" MATCHES ".*android.*")
119   set(ANDROID 1)
120   string(REGEX MATCH "-target(=| +)[^ ]+android[a-z]*([0-9]+)" ANDROID_API_LEVEL "${CMAKE_C_FLAGS}")
121   set(ANDROID_API_LEVEL ${CMAKE_MATCH_2})
122 endif()
123 pythonize_bool(ANDROID)
124
125 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
126 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
127
128 pythonize_bool(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR)
129
130 # We support running instrumented tests when we're not cross compiling
131 # and target a UNIX-like system or Windows.
132 # We can run tests on Android even when we are cross-compiling.
133 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND (UNIX OR WIN32)) OR ANDROID
134    OR COMPILER_RT_EMULATOR)
135   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
136 else()
137   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
138 endif()
139
140 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
141 option(COMPILER_RT_EXTERNALIZE_DEBUGINFO
142   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
143 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
144 pythonize_bool(COMPILER_RT_DEBUG)
145
146 option(COMPILER_RT_INTERCEPT_LIBDISPATCH
147   "Support interception of libdispatch (GCD). Requires '-fblocks'" OFF)
148 option(COMPILER_RT_LIBDISPATCH_INSTALL_PATH
149   "Specify if libdispatch is installed in a custom location" "")
150 if (COMPILER_RT_INTERCEPT_LIBDISPATCH AND NOT APPLE)
151   set(COMPILER_RT_LIBDISPATCH_CFLAGS -fblocks)
152   set(COMPILER_RT_TEST_LIBDISPATCH_CFLAGS)
153   if (COMPILER_RT_LIBDISPATCH_INSTALL_PATH)
154     list(APPEND COMPILER_RT_TEST_LIBDISPATCH_CFLAGS
155         -I${COMPILER_RT_LIBDISPATCH_INSTALL_PATH}/include
156         -L${COMPILER_RT_LIBDISPATCH_INSTALL_PATH}/lib
157         -Wl,-rpath=${COMPILER_RT_LIBDISPATCH_INSTALL_PATH}/lib)
158   endif()
159   list(APPEND COMPILER_RT_TEST_LIBDISPATCH_CFLAGS -lBlocksRuntime -ldispatch)
160 endif()
161 if (APPLE) # Always enable on Apple platforms.
162   set(COMPILER_RT_INTERCEPT_LIBDISPATCH ON)
163 endif()
164 pythonize_bool(COMPILER_RT_INTERCEPT_LIBDISPATCH)
165
166 if(APPLE AND SANITIZER_MIN_OSX_VERSION AND SANITIZER_MIN_OSX_VERSION VERSION_LESS "10.9")
167   # Mac OS X prior to 10.9 had problems with exporting symbols from
168   # libc++/libc++abi.
169   set(cxxabi_supported OFF)
170 else()
171   set(cxxabi_supported ON)
172 endif()
173
174 option(SANITIZER_ALLOW_CXXABI "Allow use of C++ ABI details in ubsan" ON)
175
176 set(SANITIZE_CAN_USE_CXXABI OFF)
177 if (cxxabi_supported AND SANITIZER_ALLOW_CXXABI)
178   set(SANITIZER_CAN_USE_CXXABI ON)
179 endif()
180 pythonize_bool(SANITIZER_CAN_USE_CXXABI)
181
182 macro(handle_default_cxx_lib var)
183   # Specifying -stdlib= in CMAKE_CXX_FLAGS overrides the defaults.
184   if (CMAKE_CXX_FLAGS MATCHES "-stdlib=([a-zA-Z+]*)")
185     set(${var}_LIBNAME "${CMAKE_MATCH_1}")
186     set(${var}_SYSTEM 1)
187   elseif (${var} STREQUAL "default")
188     if (APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
189       set(${var}_LIBNAME "libc++")
190       set(${var}_SYSTEM 1)
191     elseif (FUCHSIA)
192       set(${var}_LIBNAME "libc++")
193       set(${var}_INTREE 1)
194     else()
195       set(${var}_LIBNAME "libstdc++")
196       set(${var}_SYSTEM 1)
197     endif()
198   else()
199     set(${var}_LIBNAME "${${var}}")
200     set(${var}_SYSTEM 1)
201   endif()
202 endmacro()
203
204 # This is either directly the C++ ABI library or the full C++ library
205 # which pulls in the ABI transitively.
206 set(SANITIZER_CXX_ABI "default" CACHE STRING
207     "Specify C++ ABI library to use.")
208 set(CXXABIS none default libstdc++ libc++ libcxxabi)
209 set_property(CACHE SANITIZER_CXX_ABI PROPERTY STRINGS ;${CXXABIS})
210 handle_default_cxx_lib(SANITIZER_CXX_ABI)
211
212 # This needs to be a full C++ library for linking gtest and unit tests.
213 set(SANITIZER_TEST_CXX "default" CACHE STRING
214     "Specify C++ library to use for tests.")
215 set(CXXLIBS none default libstdc++ libc++)
216 set_property(CACHE SANITIZER_TEST_CXX PROPERTY STRINGS ;${CXXLIBS})
217 handle_default_cxx_lib(SANITIZER_TEST_CXX)
218
219 set(DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER OFF)
220 if (FUCHSIA)
221   set(DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER ON)
222 elseif (DEFINED LIBUNWIND_ENABLE_SHARED AND NOT LIBUNWIND_ENABLE_SHARED)
223   set(DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER ON)
224 endif()
225
226 option(SANITIZER_USE_STATIC_LLVM_UNWINDER
227   "Use static LLVM unwinder." ${DEFAULT_SANITIZER_USE_STATIC_LLVM_UNWINDER})
228
229 set(DEFAULT_SANITIZER_USE_STATIC_CXX_ABI OFF)
230 if (DEFINED LIBCXXABI_ENABLE_SHARED AND NOT LIBCXXABI_ENABLE_SHARED)
231   set(DEFAULT_SANITIZER_USE_STATIC_CXX_ABI ON)
232 endif()
233
234 option(SANITIZER_USE_STATIC_CXX_ABI
235   "Use static libc++abi." ${DEFAULT_SANITIZER_USE_STATIC_CXX_ABI})
236
237 set(DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY OFF)
238 if (FUCHSIA)
239   set(DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY ON)
240 endif()
241
242 option(COMPILER_RT_USE_BUILTINS_LIBRARY
243   "Use compiler-rt builtins instead of libgcc" ${DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY})
244
245 include(config-ix)
246
247 #================================
248 # Setup Compiler Flags
249 #================================
250
251 if(MSVC)
252   # Override any existing /W flags with /W4. This is what LLVM does.  Failing to
253   # remove other /W[0-4] flags will result in a warning about overriding a
254   # previous flag.
255   if (COMPILER_RT_HAS_W4_FLAG)
256     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
257     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
258     append_string_if(COMPILER_RT_HAS_W4_FLAG /W4 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
259   endif()
260 else()
261   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
262 endif()
263 if(COMPILER_RT_ENABLE_WERROR)
264   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
265   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
266 endif()
267
268 append_string_if(COMPILER_RT_HAS_STD_CXX14_FLAG -std=c++14 CMAKE_CXX_FLAGS)
269
270 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
271 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
272   add_definitions(-D__func__=__FUNCTION__)
273 endif()
274
275 # Provide some common commmandline flags for Sanitizer runtimes.
276 if("${ANDROID_API_LEVEL}" GREATER_EQUAL 28)
277   list(APPEND SANITIZER_COMMON_CFLAGS -fno-emulated-tls)
278   string(APPEND COMPILER_RT_TEST_COMPILER_CFLAGS " -fno-emulated-tls")
279 endif()
280 if(NOT WIN32)
281   append_list_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
282 endif()
283 append_list_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
284 append_list_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
285 if(NOT COMPILER_RT_DEBUG AND NOT APPLE)
286   append_list_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
287 endif()
288 append_list_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
289 append_list_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
290 append_list_if(COMPILER_RT_HAS_FNO_SANITIZE_SAFE_STACK_FLAG -fno-sanitize=safe-stack SANITIZER_COMMON_CFLAGS)
291 append_list_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
292 if(NOT COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG)
293   append_list_if(COMPILER_RT_HAS_FVISIBILITY_INLINES_HIDDEN_FLAG -fvisibility-inlines-hidden SANITIZER_COMMON_CFLAGS)
294 endif()
295 append_list_if(COMPILER_RT_HAS_FNO_LTO_FLAG -fno-lto SANITIZER_COMMON_CFLAGS)
296
297 # By default do not instrument or use profdata for compiler-rt.
298 if(NOT COMPILER_RT_ENABLE_PGO)
299   if(LLVM_PROFDATA_FILE AND COMPILER_RT_HAS_FNO_PROFILE_INSTR_USE_FLAG)
300     list(APPEND SANITIZER_COMMON_CFLAGS "-fno-profile-instr-use")
301   endif()
302   if(LLVM_BUILD_INSTRUMENTED MATCHES IR AND COMPILER_RT_HAS_FNO_PROFILE_GENERATE_FLAG)
303     list(APPEND SANITIZER_COMMON_CFLAGS "-fno-profile-generate")
304   elseif(LLVM_BUILD_INSTRUMENTED AND COMPILER_RT_HAS_FNO_PROFILE_INSTR_GENERATE_FLAG)
305     list(APPEND SANITIZER_COMMON_CFLAGS "-fno-profile-instr-generate")
306   endif()
307 endif()
308
309 # The following is a workaround for powerpc64le. This is the only architecture
310 # that requires -fno-function-sections to work properly. If lacking, the ASan
311 # Linux test function-sections-are-bad.cpp fails with the following error:
312 # 'undefined symbol: __sanitizer_unaligned_load32'.
313 if(DEFINED TARGET_powerpc64le_CFLAGS)
314   if(CMAKE_CXX_COMPILER_ID MATCHES "XL")
315     append("-qnofuncsect" TARGET_powerpc64le_CFLAGS)
316   else()
317     append_list_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections TARGET_powerpc64le_CFLAGS)
318   endif()
319 endif()
320
321 # The following is a workaround for s390x.  This avoids creation of "partial
322 # inline" function fragments when building the asan libraries with certain
323 # GCC versions.  The presence of those fragments, in particular for the
324 # interceptors, changes backtraces seen in asan error cases, which causes
325 # testsuite failures.
326 if("${COMPILER_RT_DEFAULT_TARGET_ARCH}" MATCHES "s390x")
327   append_list_if(COMPILER_RT_HAS_FNO_PARTIAL_INLINING_FLAG -fno-partial-inlining SANITIZER_COMMON_CFLAGS)
328 endif()
329
330 if(MSVC)
331   # Replace the /M[DT][d] flags with /MT, and strip any definitions of _DEBUG,
332   # which cause definition mismatches at link time.
333   # FIXME: In fact, sanitizers should support both /MT and /MD, see PR20214.
334   if(COMPILER_RT_HAS_MT_FLAG)
335     foreach(flag_var
336       CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
337       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
338       CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
339       CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
340       string(REGEX REPLACE "/M[DT]d" "/MT" ${flag_var} "${${flag_var}}")
341       string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
342       string(REGEX REPLACE "/D_DEBUG" "" ${flag_var} "${${flag_var}}")
343     endforeach()
344   endif()
345   append_list_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
346   append_list_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
347
348   # Disable thread safe initialization for static locals. ASan shouldn't need
349   # it. Thread safe initialization assumes that the CRT has already been
350   # initialized, but ASan initializes before the CRT.
351   list(APPEND SANITIZER_COMMON_CFLAGS /Zc:threadSafeInit-)
352 endif()
353
354 append_list_if(COMPILER_RT_DEBUG -DSANITIZER_DEBUG=1 SANITIZER_COMMON_CFLAGS)
355
356 # If we're using MSVC,
357 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
358 if (NOT MSVC)
359
360   # Build with optimization, unless we're in debug mode.
361   if(COMPILER_RT_DEBUG)
362     list(APPEND SANITIZER_COMMON_CFLAGS -O0)
363   else()
364     list(APPEND SANITIZER_COMMON_CFLAGS -O3)
365   endif()
366 endif()
367
368 # Determine if we should restrict stack frame sizes.
369 # Stack frames on PowerPC, Mips, SystemZ and in debug build can be much larger than
370 # anticipated.
371 # FIXME: Fix all sanitizers and add -Wframe-larger-than to
372 # SANITIZER_COMMON_FLAGS
373 if(COMPILER_RT_HAS_WFRAME_LARGER_THAN_FLAG AND NOT COMPILER_RT_DEBUG
374    AND NOT ${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "powerpc|mips|s390x")
375   set(SANITIZER_LIMIT_FRAME_SIZE TRUE)
376 else()
377   set(SANITIZER_LIMIT_FRAME_SIZE FALSE)
378 endif()
379
380 if(FUCHSIA OR UNIX)
381   set(SANITIZER_USE_SYMBOLS TRUE)
382 else()
383   set(SANITIZER_USE_SYMBOLS FALSE)
384 endif()
385
386 # Build sanitizer runtimes with debug info.
387 if(MSVC)
388   # Use /Z7 instead of /Zi for the asan runtime. This avoids the LNK4099
389   # warning from the MS linker complaining that it can't find the 'vc140.pdb'
390   # file used by our object library compilations.
391   list(APPEND SANITIZER_COMMON_CFLAGS /Z7)
392   foreach(var_to_update
393     CMAKE_CXX_FLAGS
394     CMAKE_CXX_FLAGS_DEBUG
395     CMAKE_CXX_FLAGS_RELWITHDEBINFO)
396     string(REGEX REPLACE "(^| )/Z[i7I]($| )" " /Z7 "
397            "${var_to_update}" "${${var_to_update}}")
398   endforeach()
399 elseif(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG AND NOT COMPILER_RT_DEBUG)
400   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
401 elseif(COMPILER_RT_HAS_G_FLAG)
402   list(APPEND SANITIZER_COMMON_CFLAGS -g)
403 endif()
404
405 if(LLVM_ENABLE_MODULES)
406   # Sanitizers cannot be built with -fmodules. The interceptors intentionally
407   # don't include system headers, which is incompatible with modules.
408   list(APPEND SANITIZER_COMMON_CFLAGS -fno-modules)
409 endif()
410
411 # Turn off several warnings.
412 append_list_if(COMPILER_RT_HAS_WGNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
413 append_list_if(COMPILER_RT_HAS_WVARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
414 append_list_if(COMPILER_RT_HAS_WC99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
415 append_list_if(COMPILER_RT_HAS_WD4146_FLAG /wd4146 SANITIZER_COMMON_CFLAGS)
416 append_list_if(COMPILER_RT_HAS_WD4291_FLAG /wd4291 SANITIZER_COMMON_CFLAGS)
417 append_list_if(COMPILER_RT_HAS_WD4391_FLAG /wd4391 SANITIZER_COMMON_CFLAGS)
418 append_list_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
419 append_list_if(COMPILER_RT_HAS_WD4800_FLAG /wd4800 SANITIZER_COMMON_CFLAGS)
420
421 append_list_if(MINGW -fms-extensions SANITIZER_COMMON_CFLAGS)
422
423 # Set common link flags.
424 append_list_if(COMPILER_RT_HAS_NODEFAULTLIBS_FLAG -nodefaultlibs SANITIZER_COMMON_LINK_FLAGS)
425 append_list_if(COMPILER_RT_HAS_Z_TEXT -Wl,-z,text SANITIZER_COMMON_LINK_FLAGS)
426
427 if (COMPILER_RT_USE_BUILTINS_LIBRARY)
428   string(REPLACE "-Wl,-z,defs" "" CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS}")
429 else()
430   if (ANDROID)
431     append_list_if(COMPILER_RT_HAS_GCC_LIB gcc SANITIZER_COMMON_LINK_LIBS)
432   else()
433     append_list_if(COMPILER_RT_HAS_GCC_S_LIB gcc_s SANITIZER_COMMON_LINK_LIBS)
434   endif()
435 endif()
436
437 append_list_if(COMPILER_RT_HAS_LIBC c SANITIZER_COMMON_LINK_LIBS)
438
439 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Fuchsia")
440   list(APPEND SANITIZER_COMMON_LINK_FLAGS -Wl,-z,defs,-z,now,-z,relro)
441   list(APPEND SANITIZER_COMMON_LINK_LIBS zircon)
442 endif()
443
444 # TODO: COMPILER_RT_COMMON_CFLAGS and COMPILER_RT_COMMON_LINK_FLAGS are
445 # intended for use in non-sanitizer runtimes such as libFuzzer, profile or XRay,
446 # move these higher to include common flags, then derive SANITIZER_COMMON_CFLAGS
447 # and SANITIZER_COMMON_LINK_FLAGS from those and append sanitizer-specific flags.
448 set(COMPILER_RT_COMMON_CFLAGS ${SANITIZER_COMMON_CFLAGS})
449 set(COMPILER_RT_COMMON_LINK_FLAGS ${SANITIZER_COMMON_LINK_FLAGS})
450
451 # We don't use the C++ standard library, so avoid including it by mistake.
452 append_list_if(COMPILER_RT_HAS_NOSTDINCXX_FLAG -nostdinc++ SANITIZER_COMMON_CFLAGS)
453 append_list_if(COMPILER_RT_HAS_NOSTDLIBXX_FLAG -nostdlib++ SANITIZER_COMMON_LINK_FLAGS)
454
455 # Remove -stdlib= which is unused when passing -nostdinc++...
456 string(REGEX MATCHALL "-stdlib=[a-zA-Z+]*" stdlib_flag "${CMAKE_CXX_FLAGS}")
457 string(REGEX REPLACE "-stdlib=[a-zA-Z+]*" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
458
459 # ...we need it to build some runtimes and tests so readd it where appropriate.
460 list(APPEND COMPILER_RT_COMMON_CFLAGS ${stdlib_flag})
461 list(APPEND COMPILER_RT_COMMON_LINK_FLAGS ${stdlib_flag})
462
463 macro(append_libcxx_libs var)
464   if (${var}_INTREE)
465     if (SANITIZER_USE_STATIC_LLVM_UNWINDER AND (TARGET unwind_static OR HAVE_LIBUNWIND))
466       list(APPEND ${var}_LIBRARIES unwind_static)
467     elseif (TARGET unwind_shared OR HAVE_LIBUNWIND)
468       list(APPEND ${var}_LIBRARIES unwind_shared)
469     endif()
470
471     if (SANITIZER_USE_STATIC_CXX_ABI AND (TARGET cxxabi_static OR HAVE_LIBCXXABI))
472       list(APPEND ${var}_LIBRARIES cxxabi_static)
473     elseif (TARGET cxxabi_shared OR HAVE_LIBCXXABI)
474       list(APPEND ${var}_LIBRARIES cxxabi_shared)
475     endif()
476   else()
477     append_list_if(COMPILER_RT_HAS_LIBCXX c++ ${var}_LIBRARIES)
478   endif()
479 endmacro()
480
481 if (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libc++")
482   append_libcxx_libs(SANITIZER_CXX_ABI)
483 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libcxxabi")
484   list(APPEND SANITIZER_CXX_ABI_LIBRARIES "c++abi")
485 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libstdc++")
486   append_list_if(COMPILER_RT_HAS_LIBSTDCXX stdc++ SANITIZER_CXX_ABI_LIBRARIES)
487 endif()
488
489 if (SANITIZER_TEST_CXX_LIBNAME STREQUAL "libc++")
490   append_libcxx_libs(SANITIZER_TEST_CXX)
491 elseif (SANITIZER_TEST_CXX_LIBNAME STREQUAL "libstdc++")
492   append_list_if(COMPILER_RT_HAS_LIBSTDCXX stdc++ SANITIZER_TEST_CXX_LIBRARIES)
493 endif()
494
495 # TODO: There's a lot of duplication across lib/*/tests/CMakeLists.txt files,
496 # move some of the common flags to COMPILER_RT_UNITTEST_CFLAGS.
497
498 # Unittests need access to C++ standard library.
499 string(APPEND COMPILER_RT_TEST_COMPILER_CFLAGS " ${stdlib_flag}")
500
501 # When cross-compiling, COMPILER_RT_TEST_COMPILER_CFLAGS help in compilation
502 # and linking of unittests.
503 string(REPLACE " " ";" COMPILER_RT_UNITTEST_CFLAGS "${COMPILER_RT_TEST_COMPILER_CFLAGS}")
504 set(COMPILER_RT_UNITTEST_LINK_FLAGS ${COMPILER_RT_UNITTEST_CFLAGS})
505
506 # Unittests support.
507 set(COMPILER_RT_GTEST_PATH ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest)
508 set(COMPILER_RT_GTEST_SOURCE ${COMPILER_RT_GTEST_PATH}/src/gtest-all.cc)
509 set(COMPILER_RT_GTEST_CFLAGS
510   -DGTEST_NO_LLVM_SUPPORT=1
511   -DGTEST_HAS_RTTI=0
512   -I${COMPILER_RT_GTEST_PATH}/include
513   -I${COMPILER_RT_GTEST_PATH}
514 )
515
516 # Mocking support.
517 set(COMPILER_RT_GMOCK_PATH ${LLVM_MAIN_SRC_DIR}/utils/unittest/googlemock)
518 set(COMPILER_RT_GMOCK_SOURCE ${COMPILER_RT_GMOCK_PATH}/src/gmock-all.cc)
519 set(COMPILER_RT_GMOCK_CFLAGS
520   -DGTEST_NO_LLVM_SUPPORT=1
521   -DGTEST_HAS_RTTI=0
522   -I${COMPILER_RT_GMOCK_PATH}/include
523   -I${COMPILER_RT_GMOCK_PATH}
524 )
525
526 append_list_if(COMPILER_RT_DEBUG -DSANITIZER_DEBUG=1 COMPILER_RT_UNITTEST_CFLAGS)
527 append_list_if(COMPILER_RT_HAS_WCOVERED_SWITCH_DEFAULT_FLAG -Wno-covered-switch-default COMPILER_RT_UNITTEST_CFLAGS)
528 append_list_if(COMPILER_RT_HAS_WSUGGEST_OVERRIDE_FLAG -Wno-suggest-override COMPILER_RT_UNITTEST_CFLAGS)
529
530 if(MSVC)
531   # gtest use a lot of stuff marked as deprecated on Windows.
532   list(APPEND COMPILER_RT_GTEST_CFLAGS -Wno-deprecated-declarations)
533 endif()
534
535 # Warnings to turn off for all libraries, not just sanitizers.
536 append_string_if(COMPILER_RT_HAS_WUNUSED_PARAMETER_FLAG -Wno-unused-parameter CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
537
538 if (CMAKE_LINKER MATCHES "link.exe$")
539   # Silence MSVC linker warnings caused by empty object files. The
540   # sanitizer libraries intentionally use ifdefs that result in empty
541   # files, rather than skipping these files in the build system.
542   # Ideally, we would pass this flag only for the libraries that need
543   # it, but CMake doesn't seem to have a way to set linker flags for
544   # individual static libraries, so we enable the suppression flag for
545   # the whole compiler-rt project.
546   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
547 endif()
548
549 if(${CMAKE_SYSTEM_NAME} MATCHES "AIX")
550   set(CMAKE_C_ARCHIVE_CREATE "<CMAKE_AR> -X32_64 qc <TARGET> <LINK_FLAGS> <OBJECTS>")
551   set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> -X32_64 qc <TARGET> <LINK_FLAGS> <OBJECTS>")
552   set(CMAKE_C_ARCHIVE_APPEND "<CMAKE_AR> -X32_64 q <TARGET> <LINK_FLAGS> <OBJECTS>")
553   set(CMAKE_CXX_ARCHIVE_APPEND "<CMAKE_AR> -X32_64 q <TARGET> <LINK_FLAGS> <OBJECTS>")
554   set(CMAKE_C_ARCHIVE_FINISH "<CMAKE_RANLIB> -X32_64 <TARGET>")
555   set(CMAKE_CXX_ARCHIVE_FINISH "<CMAKE_RANLIB> -X32_64 <TARGET>")
556 endif()
557
558 add_subdirectory(include)
559
560 option(COMPILER_RT_USE_LIBCXX
561   "Enable compiler-rt to use libc++ from the source tree" ON)
562 if(COMPILER_RT_USE_LIBCXX)
563   if(LLVM_ENABLE_PROJECTS_USED)
564     # Don't use libcxx if LLVM_ENABLE_PROJECTS does not enable it.
565     set(COMPILER_RT_LIBCXX_PATH ${LLVM_EXTERNAL_LIBCXX_SOURCE_DIR})
566     set(COMPILER_RT_LIBCXXABI_PATH ${LLVM_EXTERNAL_LIBCXXABI_SOURCE_DIR})
567   else()
568     foreach(path IN ITEMS ${LLVM_MAIN_SRC_DIR}/projects/libcxx
569                           ${LLVM_MAIN_SRC_DIR}/runtimes/libcxx
570                           ${LLVM_MAIN_SRC_DIR}/../libcxx
571                           ${LLVM_EXTERNAL_LIBCXX_SOURCE_DIR})
572       if(IS_DIRECTORY ${path})
573         set(COMPILER_RT_LIBCXX_PATH ${path})
574         break()
575       endif()
576     endforeach()
577     foreach(path IN ITEMS ${LLVM_MAIN_SRC_DIR}/projects/libcxxabi
578                           ${LLVM_MAIN_SRC_DIR}/runtimes/libcxxabi
579                           ${LLVM_MAIN_SRC_DIR}/../libcxxabi
580                           ${LLVM_EXTERNAL_LIBCXXABI_SOURCE_DIR})
581       if(IS_DIRECTORY ${path})
582         set(COMPILER_RT_LIBCXXABI_PATH ${path})
583         break()
584       endif()
585     endforeach()
586   endif()
587 endif()
588
589 set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/tools/lld)
590 if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
591   set(COMPILER_RT_HAS_LLD TRUE)
592 else()
593   set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/../lld)
594   if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
595     set(COMPILER_RT_HAS_LLD TRUE)
596   endif()
597 endif()
598
599 if(ANDROID)
600   set(COMPILER_RT_HAS_LLD TRUE)
601   set(COMPILER_RT_TEST_USE_LLD TRUE)
602   append_list_if(COMPILER_RT_HAS_FUSE_LD_LLD_FLAG -fuse-ld=lld SANITIZER_COMMON_LINK_FLAGS)
603   append_list_if(COMPILER_RT_HAS_LLD -fuse-ld=lld COMPILER_RT_UNITTEST_LINK_FLAGS)
604   if(COMPILER_RT_HAS_FUSE_LD_LLD_FLAG)
605     set(COMPILER_RT_HAS_GNU_VERSION_SCRIPT_COMPAT FALSE)
606   endif()
607 endif()
608 pythonize_bool(COMPILER_RT_HAS_LLD)
609 pythonize_bool(COMPILER_RT_TEST_USE_LLD)
610
611 add_subdirectory(lib)
612
613 if(COMPILER_RT_INCLUDE_TESTS)
614   add_subdirectory(unittests)
615   add_subdirectory(test)
616   # Don't build llvm-lit for runtimes-build, it will clean up map_config.
617   if (COMPILER_RT_STANDALONE_BUILD AND NOT RUNTIMES_BUILD)
618     # If we have a valid source tree, generate llvm-lit into the bin directory.
619     # The user can still choose to have the check targets *use* a different lit
620     # by specifying -DLLVM_EXTERNAL_LIT, but we generate it regardless.
621     if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
622       # Needed for lit support in standalone builds.
623       include(AddLLVM)
624       add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit ${CMAKE_CURRENT_BINARY_DIR}/llvm-lit)
625     elseif(NOT EXISTS ${LLVM_EXTERNAL_LIT})
626       message(WARNING "Could not find LLVM source directory and LLVM_EXTERNAL_LIT does not"
627                        "point to a valid file.  You will not be able to run tests.")
628     endif()
629   endif()
630 endif()
631
632 add_subdirectory(tools)