Reland r356547 after fixing the YAML module missing issue.
[lldb.git] / lldb / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.4.3)
2
3 if(POLICY CMP0075)
4   cmake_policy(SET CMP0075 NEW)
5 endif()
6
7 # Add path for custom modules
8 set(CMAKE_MODULE_PATH
9   ${CMAKE_MODULE_PATH}
10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
11   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
12   )
13
14 include(LLDBStandalone)
15 include(LLDBConfig)
16 include(AddLLDB)
17
18 # Define the LLDB_CONFIGURATION_xxx matching the build type
19 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
20   add_definitions( -DLLDB_CONFIGURATION_DEBUG )
21 else()
22   add_definitions( -DLLDB_CONFIGURATION_RELEASE )
23 endif()
24
25 if(APPLE)
26   add_definitions(-DLLDB_USE_OS_LOG)
27 endif()
28
29 if (WIN32)
30   add_definitions(-D_ENABLE_EXTENDED_ALIGNED_STORAGE)
31 endif()
32
33 add_subdirectory(docs)
34 if (NOT LLDB_DISABLE_PYTHON)
35   add_subdirectory(scripts)
36 endif ()
37 add_subdirectory(source)
38 add_subdirectory(tools)
39
40 option(LLDB_INCLUDE_TESTS "Generate build targets for the LLDB unit tests." ${LLVM_INCLUDE_TESTS})
41 option(LLDB_TEST_USE_CUSTOM_C_COMPILER "Use the C compiler provided via LLDB_TEST_C_COMPILER for building test inferiors (instead of the just-built compiler). Defaults to OFF." OFF)
42 option(LLDB_TEST_USE_CUSTOM_CXX_COMPILER "Use the C++ compiler provided via LLDB_TEST_CXX_COMPILER for building test inferiors (instead of the just-built compiler). Defaults to OFF." OFF)
43 if(LLDB_INCLUDE_TESTS)
44
45   # Set the path to the default lldb test executable.
46   set(LLDB_DEFAULT_TEST_EXECUTABLE "${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb${CMAKE_EXECUTABLE_SUFFIX}")
47
48   # Set the paths to default llvm tools.
49   set(LLDB_DEFAULT_TEST_DSYMUTIL "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/dsymutil${CMAKE_EXECUTABLE_SUFFIX}")
50   set(LLDB_DEFAULT_TEST_FILECHECK "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/FileCheck${CMAKE_EXECUTABLE_SUFFIX}")
51
52   if (NOT LLDB_TEST_USE_CUSTOM_C_COMPILER AND TARGET clang)
53     set(LLDB_DEFAULT_TEST_C_COMPILER "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/clang${CMAKE_EXECUTABLE_SUFFIX}")
54   else()
55     set(LLDB_DEFAULT_TEST_C_COMPILER "")
56   endif()
57
58   if (NOT LLDB_TEST_USE_CUSTOM_CXX_COMPILER AND TARGET clang)
59     set(LLDB_DEFAULT_TEST_CXX_COMPILER "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/clang++${CMAKE_EXECUTABLE_SUFFIX}")
60   else()
61     set(LLDB_DEFAULT_TEST_CXX_COMPILER "")
62   endif()
63
64   set(LLDB_TEST_EXECUTABLE "${LLDB_DEFAULT_TEST_EXECUTABLE}" CACHE PATH "lldb executable used for testing")
65   set(LLDB_TEST_C_COMPILER "${LLDB_DEFAULT_TEST_C_COMPILER}" CACHE PATH "C Compiler to use for building LLDB test inferiors")
66   set(LLDB_TEST_CXX_COMPILER "${LLDB_DEFAULT_TEST_CXX_COMPILER}" CACHE PATH "C++ Compiler to use for building LLDB test inferiors")
67   set(LLDB_TEST_DSYMUTIL "${LLDB_DEFAULT_TEST_DSYMUTIL}" CACHE PATH "dsymutil used for generating dSYM bundles")
68   set(LLDB_TEST_FILECHECK "${LLDB_DEFAULT_TEST_FILECHECK}" CACHE PATH "FileCheck used for testing purposes")
69
70   if (("${LLDB_TEST_C_COMPILER}" STREQUAL "") OR
71       ("${LLDB_TEST_CXX_COMPILER}" STREQUAL ""))
72     message(FATAL_ERROR "LLDB test compilers not specified.  Tests will not run")
73   endif()
74
75   set(LLDB_TEST_DEPS lldb)
76
77   # darwin-debug is an hard dependency for the testsuite.
78   if (CMAKE_SYSTEM_NAME MATCHES "Darwin")
79     list(APPEND LLDB_TEST_DEPS darwin-debug)
80   endif()
81
82   if(TARGET lldb-server)
83     list(APPEND LLDB_TEST_DEPS lldb-server)
84   endif()
85
86   if(TARGET debugserver)
87     list(APPEND LLDB_TEST_DEPS debugserver)
88   endif()
89
90   if(TARGET lldb-mi)
91     list(APPEND LLDB_TEST_DEPS lldb-mi)
92   endif()
93
94   if(TARGET lldb-instr)
95     list(APPEND LLDB_TEST_DEPS lldb-instr)
96   endif()
97
98   if(NOT LLDB_BUILT_STANDALONE)
99     list(APPEND LLDB_TEST_DEPS yaml2obj)
100   endif()
101
102   if(TARGET liblldb)
103     list(APPEND LLDB_TEST_DEPS liblldb)
104   endif()
105
106   # Add dependencies if we test with the in-tree clang.
107   # This works with standalone builds as they import the clang target.
108   if(TARGET clang)
109     list(APPEND LLDB_TEST_DEPS clang)
110     if(APPLE)
111       # If we build clang, we should build libcxx.
112       # FIXME: Standalone builds should import the cxx target as well.
113       if(LLDB_BUILT_STANDALONE)
114         # For now check that the include directory exists.
115         set(cxx_dir "${LLVM_BINARY_DIR}/include/c++")
116         if(NOT EXISTS ${cxx_dir})
117           message(WARNING "LLDB test suite requires libc++ in llvm/projects/libcxx or an existing build symlinked to ${cxx_dir}")
118         endif()
119       else()
120         list(APPEND LLDB_TEST_DEPS cxx)
121       endif()
122     endif()
123   endif()
124
125   if(TARGET dsymutil)
126     list(APPEND LLDB_TEST_DEPS dsymutil)
127   endif()
128
129   add_custom_target(lldb-test-deps DEPENDS ${LLDB_TEST_DEPS})
130
131   add_subdirectory(test)
132   add_subdirectory(unittests)
133   add_subdirectory(lit)
134   add_subdirectory(utils/lldb-dotest)
135 endif()
136
137 if (NOT LLDB_DISABLE_PYTHON)
138     if(NOT LLDB_BUILD_FRAMEWORK)
139       set(use_python_wrapper_from_src_dir -m)
140     endif()
141     if(LLDB_USE_SYSTEM_SIX)
142       set(use_six_py_from_system --useSystemSix)
143     endif()
144     get_target_property(lldb_scripts_dir swig_wrapper BINARY_DIR)
145     get_target_property(liblldb_build_dir liblldb LIBRARY_OUTPUT_DIRECTORY)
146
147     # Add a Post-Build Event to copy over Python files and create the symlink
148     # to liblldb.so for the Python API(hardlink on Windows)
149     add_custom_target(finish_swig ALL
150         COMMAND
151            ${PYTHON_EXECUTABLE} ${LLDB_SOURCE_DIR}/scripts/finishSwigWrapperClasses.py
152                --srcRoot=${LLDB_SOURCE_DIR}
153                --targetDir=${liblldb_build_dir}
154                --cfgBldDir=${lldb_scripts_dir}
155                --prefix=${CMAKE_BINARY_DIR}
156                --cmakeBuildConfiguration=${CMAKE_CFG_INTDIR}
157                --lldbLibDir=lib${LLVM_LIBDIR_SUFFIX}
158                ${use_python_wrapper_from_src_dir}
159                ${use_six_py_from_system}
160         VERBATIM
161         DEPENDS ${LLDB_SOURCE_DIR}/scripts/finishSwigWrapperClasses.py
162         DEPENDS ${lldb_scripts_dir}/lldb.py
163         COMMENT "Python script sym-linking LLDB Python API")
164
165     if (TARGET readline)
166       set(readline_dep readline)
167     endif()
168     add_dependencies(finish_swig swig_wrapper liblldb lldb-argdumper ${readline_dep})
169
170     # Ensure we do the python post-build step when building lldb.
171     add_dependencies(lldb finish_swig)
172
173     if(LLDB_BUILD_FRAMEWORK)
174       add_dependencies(lldb-framework finish_swig)
175     endif()
176
177     # Add a Post-Build Event to copy the custom Python DLL to the lldb binaries dir so that Windows can find it when launching
178     # lldb.exe or any other executables that were linked with liblldb.
179     if (WIN32 AND NOT "${PYTHON_DLL}" STREQUAL "")
180         # When using the Visual Studio CMake generator the lldb binaries end up in Release/bin, Debug/bin etc.
181         file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin" LLDB_BIN_DIR)
182         file(TO_NATIVE_PATH "${PYTHON_DLL}" PYTHON_DLL_NATIVE_PATH)
183         add_custom_command(
184             TARGET finish_swig
185             POST_BUILD
186             COMMAND ${CMAKE_COMMAND} -E copy ${PYTHON_DLL_NATIVE_PATH} ${LLDB_BIN_DIR} VERBATIM
187             COMMENT "Copying Python DLL to LLDB binaries directory.")
188     endif ()
189 endif ()