test commit. update comment grammatically. NFC
[lldb.git] / libunwind / CMakeLists.txt
1 #===============================================================================
2 # Setup Project
3 #===============================================================================
4
5 cmake_minimum_required(VERSION 2.8.8)
6
7 if (POLICY CMP0042)
8   cmake_policy(SET CMP0042 NEW) # Set MACOSX_RPATH=YES by default
9 endif()
10
11 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
12   project(libunwind)
13
14   # Rely on llvm-config.
15   set(CONFIG_OUTPUT)
16   find_program(LLVM_CONFIG "llvm-config")
17   if (DEFINED LLVM_PATH)
18     set(LLVM_INCLUDE_DIR ${LLVM_INCLUDE_DIR} CACHE PATH "Path to llvm/include")
19     set(LLVM_PATH ${LLVM_PATH} CACHE PATH "Path to LLVM source tree")
20     set(LLVM_MAIN_SRC_DIR ${LLVM_PATH})
21     set(LLVM_CMAKE_PATH "${LLVM_PATH}/cmake/modules")
22   elseif (LLVM_CONFIG)
23     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
24     set(CONFIG_COMMAND ${LLVM_CONFIG} "--includedir" "--prefix" "--src-root")
25     execute_process(COMMAND ${CONFIG_COMMAND}
26                     RESULT_VARIABLE HAD_ERROR
27                     OUTPUT_VARIABLE CONFIG_OUTPUT)
28     if (NOT HAD_ERROR)
29       string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";"
30              CONFIG_OUTPUT ${CONFIG_OUTPUT})
31     else ()
32       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
33       message(STATUS "${CONFIG_COMMAND_STR}")
34       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
35     endif ()
36
37     list(GET CONFIG_OUTPUT 0 INCLUDE_DIR)
38     list(GET CONFIG_OUTPUT 1 LLVM_OBJ_ROOT)
39     list(GET CONFIG_OUTPUT 2 MAIN_SRC_DIR)
40
41     set(LLVM_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
42     set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
43     set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
44     set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
45     set(LLVM_LIT_PATH "${LLVM_PATH}/utils/lit/lit.py")
46   else ()
47     message(FATAL_ERROR "llvm-config not found and LLVM_MAIN_SRC_DIR not defined. "
48                         "Reconfigure with -DLLVM_CONFIG=path/to/llvm-config "
49                         "or -DLLVM_PATH=path/to/llvm-source-root.")
50   endif ()
51
52   if (EXISTS ${LLVM_CMAKE_PATH})
53     list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
54     include("${LLVM_CMAKE_PATH}/AddLLVM.cmake")
55     include("${LLVM_CMAKE_PATH}/HandleLLVMOptions.cmake")
56   else ()
57     message(FATAL_ERROR "Not found: ${LLVM_CMAKE_PATH}")
58   endif ()
59
60   set(PACKAGE_NAME libunwind)
61   set(PACKAGE_VERSION 3.8.0svn)
62   set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
63   set(PACKAGE_BUGREPORT "llvm-bugs@lists.llvm.org")
64
65   if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
66     set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
67   else ()
68     # Seek installed Lit.
69     find_program(LLVM_LIT "lit.py" ${LLVM_MAIN_SRC_DIR}/utils/lit
70                  DOC "Path to lit.py")
71   endif ()
72
73   if (LLVM_LIT)
74     # Define the default arguments to use with 'lit', and an option for the user
75     # to override.
76     set(LIT_ARGS_DEFAULT "-sv")
77     if (MSVC OR XCODE)
78       set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
79     endif ()
80     set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
81
82     # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
83     if (WIN32 AND NOT CYGWIN)
84       set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
85     endif ()
86   else ()
87     set(LLVM_INCLUDE_TESTS OFF)
88   endif ()
89
90   set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX})
91   set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX})
92 else()
93   set(LLVM_MAIN_SRC_DIR "${CMAKE_SOURCE_DIR}" CACHE PATH "Path to LLVM source tree")
94   set(LLVM_LIT "${CMAKE_SOURCE_DIR}/utils/lit/lit.py")
95 endif()
96
97 #===============================================================================
98 # Setup CMake Options
99 #===============================================================================
100
101 # Define options.
102 option(LIBUNWIND_BUILD_32_BITS "Build 32 bit libunwind" ${LLVM_BUILD_32_BITS})
103 option(LIBUNWIND_ENABLE_ASSERTIONS "Enable assertions independent of build mode." ON)
104 option(LIBUNWIND_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
105 option(LIBUNWIND_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
106 option(LIBUNWIND_ENABLE_SHARED "Build libunwind as a shared library." ON)
107 option(LIBUNWIND_ENABLE_CROSS_UNWINDING "Enable cross-platform unwinding support." OFF)
108 option(LIBUNWIND_ENABLE_ARM_WMMX "Enable unwinding support for ARM WMMX registers." OFF)
109
110 set(LIBUNWIND_TARGET_TRIPLE "" CACHE STRING "Target triple for cross compiling.")
111 set(LIBUNWIND_GCC_TOOLCHAIN "" CACHE PATH "GCC toolchain for cross compiling.")
112 set(LIBUNWIND_SYSROOT "" CACHE PATH "Sysroot for cross compiling.")
113
114
115 # Check that we can build with 32 bits if requested.
116 if (CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32)
117   if (LIBUNWIND_BUILD_32_BITS AND NOT LLVM_BUILD_32_BITS) # Don't duplicate the output from LLVM
118     message(STATUS "Building 32 bits executables and libraries.")
119   endif()
120 elseif(LIBUNWIND_BUILD_32_BITS)
121   message(FATAL_ERROR "LIBUNWIND_BUILD_32_BITS=ON is not supported on this platform.")
122 endif()
123
124 #===============================================================================
125 # Configure System
126 #===============================================================================
127
128 # Add path for custom modules
129 set(CMAKE_MODULE_PATH
130     "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
131     ${CMAKE_MODULE_PATH})
132
133 set(LIBUNWIND_COMPILER    ${CMAKE_CXX_COMPILER})
134 set(LIBUNWIND_SOURCE_DIR  ${CMAKE_CURRENT_SOURCE_DIR})
135 set(LIBUNWIND_BINARY_DIR  ${CMAKE_CURRENT_BINARY_DIR})
136 set(LIBUNWIND_LIBRARY_DIR ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX})
137
138 set(LIBUNWIND_C_FLAGS "")
139 set(LIBUNWIND_CXX_FLAGS "")
140 set(LIBUNWIND_COMPILE_FLAGS "")
141 set(LIBUNWIND_LINK_FLAGS "")
142
143 # Get required flags.
144 macro(append_if list condition var)
145   if (${condition})
146     list(APPEND ${list} ${var})
147   endif()
148 endmacro()
149
150 macro(add_target_flags_if condition var)
151   if (${condition})
152     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${var}")
153     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${var}")
154     list(APPEND LINUNWIND_COMPILE_FLAGS ${var})
155     list(APPEND LIBUNWIND_LINK_FLAGS ${var})
156   endif()
157 endmacro()
158
159 add_target_flags_if(LIBUNWIND_BUILD_32_BITS "-m32")
160 add_target_flags_if(LIBUNWIND_TARGET_TRIPLE
161           "-target ${LIBUNWIND_TARGET_TRIPLE}")
162 add_target_flags_if(LIBUNWIND_GCC_TOOLCHAIN
163           "-gcc-toolchain ${LIBUNWIND_GCC_TOOLCHAIN}")
164 add_target_flags_if(LIBUNWIND_SYSROOT
165           "--sysroot=${LIBUNWIND_SYSROOT}")
166
167 # Configure compiler.
168 include(config-ix)
169
170 #===============================================================================
171 # Setup Compiler Flags
172 #===============================================================================
173
174 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WERROR_FLAG -Werror=return-type)
175
176 # Get warning flags
177 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_W_FLAG -W)
178 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WALL_FLAG -Wall)
179 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WCHAR_SUBSCRIPTS_FLAG -Wchar-subscripts)
180 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WCONVERSION_FLAG -Wconversion)
181 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WMISMATCHED_TAGS_FLAG -Wmismatched-tags)
182 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WMISSING_BRACES_FLAG -Wmissing-braces)
183 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WNEWLINE_EOF_FLAG -Wnewline-eof)
184 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WNO_UNUSED_FUNCTION_FLAG -Wno-unused-function)
185 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WSHADOW_FLAG -Wshadow)
186 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WSHORTEN_64_TO_32_FLAG -Wshorten-64-to-32)
187 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WSIGN_COMPARE_FLAG -Wsign-compare)
188 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WSIGN_CONVERSION_FLAG -Wsign-conversion)
189 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WSTRICT_ALIASING_FLAG -Wstrict-aliasing=2)
190 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WSTRICT_OVERFLOW_FLAG -Wstrict-overflow=4)
191 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WUNUSED_PARAMETER_FLAG -Wunused-parameter)
192 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WUNUSED_VARIABLE_FLAG -Wunused-variable)
193 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WWRITE_STRINGS_FLAG -Wwrite-strings)
194 append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WUNDEF_FLAG -Wundef)
195
196 if (LIBUNWIND_ENABLE_WERROR)
197   append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WERROR_FLAG -Werror)
198   append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WX_FLAG -WX)
199 else()
200   append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_WNO_ERROR_FLAG -Wno-error)
201   append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_NO_WX_FLAG -WX-)
202 endif()
203
204 if (LIBUNWIND_ENABLE_PEDANTIC)
205   append_if(LIBUNWIND_COMPILE_FLAGS LIBUNWIND_HAS_PEDANTIC_FLAG -pedantic)
206 endif()
207
208 # Get feature flags.
209 # Exceptions
210 # Catches C++ exceptions only and tells the compiler to assume that extern C
211 # functions never throw a C++ exception.
212 append_if(LIBUNWIND_CXX_FLAGS LIBUNWIND_HAS_FSTRICT_ALIASING_FLAG -fstrict-aliasing)
213 append_if(LIBUNWIND_CXX_FLAGS LIBUNWIND_HAS_EHSC_FLAG -EHsc)
214
215 append_if(LIBUNWIND_C_FLAGS LIBUNWIND_HAS_FUNWIND_TABLES -funwind-tables)
216
217 # Assert
218 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
219 if (LIBUNWIND_ENABLE_ASSERTIONS)
220   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
221   if (NOT MSVC)
222     list(APPEND LIBUNWIND_COMPILE_FLAGS -D_DEBUG)
223   endif ()
224
225   # On Release builds cmake automatically defines NDEBUG, so we
226   # explicitly undefine it:
227   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
228     list(APPEND LIBUNWIND_COMPILE_FLAGS -UNDEBUG)
229   endif ()
230 else()
231   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
232     list(APPEND LIBUNWIND_COMPILE_FLAGS -DNDEBUG)
233   endif ()
234 endif ()
235
236 # Cross-unwinding
237 if (NOT LIBUNWIND_ENABLE_CROSS_UNWINDING)
238   list(APPEND LIBUNWIND_COMPILE_FLAGS -D_LIBUNWIND_IS_NATIVE_ONLY)
239 endif ()
240
241 # ARM WMMX register support
242 if (LIBUNWIND_ENABLE_ARM_WMMX)
243   # __ARM_WMMX is a compiler pre-define (as per the ACLE 2.0). Clang does not
244   # define this macro for any supported target at present. Therefore, here we
245   # provide the option to explicitly enable support for WMMX registers in the
246   # unwinder.
247   list(APPEND LIBUNWIND_COMPILE_FLAGS -D__ARM_WMMX)
248 endif ()
249
250 # This is the _ONLY_ place where add_definitions is called.
251 if (MSVC)
252   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
253 endif ()
254
255 #===============================================================================
256 # Setup Source Code
257 #===============================================================================
258
259 include_directories(include)
260
261 add_subdirectory(src)