Merge branch 'addmainunit3-altlink-sharedstmt' into addmainunit3-altlink-sharedstmt...
[lldb.git] / openmp / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.13.4)
2
3 # Add cmake directory to search for custom cmake functions.
4 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
5
6 # llvm/runtimes/ will set OPENMP_STANDALONE_BUILD.
7 if (OPENMP_STANDALONE_BUILD OR "${CMAKE_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_SOURCE_DIR}")
8   set(OPENMP_STANDALONE_BUILD TRUE)
9   project(openmp C CXX)
10
11   # CMAKE_BUILD_TYPE was not set, default to Release.
12   if (NOT CMAKE_BUILD_TYPE)
13     set(CMAKE_BUILD_TYPE Release)
14   endif()
15
16   # Group common settings.
17   set(OPENMP_ENABLE_WERROR FALSE CACHE BOOL
18     "Enable -Werror flags to turn warnings into errors for supporting compilers.")
19   set(OPENMP_LIBDIR_SUFFIX "" CACHE STRING
20     "Suffix of lib installation directory, e.g. 64 => lib64")
21   # Do not use OPENMP_LIBDIR_SUFFIX directly, use OPENMP_INSTALL_LIBDIR.
22   set(OPENMP_INSTALL_LIBDIR "lib${OPENMP_LIBDIR_SUFFIX}")
23
24   # Group test settings.
25   set(OPENMP_TEST_C_COMPILER ${CMAKE_C_COMPILER} CACHE STRING
26     "C compiler to use for testing OpenMP runtime libraries.")
27   set(OPENMP_TEST_CXX_COMPILER ${CMAKE_CXX_COMPILER} CACHE STRING
28     "C++ compiler to use for testing OpenMP runtime libraries.")
29   set(OPENMP_LLVM_TOOLS_DIR "" CACHE PATH "Path to LLVM tools for testing.")
30 else()
31   set(OPENMP_ENABLE_WERROR ${LLVM_ENABLE_WERROR})
32   # If building in tree, we honor the same install suffix LLVM uses.
33   set(OPENMP_INSTALL_LIBDIR "lib${LLVM_LIBDIR_SUFFIX}")
34
35   if (NOT MSVC)
36     set(OPENMP_TEST_C_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
37     set(OPENMP_TEST_CXX_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++)
38   else()
39     set(OPENMP_TEST_C_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang.exe)
40     set(OPENMP_TEST_CXX_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++.exe)
41   endif()
42
43   list(APPEND LIBOMPTARGET_LLVM_INCLUDE_DIRS ${LLVM_MAIN_INCLUDE_DIR} ${LLVM_BINARY_DIR}/include)
44 endif()
45
46 # Check and set up common compiler flags.
47 include(config-ix)
48 include(HandleOpenMPOptions)
49
50 # Set up testing infrastructure.
51 include(OpenMPTesting)
52
53 set(OPENMP_TEST_FLAGS "" CACHE STRING
54   "Extra compiler flags to send to the test compiler.")
55 set(OPENMP_TEST_OPENMP_FLAGS ${OPENMP_TEST_COMPILER_OPENMP_FLAGS} CACHE STRING
56   "OpenMP compiler flag to use for testing OpenMP runtime libraries.")
57
58
59 # Build host runtime library.
60 add_subdirectory(runtime)
61
62
63 set(ENABLE_LIBOMPTARGET ON)
64 # Currently libomptarget cannot be compiled on Windows or MacOS X.
65 # Since the device plugins are only supported on Linux anyway,
66 # there is no point in trying to compile libomptarget on other OSes.
67 if (APPLE OR WIN32 OR NOT OPENMP_HAVE_STD_CPP14_FLAG)
68   set(ENABLE_LIBOMPTARGET OFF)
69 endif()
70
71 # Attempt to locate LLVM source, required by libomptarget
72 if (NOT LIBOMPTARGET_LLVM_INCLUDE_DIRS)
73   if (LLVM_MAIN_INCLUDE_DIR)
74     list(APPEND LIBOMPTARGET_LLVM_INCLUDE_DIRS ${LLVM_MAIN_INCLUDE_DIR})
75   elseif (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../llvm/include)
76     list(APPEND LIBOMPTARGET_LLVM_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/../llvm/include)
77   endif()
78 endif()
79
80 if (NOT LIBOMPTARGET_LLVM_INCLUDE_DIRS)
81   message(STATUS "Missing definition for LIBOMPTARGET_LLVM_INCLUDE_DIRS, disabling libomptarget")
82   set(ENABLE_LIBOMPTARGET OFF)
83 endif()
84
85 option(OPENMP_ENABLE_LIBOMPTARGET "Enable building libomptarget for offloading."
86        ${ENABLE_LIBOMPTARGET})
87 option(OPENMP_ENABLE_LIBOMPTARGET_PROFILING "Enable time profiling for libomptarget."
88        ${ENABLE_LIBOMPTARGET})
89 if (OPENMP_ENABLE_LIBOMPTARGET)
90   # Check that the library can actually be built.
91   if (APPLE OR WIN32)
92     message(FATAL_ERROR "libomptarget cannot be built on Windows and MacOS X!")
93   elseif (NOT OPENMP_HAVE_STD_CPP14_FLAG)
94     message(FATAL_ERROR "Host compiler must support C++14 to build libomptarget!")
95   endif()
96
97   add_subdirectory(libomptarget)
98 endif()
99
100 set(ENABLE_OMPT_TOOLS ON)
101 # Currently tools are not tested well on Windows or MacOS X.
102 if (APPLE OR WIN32)
103   set(ENABLE_OMPT_TOOLS OFF)
104 endif()
105
106 option(OPENMP_ENABLE_OMPT_TOOLS "Enable building ompt based tools for OpenMP."
107        ${ENABLE_OMPT_TOOLS})
108 if (OPENMP_ENABLE_OMPT_TOOLS)
109   add_subdirectory(tools)
110 endif()
111
112
113 # Build documentation
114 add_subdirectory(docs)
115
116 # Now that we have seen all testsuites, create the check-openmp target.
117 construct_check_openmp_target()