f4802e2f5ca2cb08c6eb85b71d2764d94bc151cd
[lldb.git] / lldb / test / API / CMakeLists.txt
1 function(add_python_test_target name test_script args comment)
2   set(PYTHON_TEST_COMMAND
3     ${Python3_EXECUTABLE}
4     ${test_script}
5     ${args}
6     )
7
8   add_custom_target(${name}
9     COMMAND ${PYTHON_TEST_COMMAND} ${ARG_DEFAULT_ARGS}
10     COMMENT "${comment}"
11     USES_TERMINAL
12     )
13   add_dependencies(${name} lldb-test-deps)
14 endfunction()
15
16 # The default architecture with which to compile test executables is the
17 # default LLVM target architecture, which itself defaults to the host
18 # architecture.
19 if(NOT LLDB_DEFAULT_TEST_ARCH)
20   string(REGEX MATCH "^[^-]*" LLDB_DEFAULT_TEST_ARCH ${LLVM_HOST_TRIPLE})
21 endif ()
22
23 # Allow the user to override the default by setting LLDB_TEST_ARCH
24 set(LLDB_TEST_ARCH
25   ${LLDB_DEFAULT_TEST_ARCH}
26   CACHE STRING "Specify the architecture to run LLDB tests as (x86|x64).  Determines whether tests are compiled with -m32 or -m64")
27
28 # Users can override LLDB_TEST_USER_ARGS to specify arbitrary arguments to pass to the script
29 set(LLDB_TEST_USER_ARGS
30   ""
31   CACHE STRING "Specify additional arguments to pass to test runner. For example: '-C gcc -C clang -A i386 -A x86_64'")
32
33 # The .noindex suffix is a marker for Spotlight to never index the
34 # build directory.  LLDB queries Spotlight to locate .dSYM bundles
35 # based on the UUID embedded in a binary, and because the UUID is a
36 # hash of filename and .text section, there *will* be conflicts inside
37 # the build directory.
38 set(LLDB_TEST_COMMON_ARGS
39   -S nm
40   -u CXXFLAGS
41   -u CFLAGS
42   )
43
44 # Configure the traces directory.
45 set(LLDB_TEST_TRACE_DIRECTORY "${PROJECT_BINARY_DIR}/lldb-test-traces" CACHE PATH "The test traces directory.")
46
47 # Set the path to the default lldb test executable.
48 set(LLDB_DEFAULT_TEST_EXECUTABLE "${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb${CMAKE_EXECUTABLE_SUFFIX}")
49
50 # Set the paths to default llvm tools.
51 set(LLDB_DEFAULT_TEST_DSYMUTIL "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/dsymutil${CMAKE_EXECUTABLE_SUFFIX}")
52 set(LLDB_DEFAULT_TEST_FILECHECK "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/FileCheck${CMAKE_EXECUTABLE_SUFFIX}")
53 set(LLDB_DEFAULT_TEST_YAML2OBJ "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/yaml2obj${CMAKE_EXECUTABLE_SUFFIX}")
54
55 if (TARGET clang)
56   set(LLDB_DEFAULT_TEST_COMPILER "${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin/clang${CMAKE_EXECUTABLE_SUFFIX}")
57 else()
58   set(LLDB_DEFAULT_TEST_COMPILER "")
59 endif()
60
61 set(LLDB_TEST_EXECUTABLE "${LLDB_DEFAULT_TEST_EXECUTABLE}" CACHE PATH "lldb executable used for testing")
62 set(LLDB_TEST_COMPILER "${LLDB_DEFAULT_TEST_COMPILER}" CACHE PATH "C Compiler to use for building LLDB test inferiors")
63 set(LLDB_TEST_DSYMUTIL "${LLDB_DEFAULT_TEST_DSYMUTIL}" CACHE PATH "dsymutil used for generating dSYM bundles")
64 set(LLDB_TEST_FILECHECK "${LLDB_DEFAULT_TEST_FILECHECK}" CACHE PATH "FileCheck used for testing purposes")
65 set(LLDB_TEST_YAML2OBJ "${LLDB_DEFAULT_TEST_YAML2OBJ}" CACHE PATH "yaml2obj used for testing purposes")
66
67 if ("${LLDB_TEST_COMPILER}" STREQUAL "")
68   message(FATAL_ERROR "LLDB test compiler not specified. Tests will not run.")
69 endif()
70
71 if ( CMAKE_SYSTEM_NAME MATCHES "Windows" )
72   set(LLDB_TEST_DEBUG_TEST_CRASHES
73     0
74     CACHE BOOL "(Windows only) Enables debugging of tests in the test suite by showing the crash dialog when lldb crashes")
75
76   set(LLDB_TEST_HIDE_CONSOLE_WINDOWS
77     1
78     CACHE BOOL "(Windows only) Hides the console window for an inferior when it is launched through the test suite")
79
80   if (LLDB_TEST_DEBUG_TEST_CRASHES)
81     set(LLDB_TEST_COMMON_ARGS ${LLDB_TEST_COMMON_ARGS} --enable-crash-dialog)
82   endif()
83
84   if (NOT LLDB_TEST_HIDE_CONSOLE_WINDOWS)
85     set(LLDB_TEST_COMMON_ARGS ${LLDB_TEST_COMMON_ARGS} --show-inferior-console)
86   endif()
87 endif()
88
89 if (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Windows|Darwin")
90   list(APPEND LLDB_TEST_COMMON_ARGS
91     --env ARCHIVER=${CMAKE_AR} --env OBJCOPY=${CMAKE_OBJCOPY})
92 endif()
93
94 if (NOT "${LLDB_LIT_TOOLS_DIR}" STREQUAL "")
95   if (NOT EXISTS "${LLDB_LIT_TOOLS_DIR}")
96     message(WARNING "LLDB_LIT_TOOLS_DIR ${LLDB_LIT_TOOLS_DIR} does not exist.")
97   endif()
98 endif()
99
100 if(CMAKE_HOST_APPLE)
101   if(LLDB_BUILD_FRAMEWORK)
102     set(LLDB_FRAMEWORK_DIR ${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework)
103   endif()
104
105   # Use the same identity for testing
106   get_property(code_sign_identity_used GLOBAL PROPERTY LLDB_DEBUGSERVER_CODESIGN_IDENTITY)
107   if(code_sign_identity_used)
108     list(APPEND LLDB_TEST_COMMON_ARGS --codesign-identity "${code_sign_identity_used}")
109   endif()
110
111   if(LLDB_USE_SYSTEM_DEBUGSERVER)
112     lldb_find_system_debugserver(system_debugserver_path)
113     add_custom_target(debugserver
114       COMMAND ${CMAKE_COMMAND} -E copy_if_different
115       ${system_debugserver_path} ${LLVM_RUNTIME_OUTPUT_INTDIR}
116       COMMENT "Copying the system debugserver to LLDB's binaries directory for testing.")
117     message(STATUS "LLDB tests use out-of-tree debugserver: ${system_debugserver_path}")
118     list(APPEND LLDB_TEST_COMMON_ARGS --out-of-tree-debugserver)
119     add_lldb_test_dependency(debugserver)
120   elseif(TARGET debugserver)
121     set(debugserver_path ${LLVM_RUNTIME_OUTPUT_INTDIR}/debugserver)
122     message(STATUS "LLDB Tests use just-built debugserver: ${debugserver_path}")
123     set(LLDB_TEST_SERVER ${debugserver_path})
124     add_lldb_test_dependency(debugserver)
125   elseif(TARGET lldb-server)
126     set(lldb_server_path ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-server)
127     message(STATUS "LLDB Tests use just-built lldb-server: ${lldb_server_path}")
128     set(LLDB_TEST_SERVER ${lldb_server_path})
129     add_lldb_test_dependency(lldb-server)
130   else()
131     message(WARNING "LLDB Tests enabled, but no server available")
132   endif()
133 endif()
134
135 set(LLDB_DOTEST_ARGS ${LLDB_TEST_COMMON_ARGS};${LLDB_TEST_USER_ARGS} CACHE INTERNAL STRING)
136 set(dotest_args_replacement ${LLVM_BUILD_MODE})
137
138 if(LLDB_BUILT_STANDALONE)
139   # In paths to our build-tree, replace CMAKE_CFG_INTDIR with our configuration name placeholder.
140   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} config_runtime_output_dir ${LLVM_RUNTIME_OUTPUT_INTDIR})
141   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_DOTEST_ARGS "${LLDB_DOTEST_ARGS}")
142   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_SOURCE_DIR "${LLDB_SOURCE_DIR}")
143   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_FRAMEWORK_DIR "${LLDB_FRAMEWORK_DIR}")
144   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_BUILD_DIRECTORY "${LLDB_TEST_BUILD_DIRECTORY}")
145   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_TRACE_DIRECTORY "${LLDB_TEST_TRACE_DIRECTORY}")
146   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_EXECUTABLE "${LLDB_TEST_EXECUTABLE}")
147   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_COMPILER "${LLDB_TEST_COMPILER}")
148   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_DSYMUTIL "${LLDB_TEST_DSYMUTIL}")
149   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_FILECHECK "${LLDB_TEST_FILECHECK}")
150   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_YAML2OBJ "${LLDB_TEST_YAML2OBJ}")
151   string(REPLACE ${LLVM_RUNTIME_OUTPUT_INTDIR} ${config_runtime_output_dir} LLDB_TEST_SERVER "${LLDB_TEST_SERVER}")
152
153   # Remaining ones must be paths to the provided LLVM build-tree.
154   if(LLVM_CONFIGURATION_TYPES)
155     # LLDB uses single-config; LLVM multi-config; pick one and prefer Release types.
156     # Otherwise, if both use multi-config the default is fine.
157     if(NOT CMAKE_CONFIGURATION_TYPES)
158       if(RelWithDebInfo IN_LIST LLVM_CONFIGURATION_TYPES)
159         set(dotest_args_replacement RelWithDebInfo)
160       elseif(Release IN_LIST LLVM_CONFIGURATION_TYPES)
161         set(dotest_args_replacement Release)
162       else()
163         list(GET LLVM_CONFIGURATION_TYPES 0 dotest_args_replacement)
164       endif()
165     endif()
166   else()
167     # Common case: LLVM used a single-configuration generator like Ninja.
168     set(dotest_args_replacement ".")
169   endif()
170 endif()
171
172 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_DOTEST_ARGS "${LLDB_DOTEST_ARGS}")
173 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_SOURCE_DIR "${LLDB_SOURCE_DIR}")
174 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_BUILD_DIRECTORY "${LLDB_TEST_BUILD_DIRECTORY}")
175 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_TRACE_DIRECTORY "${LLDB_TEST_TRACE_DIRECTORY}")
176 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_EXECUTABLE "${LLDB_TEST_EXECUTABLE}")
177 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_COMPILER "${LLDB_TEST_COMPILER}")
178 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_DSYMUTIL "${LLDB_TEST_DSYMUTIL}")
179 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_FILECHECK "${LLDB_TEST_FILECHECK}")
180 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_YAML2OBJ "${LLDB_TEST_YAML2OBJ}")
181 string(REPLACE ${CMAKE_CFG_INTDIR} ${dotest_args_replacement} LLDB_TEST_SERVER "${LLDB_TEST_SERVER}")
182
183 # Configure the API test suite.
184 configure_lit_site_cfg(
185   ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.py.in
186   ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg.py
187   MAIN_CONFIG
188   ${CMAKE_CURRENT_SOURCE_DIR}/lit.cfg.py)
189
190 if (CMAKE_GENERATOR STREQUAL "Xcode")
191   # Xcode does not get the auto-generated targets. We need to create
192   # check-lldb-api manually.
193   add_lit_testsuite(check-lldb-api "Running lldb api test suite"
194     ${CMAKE_CURRENT_BINARY_DIR}
195     DEPENDS lldb-test-deps)
196 endif()