Revert "[NFCI][IR] ConstantRangeTest: add basic scaffolding for next-gen precision...
[lldb.git] / openmp / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.13.4)
2
3 # Add cmake directory to search for custom cmake functions.
4 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
5
6 # llvm/runtimes/ will set OPENMP_STANDALONE_BUILD.
7 if (OPENMP_STANDALONE_BUILD OR "${CMAKE_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_SOURCE_DIR}")
8   set(OPENMP_STANDALONE_BUILD TRUE)
9   project(openmp C CXX)
10
11   # CMAKE_BUILD_TYPE was not set, default to Release.
12   if (NOT CMAKE_BUILD_TYPE)
13     set(CMAKE_BUILD_TYPE Release)
14   endif()
15
16   # Group common settings.
17   set(OPENMP_ENABLE_WERROR FALSE CACHE BOOL
18     "Enable -Werror flags to turn warnings into errors for supporting compilers.")
19   set(OPENMP_LIBDIR_SUFFIX "" CACHE STRING
20     "Suffix of lib installation directory, e.g. 64 => lib64")
21   # Do not use OPENMP_LIBDIR_SUFFIX directly, use OPENMP_INSTALL_LIBDIR.
22   set(OPENMP_INSTALL_LIBDIR "lib${OPENMP_LIBDIR_SUFFIX}")
23
24   # Group test settings.
25   set(OPENMP_TEST_C_COMPILER ${CMAKE_C_COMPILER} CACHE STRING
26     "C compiler to use for testing OpenMP runtime libraries.")
27   set(OPENMP_TEST_CXX_COMPILER ${CMAKE_CXX_COMPILER} CACHE STRING
28     "C++ compiler to use for testing OpenMP runtime libraries.")
29   set(OPENMP_LLVM_TOOLS_DIR "" CACHE PATH "Path to LLVM tools for testing.")
30 else()
31   set(OPENMP_ENABLE_WERROR ${LLVM_ENABLE_WERROR})
32   # If building in tree, we honor the same install suffix LLVM uses.
33   set(OPENMP_INSTALL_LIBDIR "lib${LLVM_LIBDIR_SUFFIX}")
34
35   if (NOT MSVC)
36     set(OPENMP_TEST_C_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
37     set(OPENMP_TEST_CXX_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++)
38   else()
39     set(OPENMP_TEST_C_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang.exe)
40     set(OPENMP_TEST_CXX_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++.exe)
41   endif()
42 endif()
43
44 # Check and set up common compiler flags.
45 include(config-ix)
46 include(HandleOpenMPOptions)
47
48 # Set up testing infrastructure.
49 include(OpenMPTesting)
50
51 set(OPENMP_TEST_FLAGS "" CACHE STRING
52   "Extra compiler flags to send to the test compiler.")
53 set(OPENMP_TEST_OPENMP_FLAGS ${OPENMP_TEST_COMPILER_OPENMP_FLAGS} CACHE STRING
54   "OpenMP compiler flag to use for testing OpenMP runtime libraries.")
55
56
57 # Build host runtime library.
58 add_subdirectory(runtime)
59
60
61 set(ENABLE_LIBOMPTARGET ON)
62 # Currently libomptarget cannot be compiled on Windows or MacOS X.
63 # Since the device plugins are only supported on Linux anyway,
64 # there is no point in trying to compile libomptarget on other OSes.
65 if (APPLE OR WIN32 OR NOT OPENMP_HAVE_STD_CPP14_FLAG)
66   set(ENABLE_LIBOMPTARGET OFF)
67 endif()
68
69 option(OPENMP_ENABLE_LIBOMPTARGET "Enable building libomptarget for offloading."
70        ${ENABLE_LIBOMPTARGET})
71 if (OPENMP_ENABLE_LIBOMPTARGET)
72   # Check that the library can actually be built.
73   if (APPLE OR WIN32)
74     message(FATAL_ERROR "libomptarget cannot be built on Windows and MacOS X!")
75   elseif (NOT OPENMP_HAVE_STD_CPP14_FLAG)
76     message(FATAL_ERROR "Host compiler must support C++14 to build libomptarget!")
77   endif()
78
79   add_subdirectory(libomptarget)
80 endif()
81
82 set(ENABLE_OMPT_TOOLS ON)
83 # Currently tools are not tested well on Windows or MacOS X.
84 if (APPLE OR WIN32)
85   set(ENABLE_OMPT_TOOLS OFF)
86 endif()
87
88 option(OPENMP_ENABLE_OMPT_TOOLS "Enable building ompt based tools for OpenMP."
89        ${ENABLE_OMPT_TOOLS})
90 if (OPENMP_ENABLE_OMPT_TOOLS)
91   add_subdirectory(tools)
92 endif()
93
94
95 # Build documentation
96 add_subdirectory(docs)
97
98 # Now that we have seen all testsuites, create the check-openmp target.
99 construct_check_openmp_target()