[RISCV] Add addu.w and slliu.w test that uses getelementptr with zero extended indices.
[lldb.git] / lldb / tools / lldb-server / CMakeLists.txt
1 set(LLVM_TARGET_DEFINITIONS LLGSOptions.td)
2 tablegen(LLVM LLGSOptions.inc -gen-opt-parser-defs)
3 add_public_tablegen_target(LLGSOptionsTableGen)
4 set_target_properties(LLGSOptionsTableGen PROPERTIES FOLDER "lldb misc")
5
6 set(LLDB_PLUGINS)
7
8 if(CMAKE_SYSTEM_NAME MATCHES "Linux|Android")
9   list(APPEND LLDB_PLUGINS lldbPluginProcessLinux)
10 endif()
11
12 if(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
13   list(APPEND LLDB_PLUGINS
14     lldbPluginProcessFreeBSDRemote
15     lldbPluginProcessFreeBSD)
16 endif()
17
18 if(CMAKE_SYSTEM_NAME MATCHES "NetBSD")
19   list(APPEND LLDB_PLUGINS lldbPluginProcessNetBSD)
20 endif()
21
22 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
23   list(APPEND LLDB_PLUGINS lldbPluginObjectFileMachO)
24 elseif(CMAKE_SYSTEM_NAME MATCHES "Windows")
25   list(APPEND LLDB_PLUGINS lldbPluginObjectFilePECOFF)
26 else()
27   list(APPEND LLDB_PLUGINS lldbPluginObjectFileELF)
28 endif()
29
30 if(APPLE_EMBEDDED)
31   if(LLDB_CODESIGN_IDENTITY)
32     # Use explicit LLDB identity
33     set(LLVM_CODESIGNING_IDENTITY ${LLDB_CODESIGN_IDENTITY})
34   else()
35     # Use explicit LLVM identity or default to lldb_codesign if empty
36     if(NOT LLVM_CODESIGNING_IDENTITY)
37       set(LLVM_CODESIGNING_IDENTITY lldb_codesign)
38     endif()
39   endif()
40 endif()
41
42 add_lldb_tool(lldb-server
43     Acceptor.cpp
44     lldb-gdbserver.cpp
45     lldb-platform.cpp
46     lldb-server.cpp
47     LLDBServerUtilities.cpp
48     SystemInitializerLLGS.cpp
49
50     LINK_LIBS
51       lldbBase
52       lldbHost
53       lldbInitialization
54       ${LLDB_PLUGINS}
55       lldbPluginInstructionARM
56       lldbPluginInstructionMIPS
57       lldbPluginInstructionMIPS64
58       ${LLDB_SYSTEM_LIBS}
59
60     LINK_COMPONENTS
61       Option
62       Support
63 )
64
65 add_dependencies(lldb-server
66   LLGSOptionsTableGen
67   ${tablegen_deps}
68 )
69 target_include_directories(lldb-server PRIVATE "${LLDB_SOURCE_DIR}/source")
70 target_link_libraries(lldb-server PRIVATE ${LLDB_SYSTEM_LIBS})