Merge branch 'addmainunit4-altlink-sharedstmt-dieref-dwz3-inlinebug-testcategory...
[lldb.git] / lldb / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.13.4)
2
3 # Add path for custom modules.
4 set(CMAKE_MODULE_PATH
5   ${CMAKE_MODULE_PATH}
6   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
7   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
8   )
9
10 # If we are not building as part of LLVM, build LLDB as a standalone project,
11 # using LLVM as an external library.
12 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
13   project(lldb)
14   include(LLDBStandalone)
15
16   set(CMAKE_CXX_STANDARD 14 CACHE STRING "C++ standard to conform to")
17   set(CMAKE_CXX_STANDARD_REQUIRED YES)
18   set(CMAKE_CXX_EXTENSIONS NO)
19 endif()
20
21 include(LLDBConfig)
22 include(AddLLDB)
23
24 # Define the LLDB_CONFIGURATION_xxx matching the build type.
25 if(uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
26   add_definitions(-DLLDB_CONFIGURATION_DEBUG)
27 endif()
28
29 if (WIN32)
30   add_definitions(-D_ENABLE_EXTENDED_ALIGNED_STORAGE)
31 endif()
32
33 if (LLDB_ENABLE_PYTHON)
34   execute_process(
35     COMMAND ${Python3_EXECUTABLE}
36         -c "import distutils.sysconfig; print(distutils.sysconfig.get_python_lib(True, False, ''))"
37     OUTPUT_VARIABLE LLDB_PYTHON_DEFAULT_RELATIVE_PATH
38     OUTPUT_STRIP_TRAILING_WHITESPACE)
39
40   file(TO_CMAKE_PATH ${LLDB_PYTHON_DEFAULT_RELATIVE_PATH} LLDB_PYTHON_DEFAULT_RELATIVE_PATH)
41   set(LLDB_PYTHON_RELATIVE_PATH ${LLDB_PYTHON_DEFAULT_RELATIVE_PATH}
42     CACHE STRING "Path where Python modules are installed, relative to install prefix")
43 endif ()
44
45 if (LLDB_ENABLE_PYTHON OR LLDB_ENABLE_LUA)
46   add_subdirectory(bindings)
47 endif ()
48
49 # We need the headers generated by instrinsics_gen before we can compile
50 # any source file in LLDB as the imported Clang modules might include
51 # some of these generated headers. This approach is copied from Clang's main
52 # CMakeLists.txt, so it should kept in sync the code in Clang which was added
53 # in llvm-svn 308844.
54 if(LLVM_ENABLE_MODULES)
55   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
56 endif()
57
58 if(CMAKE_CROSSCOMPILING AND LLDB_BUILT_STANDALONE)
59   set(LLVM_USE_HOST_TOOLS ON)
60   include(CrossCompile)
61   if (NOT NATIVE_LLVM_DIR OR NOT NATIVE_Clang_DIR)
62     message(FATAL_ERROR
63       "Crosscompiling standalone requires the variables NATIVE_{CLANG,LLVM}_DIR
64       for building the native lldb-tblgen used during the build process.")
65   endif()
66   llvm_create_cross_target(lldb NATIVE "" Release
67     -DLLVM_DIR=${NATIVE_LLVM_DIR}
68     -DClang_DIR=${NATIVE_Clang_DIR})
69 endif()
70
71 # TableGen
72 add_subdirectory(utils/TableGen)
73
74 add_subdirectory(source)
75 add_subdirectory(tools)
76 add_subdirectory(docs)
77
78 if (LLDB_ENABLE_PYTHON)
79   if(LLDB_BUILD_FRAMEWORK)
80     set(lldb_python_target_dir "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/Resources/Python/lldb")
81   else()
82     set(lldb_python_target_dir "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${LLDB_PYTHON_RELATIVE_PATH}/lldb")
83   endif()
84   get_target_property(lldb_python_bindings_dir swig_wrapper_python BINARY_DIR)
85   finish_swig_python("lldb-python" "${lldb_python_bindings_dir}" "${lldb_python_target_dir}")
86 endif()
87
88 option(LLDB_INCLUDE_TESTS "Generate build targets for the LLDB unit tests." ${LLVM_INCLUDE_TESTS})
89 if(LLDB_INCLUDE_TESTS)
90   add_subdirectory(test)
91   add_subdirectory(unittests)
92   add_subdirectory(utils)
93 endif()
94
95 if(LLDB_BUILT_STANDALONE AND NOT LLVM_ENABLE_IDE)
96   llvm_distribution_add_targets()
97 endif()