lldb/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.13.4)
   2
   3 if(POLICY CMP0075)
   4   cmake_policy(SET CMP0075 NEW)
   5 endif()
   6
   7 if(POLICY CMP0077)
   8   cmake_policy(SET CMP0077 NEW)
   9 endif()
  10
  11 # Add path for custom modules.
  12 set(CMAKE_MODULE_PATH
  13   ${CMAKE_MODULE_PATH}
  14   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  15   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  16   )
  17
  18 # If we are not building as part of LLVM, build LLDB as a standalone project,
  19 # using LLVM as an external library.
  20 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  21   project(lldb)
  22   include(LLDBStandalone)
  23
  24   set(CMAKE_CXX_STANDARD 14 CACHE STRING "C++ standard to conform to")
  25   set(CMAKE_CXX_STANDARD_REQUIRED YES)
  26   set(CMAKE_CXX_EXTENSIONS NO)
  27 endif()
  28
  29 include(LLDBConfig)
  30 include(AddLLDB)
  31
  32 # Define the LLDB_CONFIGURATION_xxx matching the build type.
  33 if(uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  34   add_definitions(-DLLDB_CONFIGURATION_DEBUG)
  35 endif()
  36
  37 if (WIN32)
  38   add_definitions(-D_ENABLE_EXTENDED_ALIGNED_STORAGE)
  39 endif()
  40
  41 if (LLDB_ENABLE_PYTHON)
  42   execute_process(
  43     COMMAND ${Python3_EXECUTABLE}
  44         -c "import distutils.sysconfig; print(distutils.sysconfig.get_python_lib(True, False, ''))"
  45     OUTPUT_VARIABLE LLDB_PYTHON_DEFAULT_RELATIVE_PATH
  46     OUTPUT_STRIP_TRAILING_WHITESPACE)
  47
  48   file(TO_CMAKE_PATH ${LLDB_PYTHON_DEFAULT_RELATIVE_PATH} LLDB_PYTHON_DEFAULT_RELATIVE_PATH)
  49   set(LLDB_PYTHON_RELATIVE_PATH ${LLDB_PYTHON_DEFAULT_RELATIVE_PATH}
  50     CACHE STRING "Path where Python modules are installed, relative to install prefix")
  51 endif ()
  52
  53 if (LLDB_ENABLE_PYTHON OR LLDB_ENABLE_LUA)
  54   add_subdirectory(bindings)
  55 endif ()
  56
  57 # We need the headers generated by instrinsics_gen before we can compile
  58 # any source file in LLDB as the imported Clang modules might include
  59 # some of these generated headers. This approach is copied from Clang's main
  60 # CMakeLists.txt, so it should kept in sync the code in Clang which was added
  61 # in llvm-svn 308844.
  62 if(LLVM_ENABLE_MODULES)
  63   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
  64 endif()
  65
  66 if(CMAKE_CROSSCOMPILING AND LLDB_BUILT_STANDALONE)
  67   set(LLVM_USE_HOST_TOOLS ON)
  68   include(CrossCompile)
  69   if (NOT NATIVE_LLVM_DIR OR NOT NATIVE_Clang_DIR)
  70     message(FATAL_ERROR
  71       "Crosscompiling standalone requires the variables NATIVE_{CLANG,LLVM}_DIR
  72       for building the native lldb-tblgen used during the build process.")
  73   endif()
  74   llvm_create_cross_target(lldb NATIVE "" Release
  75     -DLLVM_DIR=${NATIVE_LLVM_DIR}
  76     -DClang_DIR=${NATIVE_Clang_DIR})
  77 endif()
  78
  79 # TableGen
  80 add_subdirectory(utils/TableGen)
  81
  82 add_subdirectory(source)
  83 add_subdirectory(tools)
  84 add_subdirectory(docs)
  85
  86 if (LLDB_ENABLE_PYTHON)
  87   if(LLDB_BUILD_FRAMEWORK)
  88     set(lldb_python_target_dir "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/Resources/Python/lldb")
  89   else()
  90     set(lldb_python_target_dir "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${LLDB_PYTHON_RELATIVE_PATH}/lldb")
  91   endif()
  92   get_target_property(lldb_python_bindings_dir swig_wrapper_python BINARY_DIR)
  93   finish_swig_python("lldb-python" "${lldb_python_bindings_dir}" "${lldb_python_target_dir}")
  94 endif()
  95
  96 option(LLDB_INCLUDE_TESTS "Generate build targets for the LLDB unit tests." ${LLVM_INCLUDE_TESTS})
  97 if(LLDB_INCLUDE_TESTS)
  98   add_subdirectory(test)
  99   add_subdirectory(unittests)
 100   add_subdirectory(utils)
 101 endif()
 102
 103 if(LLDB_BUILT_STANDALONE AND NOT LLVM_ENABLE_IDE)
 104   llvm_distribution_add_targets()
 105 endif()