[MSVC] Don't add -nostdinc++ -isystem to runtimes builds
[lldb.git] / runtimes / CMakeLists.txt
1 # This file handles building LLVM runtime sub-projects.
2 cmake_minimum_required(VERSION 3.13.4)
3 project(Runtimes C CXX ASM)
4
5 set(LLVM_ALL_RUNTIMES "compiler-rt;libcxx;libcxxabi;libunwind;openmp")
6 set(LLVM_ENABLE_RUNTIMES "" CACHE STRING
7   "Semicolon-separated list of runtimes to build (${LLVM_ALL_RUNTIMES}), or \"all\".")
8 if(LLVM_ENABLE_RUNTIMES STREQUAL "all" )
9   set(LLVM_ENABLE_RUNTIMES ${LLVM_ALL_RUNTIMES})
10 endif()
11
12 foreach(proj ${LLVM_ENABLE_RUNTIMES})
13   set(proj_dir "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
14   if(IS_DIRECTORY ${proj_dir} AND EXISTS ${proj_dir}/CMakeLists.txt)
15     list(APPEND runtimes ${proj_dir})
16   else()
17     message(FATAL_ERROR "LLVM_ENABLE_RUNTIMES requests ${proj} but directory not found: ${proj_dir}")
18   endif()
19   string(TOUPPER "${proj}" canon_name)
20   STRING(REGEX REPLACE "-" "_" canon_name ${canon_name})
21   set(LLVM_EXTERNAL_${canon_name}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
22 endforeach()
23
24 function(runtime_register_component name)
25   set_property(GLOBAL APPEND PROPERTY SUB_COMPONENTS ${name})
26 endfunction()
27
28 find_package(LLVM PATHS "${LLVM_BINARY_DIR}" NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
29 find_package(Clang PATHS "${LLVM_BINARY_DIR}" NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
30
31 # Add path for custom and the LLVM build's modules to the CMake module path.
32 list(INSERT CMAKE_MODULE_PATH 0
33   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
34   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
35   "${CMAKE_CURRENT_SOURCE_DIR}/../llvm/cmake"
36   "${CMAKE_CURRENT_SOURCE_DIR}/../llvm/cmake/modules"
37 )
38
39 function(get_compiler_rt_path path)
40   foreach(entry ${runtimes})
41     get_filename_component(projName ${entry} NAME)
42     if("${projName}" MATCHES "compiler-rt")
43       set(${path} ${entry} PARENT_SCOPE)
44       return()
45     endif()
46   endforeach()
47 endfunction()
48
49 # Some of the runtimes will conditionally use the compiler-rt sanitizers
50 # to make this work smoothly we ensure that compiler-rt is added first in
51 # the list of sub-projects. This allows other sub-projects to have checks
52 # like `if(TARGET asan)` to enable building with asan.
53 get_compiler_rt_path(compiler_rt_path)
54 if(compiler_rt_path)
55   list(REMOVE_ITEM runtimes ${compiler_rt_path})
56   if(NOT DEFINED LLVM_BUILD_COMPILER_RT OR LLVM_BUILD_COMPILER_RT)
57     list(INSERT runtimes 0 ${compiler_rt_path})
58   endif()
59 endif()
60
61 # Setting these variables will allow the sub-build to put their outputs into
62 # the library and bin directories of the top-level build.
63 set(LLVM_LIBRARY_OUTPUT_INTDIR ${LLVM_LIBRARY_DIR})
64 set(LLVM_RUNTIME_OUTPUT_INTDIR ${LLVM_TOOLS_BINARY_DIR})
65
66 # This variable makes sure that e.g. llvm-lit is found.
67 set(LLVM_MAIN_SRC_DIR ${LLVM_BUILD_MAIN_SRC_DIR})
68 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
69
70 # This variable is used by individual runtimes to locate LLVM files.
71 set(LLVM_PATH ${LLVM_BUILD_MAIN_SRC_DIR})
72
73 if(APPLE)
74   set(LLVM_ENABLE_LIBCXX ON CACHE BOOL "")
75 endif()
76
77 include(CheckLibraryExists)
78 include(CheckCCompilerFlag)
79
80 # Disable use of the installed C++ standard library when building runtimes. If
81 # MSVC is true, we must be using the clang-cl driver, which doesn't understand
82 # these flags.
83 if (NOT MSVC)
84   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nostdinc++ -nostdlib++")
85
86   if (LLVM_EXTERNAL_LIBCXX_SOURCE_DIR AND "libcxx" IN_LIST LLVM_ENABLE_RUNTIMES)
87     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -isystem ${LLVM_EXTERNAL_LIBCXX_SOURCE_DIR}/include")
88   endif()
89 endif()
90
91 # Avoid checking whether the compiler is working.
92 set(LLVM_COMPILER_CHECKED ON)
93
94 # Handle common options used by all runtimes.
95 include(AddLLVM)
96 include(HandleLLVMOptions)
97 include(FindPythonInterp)
98
99 # Remove the -nostdlib++ option we've added earlier.
100 string(REPLACE "-nostdlib++" "" CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
101
102 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
103 if(CMAKE_HOST_APPLE AND APPLE)
104   include(UseLibtool)
105 endif()
106
107 # This can be used to detect whether we're in the runtimes build.
108 set(RUNTIMES_BUILD ON)
109
110 foreach(entry ${runtimes})
111   get_filename_component(projName ${entry} NAME)
112
113   # TODO: Clean this up as part of an interface standardization
114   string(REPLACE "-" "_" canon_name ${projName})
115   string(TOUPPER ${canon_name} canon_name)
116
117   # The subdirectories need to treat this as standalone builds. D57992 tried
118   # to get rid of this, but the runtimes treat *_STANDALONE_BUILD=OFF as if
119   # llvm & clang are configured in the same CMake, and setup dependencies
120   # against their targets. OpenMP has fixed the issue so we don't set the
121   # variable.
122   if (NOT ${canon_name} STREQUAL "OPENMP")
123     set(${canon_name}_STANDALONE_BUILD ON)
124   endif()
125
126   if(LLVM_RUNTIMES_LIBDIR_SUBDIR)
127     set(${canon_name}_LIBDIR_SUBDIR "${LLVM_RUNTIMES_LIBDIR_SUBDIR}" CACHE STRING "" FORCE)
128   endif()
129
130   # Setting a variable to let sub-projects detect which other projects
131   # will be included under here.
132   set(HAVE_${canon_name} ON)
133 endforeach()
134
135 # We do this in two loops so that HAVE_* is set for each runtime before the
136 # other runtimes are added.
137 foreach(entry ${runtimes})
138   get_filename_component(projName ${entry} NAME)
139
140   # Between each sub-project we want to cache and clear the LIT properties
141   set_property(GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
142   set_property(GLOBAL PROPERTY LLVM_LIT_PARAMS)
143   set_property(GLOBAL PROPERTY LLVM_LIT_DEPENDS)
144   set_property(GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
145
146   add_subdirectory(${entry} ${projName})
147
148   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
149   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
150   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
151   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
152
153   list(APPEND RUNTIMES_LIT_TESTSUITES ${LLVM_LIT_TESTSUITES})
154   list(APPEND RUNTIMES_LIT_PARAMS ${LLVM_LIT_PARAMS})
155   list(APPEND RUNTIMES_LIT_DEPENDS ${LLVM_LIT_DEPENDS})
156   list(APPEND RUNTIMES_LIT_EXTRA_ARGS ${LLVM_LIT_EXTRA_ARGS})
157 endforeach()
158
159 if(LLVM_INCLUDE_TESTS)
160   # Add a global check rule now that all subdirectories have been traversed
161   # and we know the total set of lit testsuites.
162
163   add_lit_target(check-runtimes
164     "Running all regression tests"
165     ${RUNTIMES_LIT_TESTSUITES}
166     PARAMS ${RUNTIMES_LIT_PARAMS}
167     DEPENDS ${RUNTIMES_LIT_DEPENDS}
168     ARGS ${RUNTIMES_LIT_EXTRA_ARGS}
169     )
170   add_custom_target(runtimes-test-depends DEPENDS ${RUNTIMES_LIT_DEPENDS})
171 endif()
172
173 get_property(SUB_COMPONENTS GLOBAL PROPERTY SUB_COMPONENTS)
174 if(SUB_COMPONENTS)
175   list(REMOVE_DUPLICATES SUB_COMPONENTS)
176   foreach(component ${SUB_COMPONENTS})
177     if(NOT TARGET ${component})
178       message(SEND_ERROR "Missing target for runtime component ${component}!")
179       continue()
180     endif()
181
182     if(TARGET check-${component})
183       list(APPEND SUB_CHECK_TARGETS check-${component})
184     endif()
185
186     if(TARGET install-${component})
187       list(APPEND SUB_INSTALL_TARGETS install-${component})
188     endif()
189     if(TARGET install-${component}-stripped)
190       list(APPEND SUB_INSTALL_TARGETS install-${component}-stripped)
191     endif()
192   endforeach()
193
194   if(LLVM_RUNTIMES_TARGET)
195     configure_file(
196       ${CMAKE_CURRENT_SOURCE_DIR}/Components.cmake.in
197       ${LLVM_BINARY_DIR}/runtimes/${LLVM_RUNTIMES_TARGET}/Components.cmake)
198   else()
199     configure_file(
200       ${CMAKE_CURRENT_SOURCE_DIR}/Components.cmake.in
201       ${LLVM_BINARY_DIR}/runtimes/Components.cmake)
202   endif()
203 endif()