libcxxabi/cmake/config-ix.cmake

   1 include(CMakePushCheckState)
   2 include(CheckLibraryExists)
   3 include(CheckCCompilerFlag)
   4 include(CheckCXXCompilerFlag)
   5 include(CheckCSourceCompiles)
   6
   7 check_library_exists(c fopen "" LIBCXXABI_HAS_C_LIB)
   8 if (NOT LIBCXXABI_USE_COMPILER_RT)
   9   if (ANDROID)
  10     check_library_exists(gcc __gcc_personality_v0 "" LIBCXXABI_HAS_GCC_LIB)
  11   else ()
  12     check_library_exists(gcc_s __gcc_personality_v0 "" LIBCXXABI_HAS_GCC_S_LIB)
  13     check_library_exists(gcc __aeabi_uldivmod "" LIBCXXABI_HAS_GCC_LIB)
  14   endif ()
  15 endif ()
  16
  17 # libc++abi is using -nostdlib++ at the link step when available,
  18 # otherwise -nodefaultlibs is used. We want all our checks to also
  19 # use one of these options, otherwise we may end up with an inconsistency between
  20 # the flags we think we require during configuration (if the checks are
  21 # performed without -nodefaultlibs) and the flags that are actually
  22 # required during compilation (which has the -nodefaultlibs). libc is
  23 # required for the link to go through. We remove sanitizers from the
  24 # configuration checks to avoid spurious link errors.
  25
  26 check_c_compiler_flag(-nostdlib++ LIBCXXABI_SUPPORTS_NOSTDLIBXX_FLAG)
  27 if (LIBCXXABI_SUPPORTS_NOSTDLIBXX_FLAG)
  28   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nostdlib++")
  29 else()
  30   check_c_compiler_flag(-nodefaultlibs LIBCXXABI_SUPPORTS_NODEFAULTLIBS_FLAG)
  31   if (LIBCXXABI_SUPPORTS_NODEFAULTLIBS_FLAG)
  32     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nodefaultlibs")
  33   endif()
  34 endif()
  35
  36 if (LIBCXXABI_SUPPORTS_NOSTDLIBXX_FLAG OR LIBCXXABI_SUPPORTS_NODEFAULTLIBS_FLAG)
  37   if (LIBCXXABI_HAS_C_LIB)
  38     list(APPEND CMAKE_REQUIRED_LIBRARIES c)
  39   endif ()
  40   if (LIBCXXABI_USE_COMPILER_RT)
  41     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -rtlib=compiler-rt")
  42     find_compiler_rt_library(builtins LIBCXXABI_BUILTINS_LIBRARY)
  43     list(APPEND CMAKE_REQUIRED_LIBRARIES "${LIBCXXABI_BUILTINS_LIBRARY}")
  44   else ()
  45     if (LIBCXXABI_HAS_GCC_S_LIB)
  46       list(APPEND CMAKE_REQUIRED_LIBRARIES gcc_s)
  47     endif ()
  48     if (LIBCXXABI_HAS_GCC_LIB)
  49       list(APPEND CMAKE_REQUIRED_LIBRARIES gcc)
  50     endif ()
  51   endif ()
  52   if (MINGW)
  53     # Mingw64 requires quite a few "C" runtime libraries in order for basic
  54     # programs to link successfully with -nodefaultlibs.
  55     if (LIBCXXABI_USE_COMPILER_RT)
  56       set(MINGW_RUNTIME ${LIBCXXABI_BUILTINS_LIBRARY})
  57     else ()
  58       set(MINGW_RUNTIME gcc_s gcc)
  59     endif()
  60     set(MINGW_LIBRARIES mingw32 ${MINGW_RUNTIME} moldname mingwex msvcrt advapi32
  61                         shell32 user32 kernel32 mingw32 ${MINGW_RUNTIME}
  62                         moldname mingwex msvcrt)
  63     list(APPEND CMAKE_REQUIRED_LIBRARIES ${MINGW_LIBRARIES})
  64   endif()
  65   if (CMAKE_C_FLAGS MATCHES -fsanitize OR CMAKE_CXX_FLAGS MATCHES -fsanitize)
  66     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-sanitize=all")
  67   endif ()
  68   if (CMAKE_C_FLAGS MATCHES -fsanitize-coverage OR CMAKE_CXX_FLAGS MATCHES -fsanitize-coverage)
  69     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-sanitize-coverage=edge,trace-cmp,indirect-calls,8bit-counters")
  70   endif ()
  71 endif ()
  72
  73 # Check compiler pragmas
  74 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  75   cmake_push_check_state()
  76   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unknown-pragmas")
  77   check_c_source_compiles("
  78 #pragma comment(lib, \"c\")
  79 int main() { return 0; }
  80 " LIBCXXABI_HAS_COMMENT_LIB_PRAGMA)
  81   cmake_pop_check_state()
  82 endif()
  83
  84 # Check compiler flags
  85 check_cxx_compiler_flag(-nostdinc++ LIBCXXABI_HAS_NOSTDINCXX_FLAG)
  86
  87 # Check libraries
  88 if(FUCHSIA)
  89   set(LIBCXXABI_HAS_DL_LIB NO)
  90   set(LIBCXXABI_HAS_PTHREAD_LIB NO)
  91   check_library_exists(c __cxa_thread_atexit_impl ""
  92     LIBCXXABI_HAS_CXA_THREAD_ATEXIT_IMPL)
  93   set(LIBCXXABI_HAS_SYSTEM_LIB NO)
  94 else()
  95   check_library_exists(dl dladdr "" LIBCXXABI_HAS_DL_LIB)
  96   check_library_exists(pthread pthread_once "" LIBCXXABI_HAS_PTHREAD_LIB)
  97   check_library_exists(c __cxa_thread_atexit_impl ""
  98     LIBCXXABI_HAS_CXA_THREAD_ATEXIT_IMPL)
  99   check_library_exists(System write "" LIBCXXABI_HAS_SYSTEM_LIB)
 100 endif()