e72c85fda7c3a9c4162603a4b362acd8bdc2788b
[lldb.git] / pstl / CMakeLists.txt
1 #===-- CMakeLists.txt ----------------------------------------------------===##
2 #
3 # Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
4 # See https://llvm.org/LICENSE.txt for license information.
5 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
6 #
7 #===----------------------------------------------------------------------===##
8 cmake_minimum_required(VERSION 3.4.3)
9 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
10
11 set(PARALLELSTL_VERSION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/include/pstl/internal/pstl_config.h")
12 file(STRINGS "${PARALLELSTL_VERSION_FILE}" PARALLELSTL_VERSION_SOURCE REGEX "#define _PSTL_VERSION .*$")
13 string(REGEX REPLACE "#define _PSTL_VERSION (.*)$" "\\1" PARALLELSTL_VERSION_SOURCE "${PARALLELSTL_VERSION_SOURCE}")
14 math(EXPR VERSION_MAJOR "(${PARALLELSTL_VERSION_SOURCE} / 1000)")
15 math(EXPR VERSION_MINOR "((${PARALLELSTL_VERSION_SOURCE} % 1000) / 10)")
16 math(EXPR VERSION_PATCH "(${PARALLELSTL_VERSION_SOURCE} % 10)")
17
18 project(ParallelSTL VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH} LANGUAGES CXX)
19
20 option(PARALLELSTL_USE_PARALLEL_POLICIES "Enable parallel policies" OFF)
21 set(PARALLELSTL_BACKEND "tbb" CACHE STRING "Threading backend; defaults to TBB")
22
23 if (NOT TBB_DIR)
24     get_filename_component(PSTL_DIR_NAME ${CMAKE_CURRENT_SOURCE_DIR} NAME)
25     string(REPLACE pstl tbb TBB_DIR_NAME ${PSTL_DIR_NAME})
26     if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/../${TBB_DIR_NAME}/cmake")
27         get_filename_component(TBB_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${TBB_DIR_NAME}/cmake" ABSOLUTE)
28     endif()
29 endif()
30
31 ###############################################################################
32 # Setup the ParallelSTL library target
33 ###############################################################################
34 add_library(ParallelSTL INTERFACE)
35 add_library(pstl::ParallelSTL ALIAS ParallelSTL)
36 target_compile_features(ParallelSTL INTERFACE cxx_std_17)
37
38 if (PARALLELSTL_USE_PARALLEL_POLICIES)
39     message(STATUS "Using Parallel Policies")
40     if (PARALLELSTL_BACKEND STREQUAL "tbb")
41         find_package(TBB 2018 REQUIRED tbb OPTIONAL_COMPONENTS tbbmalloc)
42         message(STATUS "Parallel STL uses TBB ${TBB_VERSION} (interface version: ${TBB_INTERFACE_VERSION})")
43         target_link_libraries(ParallelSTL INTERFACE TBB::tbb)
44       else()
45         message(STATUS "Using Parallel Policies, but not tbb")
46         if (TARGET ${PARALLELSTL_BACKEND})
47             target_link_libraries(ParallelSTL INTERFACE ${PARALLELSTL_BACKEND})
48         else()
49             find_package(${PARALLELSTL_BACKEND} REQUIRED)
50             target_link_libraries(ParallelSTL INTERFACE ${${PARALLELSTL_BACKEND}_IMPORTED_TARGETS})
51         endif()
52     endif()
53 else()
54     target_compile_definitions(ParallelSTL INTERFACE PSTL_USE_PARALLEL_POLICIES=0)
55 endif()
56
57 target_include_directories(ParallelSTL
58     INTERFACE
59     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
60     $<INSTALL_INTERFACE:include>)
61
62 ###############################################################################
63 # Setup tests
64 ###############################################################################
65 enable_testing()
66 add_subdirectory(test)
67
68 ###############################################################################
69 # Install the target and the associated CMake files
70 ###############################################################################
71 include(CMakePackageConfigHelpers)
72 write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/ParallelSTLConfigVersion.cmake"
73                                  COMPATIBILITY ExactVersion)
74
75 configure_file(cmake/ParallelSTLConfig.cmake.in
76                "${CMAKE_CURRENT_BINARY_DIR}/ParallelSTLConfig.cmake"
77                @ONLY)
78
79 install(TARGETS ParallelSTL
80         EXPORT ParallelSTLTargets)
81 install(EXPORT ParallelSTLTargets
82         FILE ParallelSTLTargets.cmake
83         NAMESPACE pstl::
84         DESTINATION lib/cmake/ParallelSTL)
85 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/ParallelSTLConfig.cmake"
86               "${CMAKE_CURRENT_BINARY_DIR}/ParallelSTLConfigVersion.cmake"
87         DESTINATION lib/cmake/ParallelSTL)
88 install(DIRECTORY include/pstl
89         DESTINATION include)
90
91 add_custom_target(install-pstl
92                   COMMAND "${CMAKE_COMMAND}" -P "${PROJECT_BINARY_DIR}/cmake_install.cmake" -DCOMPONENT=ParallelSTL)