# $Id$
#
# $Log$
# Revision 1.3  1999/07/14 01:02:51  short
# Version bumped to 1.2.
#
# Revision 1.2  1999/06/03 11:48:18  short
# Version bumped to 1.1.
#
# Revision 1.1.1.1  1999/05/26 13:06:26  short
# First alpha release.
#

dnl Process this file with autoconf to produce a configure script.
AC_INIT(mdsms.c)
AM_INIT_AUTOMAKE(mdsms, 1.2)
AM_CONFIG_HEADER(config.h)
AM_MAINTAINER_MODE

dnl Configuration switches.

AC_MSG_CHECKING([whether debugging is requested])
AC_ARG_ENABLE(debug,
[  --enable-debug          enable debugging output to stderr],
    enable_debug=$enableval, enable_debug=no)
AC_MSG_RESULT($enable_debug)

AC_MSG_CHECKING([whether included getopt is requested])
AC_ARG_WITH(included-getopt,
[  --with-included-getopt  use included getopt(3)],
     with_getopt=$withval, with_getopt=no)
AC_MSG_RESULT($with_getopt)

AC_MSG_CHECKING([for user-specified lock directory])
AC_ARG_WITH(lock-directory,
[  --with-lock-directory   override default search for modem lock directory],
     with_lock_directory=$withval, with_lock_directory=)
AC_MSG_RESULT($with_lock_directory)

dnl Checks for programs.
AC_PROG_CC
if test "$USE_MAINTAINER_MODE" = yes;then
  if test "$GCC" = yes;then
		CFLAGS="-Wall -ansi -pedantic -ggdb"
		LDFLAGS="$LDFLAGS -lefence"
		fi
else
	LDFLAGS="-s"
  AC_DEFINE(NDEBUG)
	fi

AC_PROG_CPP

dnl Checks for pathnames.

AC_MSG_CHECKING([for modem lock directory])
dirx=""
if test "$with_lock_directory" = no;then
  AC_MSG_RESULT([user disabled])
else
  if test yes = "$with_lock_directory" \
  	   -o  -z   "$with_lock_directory";then
    for dira in /usr /var         ;do
		for dirb in /spool ""         ;do
		for dirc in /uucp /locks /lock;do
		  dir="${dira}${dirb}${dirc}"
		  if test -d "$dir";then dirx="$dir";fi
			done;done;done
    if test -z "$dirx";then
	    AC_MSG_RESULT([none found, disabled])
    else
		  AC_MSG_RESULT([$dirx])
    fi
  else
    dirx="$with_lock_directory"
		if test -d "$dirx";then AC_MSG_RESULT([$dirx])
		else AC_MSG_RESULT([warning - directory doesn't exist: $dirx])
		fi
	fi
fi
if test -z "$dirx";then AC_DEFINE(DEF_LOCKFILE,[""])
else AC_DEFINE_UNQUOTED(DEF_LOCKFILE,"${dirx}/LCK..%s")
fi

dnl Checks for libraries.

dnl Checks for header files.
AC_HEADER_STDC

dnl Checks for typedefs, structures, and compiler characteristics.

AC_C_CONST
AC_C_INLINE

dnl Checks for library functions.

if test "$with_getopt" = no;then
	AC_CHECK_FUNCS(getopt_long)
	fi

if test "$enable_debug" = yes;then
	AC_DEFINE(DEBUG)
	fi

AC_MSG_CHECKING(whether to use included getopt)
if test "$with_getopt" = yes -o "$ac_cv_func_getopt_long" != yes ;then
	LIBOBJS="$LIBOBJS getopt1.o getopt.o"
	   AC_MSG_RESULT(yes)
else AC_MSG_RESULT(no)
fi

AC_CHECK_FUNC(MAX, AC_DEFINE(HAVE_MAX) ,
	AC_CHECK_FUNC(max, AC_DEFINE(MAX, max) AC_DEFINE(HAVE_MAX))
	)

AC_CHECK_FUNC(MIN, AC_DEFINE(HAVE_MIN) ,
	AC_CHECK_FUNC(min, AC_DEFINE(MIN, min) AC_DEFINE(HAVE_MIN))
	)

AC_MSG_CHECKING([for LINE_MAX])
AC_TRY_COMPILE([#include <limits.h>], [LINE_MAX;],
	AC_DEFINE(HAVE_LINE_MAX)  AC_MSG_RESULT(yes),
	AC_DEFINE(LINE_MAX, 4096) AC_MSG_RESULT(no))

AC_MSG_CHECKING([for CBAUD])
AC_TRY_COMPILE([#include <termios.h>], [CBAUD;],
	AC_DEFINE(HAVE_CBAUD) AC_MSG_RESULT(yes),
	AC_DEFINE(CBAUD, 0)   AC_MSG_RESULT(no))

AC_MSG_CHECKING([for CBAUDEX])
AC_TRY_COMPILE([#include <termios.h>], [CBAUDEX;],
	AC_DEFINE(HAVE_CBAUDEX) AC_MSG_RESULT(yes),
	AC_DEFINE(CBAUDEX, 0)   AC_MSG_RESULT(no))

AC_MSG_CHECKING([for unused attribute])
uns=true
for un in __unused__ unused;do
  if $uns;then
		unx="__attribute__ (($un))"
		AC_TRY_COMPILE([#include <stddef.h>],[char untest $unx;],
		AC_DEFINE_UNQUOTED(ATTR_UNUSED, $unx)
		AC_MSG_RESULT($un)
		uns=false)
		fi
	done
if $uns;then AC_DEFINE(ATTR_UNUSED,) AC_MSG_RESULT(no);fi

AC_CHECK_FUNC(snprintf, AC_DEFINE(HAVE_SNPRINTF))
AC_CHECK_FUNC(vsnprintf, AC_DEFINE(HAVE_VSNPRINTF))

AC_TYPE_SIGNAL
AC_TYPE_PID_T

AC_REPLACE_FUNCS(strdup)
dnl AC_MSG_CHECKING([for strdup])
dnl AC_TRY_COMPILE([#include <string.h>], [strdup("");],
dnl 	AC_DEFINE(HAVE_STRDUP)  AC_MSG_RESULT(yes),
dnl 	LIBOBJS="$LIBOBJS strdup.o" AC_MSG_RESULT(no))

AC_MSG_CHECKING([for working %m in printf])
AC_TRY_RUN([int main() { char s[100];
	sprintf(s,"%m");
	return(!(strcmp(s,"m") && strcmp(s,"%m")));
	}],AC_DEFINE(PRINTF_WORKS_PM) AC_MSG_RESULT(yes),AC_MSG_RESULT(no),AC_MSG_RESULT(avoiding))

# Final output.

AC_SUBST(LIBOBJS)

AC_OUTPUT(Makefile)