Consider ASan messages interesting for creduce
[lldb.git] / libunwind / CMakeLists.txt
1 if (NOT IS_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}/../libcxx")
2   message(FATAL_ERROR "libunwind requires being built in a monorepo layout with libcxx available")
3 endif()
4
5 #===============================================================================
6 # Setup Project
7 #===============================================================================
8
9 cmake_minimum_required(VERSION 3.13.4)
10
11 # Add path for custom modules
12 set(CMAKE_MODULE_PATH
13   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
14   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
15   ${CMAKE_MODULE_PATH}
16   )
17
18 set(LIBUNWIND_SOURCE_DIR  ${CMAKE_CURRENT_SOURCE_DIR})
19 set(LIBUNWIND_BINARY_DIR  ${CMAKE_CURRENT_BINARY_DIR})
20 set(LIBUNWIND_LIBCXX_PATH "${CMAKE_CURRENT_LIST_DIR}/../libcxx" CACHE PATH
21         "Specify path to libc++ source.")
22
23 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR OR LIBUNWIND_STANDALONE_BUILD)
24   project(libunwind LANGUAGES C CXX ASM)
25
26   set(PACKAGE_NAME libunwind)
27   set(PACKAGE_VERSION 12.0.0git)
28   set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
29   set(PACKAGE_BUGREPORT "llvm-bugs@lists.llvm.org")
30
31   # Add the CMake module path of libcxx so we can reuse HandleOutOfTreeLLVM.cmake
32   set(LIBUNWIND_LIBCXX_CMAKE_PATH "${LIBUNWIND_LIBCXX_PATH}/cmake/Modules")
33   list(APPEND CMAKE_MODULE_PATH "${LIBUNWIND_LIBCXX_CMAKE_PATH}")
34
35   # In a standalone build, we don't have llvm to automatically generate the
36   # llvm-lit script for us.  So we need to provide an explicit directory that
37   # the configurator should write the script into.
38   set(LIBUNWIND_STANDALONE_BUILD 1)
39   set(LLVM_LIT_OUTPUT_DIR "${LIBUNWIND_BINARY_DIR}/bin")
40
41   # Find the LLVM sources and simulate LLVM CMake options.
42   include(HandleOutOfTreeLLVM)
43 else()
44   set(LLVM_LIT "${CMAKE_SOURCE_DIR}/utils/lit/lit.py")
45 endif()
46
47 #===============================================================================
48 # Setup CMake Options
49 #===============================================================================
50 include(CMakeDependentOption)
51 include(HandleCompilerRT)
52
53 # Define options.
54 option(LIBUNWIND_BUILD_32_BITS "Build 32 bit libunwind" ${LLVM_BUILD_32_BITS})
55 option(LIBUNWIND_ENABLE_ASSERTIONS "Enable assertions independent of build mode." ON)
56 option(LIBUNWIND_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
57 option(LIBUNWIND_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
58 option(LIBUNWIND_ENABLE_SHARED "Build libunwind as a shared library." ON)
59 option(LIBUNWIND_ENABLE_STATIC "Build libunwind as a static library." ON)
60 option(LIBUNWIND_ENABLE_CROSS_UNWINDING "Enable cross-platform unwinding support." OFF)
61 option(LIBUNWIND_ENABLE_ARM_WMMX "Enable unwinding support for ARM WMMX registers." OFF)
62 option(LIBUNWIND_ENABLE_THREADS "Build libunwind with threading support." ON)
63 option(LIBUNWIND_WEAK_PTHREAD_LIB "Use weak references to refer to pthread functions." OFF)
64 option(LIBUNWIND_USE_COMPILER_RT "Use compiler-rt instead of libgcc" OFF)
65 option(LIBUNWIND_INCLUDE_DOCS "Build the libunwind documentation." ${LLVM_INCLUDE_DOCS})
66 option(LIBUNWIND_IS_BAREMETAL "Build libunwind for baremetal targets." OFF)
67 option(LIBUNWIND_USE_FRAME_HEADER_CACHE "Cache frame headers for unwinding. Requires locking dl_iterate_phdr." OFF)
68 option(LIBUNWIND_REMEMBER_HEAP_ALLOC "Use heap instead of the stack for .cfi_remember_state." OFF)
69
70 set(LIBUNWIND_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}" CACHE STRING
71     "Define suffix of library directory name (32/64)")
72 option(LIBUNWIND_INSTALL_LIBRARY "Install the libunwind library." ON)
73 cmake_dependent_option(LIBUNWIND_INSTALL_STATIC_LIBRARY
74   "Install the static libunwind library." ON
75   "LIBUNWIND_ENABLE_STATIC;LIBUNWIND_INSTALL_LIBRARY" OFF)
76 cmake_dependent_option(LIBUNWIND_INSTALL_SHARED_LIBRARY
77   "Install the shared libunwind library." ON
78   "LIBUNWIND_ENABLE_SHARED;LIBUNWIND_INSTALL_LIBRARY" OFF)
79 set(LIBUNWIND_TARGET_TRIPLE "" CACHE STRING "Target triple for cross compiling.")
80 set(LIBUNWIND_GCC_TOOLCHAIN "" CACHE PATH "GCC toolchain for cross compiling.")
81 set(LIBUNWIND_SYSROOT "" CACHE PATH "Sysroot for cross compiling.")
82 set(LIBUNWIND_TEST_LINKER_FLAGS "" CACHE STRING
83     "Additional linker flags for test programs.")
84 set(LIBUNWIND_TEST_COMPILER_FLAGS "" CACHE STRING
85     "Additional compiler flags for test programs.")
86 set(LIBUNWIND_TEST_CONFIG "${CMAKE_CURRENT_SOURCE_DIR}/test/lit.site.cfg.in" CACHE STRING
87     "The Lit testing configuration to use when running the tests.")
88 set(LIBUNWIND_TEST_PARAMS "" CACHE STRING
89     "A list of parameters to run the Lit test suite with.")
90
91 if (NOT LIBUNWIND_ENABLE_SHARED AND NOT LIBUNWIND_ENABLE_STATIC)
92   message(FATAL_ERROR "libunwind must be built as either a shared or static library.")
93 endif()
94
95 # Check that we can build with 32 bits if requested.
96 if (CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32)
97   if (LIBUNWIND_BUILD_32_BITS AND NOT LLVM_BUILD_32_BITS) # Don't duplicate the output from LLVM
98     message(STATUS "Building 32 bits executables and libraries.")
99   endif()
100 elseif(LIBUNWIND_BUILD_32_BITS)
101   message(FATAL_ERROR "LIBUNWIND_BUILD_32_BITS=ON is not supported on this platform.")
102 endif()
103
104 option(LIBUNWIND_HERMETIC_STATIC_LIBRARY
105   "Do not export any symbols from the static library." OFF)
106
107 #===============================================================================
108 # Configure System
109 #===============================================================================
110
111 # Add path for custom modules
112 set(CMAKE_MODULE_PATH
113     "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
114     ${CMAKE_MODULE_PATH})
115
116 if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
117   set(LIBUNWIND_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/${LLVM_DEFAULT_TARGET_TRIPLE}/c++)
118   set(LIBUNWIND_INSTALL_LIBRARY_DIR lib${LLVM_LIBDIR_SUFFIX}/${LLVM_DEFAULT_TARGET_TRIPLE}/c++)
119   if(LIBCXX_LIBDIR_SUBDIR)
120     string(APPEND LIBUNWIND_LIBRARY_DIR /${LIBUNWIND_LIBDIR_SUBDIR})
121     string(APPEND LIBUNWIND_INSTALL_LIBRARY_DIR /${LIBUNWIND_LIBDIR_SUBDIR})
122   endif()
123 elseif(LLVM_LIBRARY_OUTPUT_INTDIR)
124   set(LIBUNWIND_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
125   set(LIBUNWIND_INSTALL_LIBRARY_DIR lib${LIBUNWIND_LIBDIR_SUFFIX})
126 else()
127   set(LIBUNWIND_LIBRARY_DIR ${CMAKE_BINARY_DIR}/lib${LIBUNWIND_LIBDIR_SUFFIX})
128   set(LIBUNWIND_INSTALL_LIBRARY_DIR lib${LIBUNWIND_LIBDIR_SUFFIX})
129 endif()
130
131 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
132 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
133 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
134
135 set(LIBUNWIND_INSTALL_PREFIX "" CACHE STRING "Define libunwind destination prefix.")
136
137 set(LIBUNWIND_C_FLAGS "")
138 set(LIBUNWIND_CXX_FLAGS "")
139 set(LIBUNWIND_COMPILE_FLAGS "")
140 set(LIBUNWIND_LINK_FLAGS "")
141
142 # Include macros for adding and removing libunwind flags.
143 include(HandleLibunwindFlags)
144
145 #===============================================================================
146 # Setup Compiler Flags
147 #===============================================================================
148
149 # Get required flags.
150 add_target_flags_if(LIBUNWIND_BUILD_32_BITS "-m32")
151
152 if(LIBUNWIND_TARGET_TRIPLE)
153   add_target_flags("--target=${LIBUNWIND_TARGET_TRIPLE}")
154 elseif(CMAKE_CXX_COMPILER_TARGET)
155   set(LIBUNWIND_TARGET_TRIPLE "${CMAKE_CXX_COMPILER_TARGET}")
156 endif()
157 if(LIBUNWIND_GCC_TOOLCHAIN)
158   add_target_flags("--gcc-toolchain=${LIBUNWIND_GCC_TOOLCHAIN}")
159 elseif(CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN)
160   set(LIBUNWIND_GCC_TOOLCHAIN "${CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN}")
161 endif()
162 if(LIBUNWIND_SYSROOT)
163   add_target_flags("--sysroot=${LIBUNWIND_SYSROOT}")
164 elseif(CMAKE_SYSROOT)
165   set(LIBUNWIND_SYSROOT "${CMAKE_SYSROOT}")
166 endif()
167
168 if (LIBUNWIND_TARGET_TRIPLE)
169   set(TARGET_TRIPLE "${LIBUNWIND_TARGET_TRIPLE}")
170 endif()
171
172 # Configure compiler.
173 include(config-ix)
174
175 if (LIBUNWIND_USE_COMPILER_RT AND NOT LIBUNWIND_HAS_NODEFAULTLIBS_FLAG)
176   list(APPEND LIBUNWIND_LINK_FLAGS "-rtlib=compiler-rt")
177 endif()
178
179 add_compile_flags_if_supported(-Werror=return-type)
180
181 # Get warning flags
182 add_compile_flags_if_supported(-W)
183 add_compile_flags_if_supported(-Wall)
184 add_compile_flags_if_supported(-Wchar-subscripts)
185 add_compile_flags_if_supported(-Wconversion)
186 add_compile_flags_if_supported(-Wmismatched-tags)
187 add_compile_flags_if_supported(-Wmissing-braces)
188 add_compile_flags_if_supported(-Wnewline-eof)
189 add_compile_flags_if_supported(-Wno-unused-function)
190 add_compile_flags_if_supported(-Wshadow)
191 add_compile_flags_if_supported(-Wshorten-64-to-32)
192 add_compile_flags_if_supported(-Wsign-compare)
193 add_compile_flags_if_supported(-Wsign-conversion)
194 add_compile_flags_if_supported(-Wstrict-aliasing=2)
195 add_compile_flags_if_supported(-Wstrict-overflow=4)
196 add_compile_flags_if_supported(-Wunused-parameter)
197 add_compile_flags_if_supported(-Wunused-variable)
198 add_compile_flags_if_supported(-Wwrite-strings)
199 add_compile_flags_if_supported(-Wundef)
200
201 add_compile_flags_if_supported(-Wno-suggest-override)
202
203 if (WIN32)
204   # The headers lack matching dllexport attributes (_LIBUNWIND_EXPORT);
205   # silence the warning instead of cluttering the headers (which aren't
206   # necessarily the ones that the callers will use anyway) with the
207   # attributes.
208   add_compile_flags_if_supported(-Wno-dll-attribute-on-redeclaration)
209 endif()
210
211 if (LIBUNWIND_ENABLE_WERROR)
212   add_compile_flags_if_supported(-Werror)
213   add_compile_flags_if_supported(-WX)
214 else()
215   add_compile_flags_if_supported(-Wno-error)
216   add_compile_flags_if_supported(-WX-)
217 endif()
218
219 if (LIBUNWIND_ENABLE_PEDANTIC)
220   add_compile_flags_if_supported(-pedantic)
221 endif()
222
223 # Get feature flags.
224 # Exceptions
225 # Catches C++ exceptions only and tells the compiler to assume that extern C
226 # functions never throw a C++ exception.
227 add_cxx_compile_flags_if_supported(-fstrict-aliasing)
228 add_cxx_compile_flags_if_supported(-EHsc)
229
230 # Don't run the linker in this CMake check.
231 #
232 # The reason why this was added is that when building libunwind for
233 # ARM Linux, we need to pass the -funwind-tables flag in order for it to
234 # work properly with ARM EHABI.
235 #
236 # However, when performing CMake checks, adding this flag causes the check
237 # to produce a false negative, because the compiler generates calls
238 # to __aeabi_unwind_cpp_pr0, which is defined in libunwind itself,
239 # which isn't built yet, so the linker complains about undefined symbols.
240 #
241 # This leads to libunwind not being built with this flag, which makes
242 # libunwind quite useless in this setup.
243 set(_previous_CMAKE_TRY_COMPILE_TARGET_TYPE ${CMAKE_TRY_COMPILE_TARGET_TYPE})
244 set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
245 add_compile_flags_if_supported(-funwind-tables)
246 set(CMAKE_TRY_COMPILE_TARGET_TYPE ${_previous_CMAKE_TRY_COMPILE_TARGET_TYPE})
247
248 if (LIBUNWIND_USES_ARM_EHABI AND NOT LIBUNWIND_SUPPORTS_FUNWIND_TABLES_FLAG)
249   message(SEND_ERROR "The -funwind-tables flag must be supported "
250                      "because this target uses ARM Exception Handling ABI")
251 endif()
252
253 add_cxx_compile_flags_if_supported(-fno-exceptions)
254 add_cxx_compile_flags_if_supported(-fno-rtti)
255
256 # Ensure that we don't depend on C++ standard library.
257 if (LIBUNWIND_HAS_NOSTDINCXX_FLAG)
258   list(APPEND LIBUNWIND_COMPILE_FLAGS -nostdinc++)
259   # Remove -stdlib flags to prevent them from causing an unused flag warning.
260   string(REPLACE "--stdlib=libc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
261   string(REPLACE "--stdlib=libstdc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
262   string(REPLACE "-stdlib=libc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
263   string(REPLACE "-stdlib=libstdc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
264 endif()
265
266 # Assert
267 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
268 if (LIBUNWIND_ENABLE_ASSERTIONS)
269   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
270   if (NOT MSVC)
271     add_compile_flags(-D_DEBUG)
272   endif()
273
274   # On Release builds cmake automatically defines NDEBUG, so we
275   # explicitly undefine it:
276   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
277     add_compile_flags(-UNDEBUG)
278   endif()
279 else()
280   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
281     add_compile_flags(-DNDEBUG)
282   endif()
283 endif()
284
285 # Cross-unwinding
286 if (NOT LIBUNWIND_ENABLE_CROSS_UNWINDING)
287   add_compile_flags(-D_LIBUNWIND_IS_NATIVE_ONLY)
288 endif()
289
290 # Threading-support
291 if (NOT LIBUNWIND_ENABLE_THREADS)
292   add_compile_flags(-D_LIBUNWIND_HAS_NO_THREADS)
293 endif()
294
295 # ARM WMMX register support
296 if (LIBUNWIND_ENABLE_ARM_WMMX)
297   # __ARM_WMMX is a compiler pre-define (as per the ACLE 2.0). Clang does not
298   # define this macro for any supported target at present. Therefore, here we
299   # provide the option to explicitly enable support for WMMX registers in the
300   # unwinder.
301   add_compile_flags(-D__ARM_WMMX)
302 endif()
303
304 if(LIBUNWIND_IS_BAREMETAL)
305   add_compile_definitions(_LIBUNWIND_IS_BAREMETAL)
306 endif()
307
308 if(LIBUNWIND_USE_FRAME_HEADER_CACHE)
309   add_compile_definitions(_LIBUNWIND_USE_FRAME_HEADER_CACHE)
310 endif()
311
312 if(LIBUNWIND_REMEMBER_HEAP_ALLOC)
313   add_compile_definitions(_LIBUNWIND_REMEMBER_HEAP_ALLOC)
314 endif()
315
316 # This is the _ONLY_ place where add_definitions is called.
317 if (MSVC)
318   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
319 endif()
320
321 # Disable DLL annotations on Windows for static builds.
322 if (WIN32 AND LIBUNWIND_ENABLE_STATIC AND NOT LIBUNWIND_ENABLE_SHARED)
323   add_definitions(-D_LIBUNWIND_DISABLE_VISIBILITY_ANNOTATIONS)
324 endif()
325
326 if (LIBUNWIND_HAS_COMMENT_LIB_PRAGMA)
327   if (LIBUNWIND_HAS_DL_LIB)
328     add_definitions(-D_LIBUNWIND_LINK_DL_LIB)
329   endif()
330   if (LIBUNWIND_HAS_PTHREAD_LIB)
331     add_definitions(-D_LIBUNWIND_LINK_PTHREAD_LIB)
332   endif()
333 endif()
334
335 #===============================================================================
336 # Setup Source Code
337 #===============================================================================
338
339 include_directories(include)
340
341 add_subdirectory(src)
342
343 if (LIBUNWIND_INCLUDE_DOCS)
344   add_subdirectory(docs)
345 endif()
346
347 if (EXISTS ${LLVM_CMAKE_PATH})
348   add_subdirectory(test)
349 endif()