bin/hammock

   1 #! /usr/bin/perl
   2 # $Id$
   3
   4 use strict;
   5 use warnings;
   6 use POSIX qw(&strftime);
   7 use Getopt::Long qw(:config no_ignore_case);
   8 use Carp qw(&carp);
   9 my $start=time();
  10
  11 my $gdbcvsbare=$ENV{"HOME"}."/redhat/gdb-cvs-bare";
  12 my $binutilscvsbare=$ENV{"HOME"}."/redhat/binutils-cvs-bare";
  13 my $archermaster=$ENV{"HOME"}."/redhat/archer-master";
  14 my $fedoracvsroot=q{:pserver:anonymous:@cvs.fedoraproject.org:/cvs/pkgs};
  15 my $rhelcvsroot=q{:pserver:anonymous:@192.168.67.2:3401/cvs/dist};
  16 my $arch_i386=qr{(?:x86|i\d86|ia32)}io;
  17 my $arch_x86_64=qr{(?:x8664|x86_64|em64t)}io;
  18 my $resultdir=$ENV{"HOME"}."/.hammock-result";
  19 my @arches=qw(i386 x86_64);
  20
  21 my $error=0;
  22 sub error
  23 {
  24   carp @_;
  25   $error++;
  26 }
  27
  28 my $userid;
  29 my $force;
  30 my $parallel=9; # 1 or 2 or 3
  31 my @distro;
  32 my @componentdistro;
  33 my @path;
  34 my @arch;
  35 my $component;
  36 my $srcrpm;
  37 my @file;
  38 my @target;
  39 my $configure;
  40 my $branch;
  41 # FIXME: Connect make paralellization to the children.
  42 my $distrojobs;
  43 die if !GetOptions(
  44   "i|userid=s"=>\$userid,
  45     "force"=>\$force,
  46   "1|serial"=>sub { $parallel=1; },
  47   "2|standard"=>sub { $parallel=2; },
  48   "3|parallel"=>sub { $parallel=3; },
  49   "d|distro=s{,}"=>\@distro,
  50     "cd|componentdistro=s{,}"=>\@componentdistro,
  51   "p|path=s{,}"=>\@path,
  52   "a|arch=s{,}"=>\@arch,
  53   "c|component=s"=>\$component,
  54   "s|srcrpm=s"=>\$srcrpm,
  55     "file=s{,}"=>\@file,
  56     "target=s{,}"=>\@target,
  57   "D|distrojobs=s"=>\$distrojobs,
  58     "configure=s"=>\$configure,
  59     "branch=s"=>\$branch,
  60 );
  61 $component and ($component=~m{^(?:(?:fedora|rhel)(?:gdb|binutils|glibc)|gdbcvs|binutilscvs|archer-.*|/home/.*)$} or die "-c|--component required to be: fedoragdb|rhelgdb|fedorabinutils|rhelbinutils|fedoraglibc|rhelglibc|gdbcvs|binutilscvs|archer-*|/home/*");
  62 $component and $component=~m{^/home/} and (-f "$component/gdb/gdbtypes.c" or die "$component/gdb/gdbtypes.c not found");
  63 $component and $srcrpm and die "-c|--component excludes -s|--srcrpm";
  64 $component or $srcrpm or die "-c|--component or -s|--srcrpm required";
  65 $component||="";  # Make `eq' not complaining.
  66 my $cvsbranch;
  67 if ($component=~/^(gdb|binutils)cvs$/) {
  68   $cvsbranch=(!$branch?"-A":"-r $branch");
  69 } else {
  70   die "--branch currently unsupported for non-CVS sources" if $branch;
  71 }
  72 @target and ($srcrpm or $component=~/^(?:fedora|rhel)/) and die "--target is available only for baretestsuite modes";
  73 my %target;
  74 do { error "Duplicate target: $_\n" if $target{$_}++; } for @target;
  75 @arch="x86_64" if @target&&!@arch;
  76 for my $file (@file) {
  77   -f $file and -r $file or error "-f|--file $file not readable: $!";
  78 }
  79 $distrojobs=(@target?1:2) if !defined $distrojobs;
  80 $distrojobs=~/^\d+$/ or die "-D|distrojobs must be a number: $distrojobs";
  81 $distrojobs>=1 or die "-D|distrojobs must be positive: $distrojobs";
  82 # User may want to modify ASAP her files submitted for the test.
  83 my $will_copy=@file || $component=~m{^/home/};
  84 $parallel||=$will_copy ? 2 : 1;
  85 error "Excessive arguments: @ARGV" if @ARGV;
  86 @arch=@arches if !@arch;
  87 my $path=join(":",@path) if @path;
  88 @componentdistro and @componentdistro!=@distro and die "--cd|--componentdistro must have the same elements count as -d|--distro";
  89
  90 sub distro_normalize($;$)
  91 {
  92   my($name,$force)=@_;
  93   local $_=$name;
  94
  95   s{^/var/lib/mock/+}{};
  96   s{/+$}{};
  97   s/^.*$/\L$&/s;
  98   s/^(?:devel|rawhide)\b/fedora-rawhide/;
  99   s/^(?:epel|rhel|centos)-?(\d)/epel-$1/;
 100   s/^(?:f|fedora)-?(\d)/fedora-$1/;
 101   my @archuse;
 102   @archuse="" if -d "/var/lib/mock/$_";
 103   @archuse="i386" if s/-$arch_i386$//o;
 104   @archuse="x86_64" if s/-$arch_x86_64$//o;
 105
 106   for my $arch (@archuse?@archuse:@arch) {
 107     my $dir="/var/lib/mock/$_".(!$arch?"":"-$arch");
 108     $force or -d $dir or error "No distro: $dir";
 109   }
 110
 111   return ($_,@archuse);
 112 }
 113
 114 # epel-\d-i386|fedora-\d-i386|fedora-rawhide-i386
 115 my @distrouse;
 116 for my $distroi (0..$#distro) {
 117   my $distro=$distro[$distroi];
 118   my $componentdistro=$componentdistro[$distroi];
 119   my @archuse;
 120   if ($componentdistro) {
 121     my $force=($componentdistro=~s/!$//);
 122     ($componentdistro,@archuse)=distro_normalize $componentdistro,$force;
 123     @archuse and die "--cd|--componentdistro must have no arch: ".join(" ",@archuse);
 124   }
 125   ($distro,@archuse)=distro_normalize $distro;
 126   $componentdistro||=$distro;
 127   @archuse=@arch if !@archuse;
 128   for my $archuse (@archuse) {
 129     for my $target (@target?@target:undef()) {
 130       push @distrouse,{"distro"=>$distro.(!$archuse?"":"-$archuse"),"componentdistro"=>$componentdistro,"target"=>$target};
 131     }
 132   }
 133 }
 134
 135 # "-p", "mayexist"
 136 sub newdir($;@)
 137 {
 138   my($dir,@opt)=@_;
 139
 140   my %opt=map(($_=>1),@opt);
 141   warn "+ mkdir".($opt{"-p"} ? " -p" : "")." $dir\n";
 142   mkdir $dir or ($opt{"mayexist"} && $!{EEXIST}) or die "mkdir $dir: $!";
 143 }
 144
 145 my $log;
 146 # "bare"
 147 sub spawn($;%)
 148 {
 149   my($cmd,@opt)=@_;
 150
 151   my %opt=map(($_=>1),@opt);
 152   my $ok;
 153   if (!$opt{"bare"}) {
 154     $cmd="set -ex; $cmd";
 155     $ok="$log.ok" if $log;
 156     $cmd="($cmd; touch $ok) 2>&1|tee -a $log; test -f $ok" if $log;
 157     unlink $ok if $ok;
 158   } else {
 159     warn "+ $cmd\n";
 160   }
 161   # warn "+ $cmd\n";
 162   system $cmd and die "$cmd: $!";
 163   unlink $ok if $ok;
 164 }
 165
 166 my $basedir=$ENV{"HOME"}."/hammock";
 167 newdir $basedir,"mayexist";
 168 my $idbase=strftime("%Y%m%d",localtime());
 169 my $id;
 170 my $dir;
 171 for my $seq (defined $userid ? $userid : (0..99)) {
 172   $id=$idbase.(defined $userid ? $seq : sprintf("%02d",$seq));
 173   $dir="$basedir/$id";
 174   last if ! -e $dir;
 175 }
 176 spawn "rm -rf $dir" if -d $dir && $force && defined $userid;
 177 error "Directory not free: $dir" if !$id || !$dir || -e $dir;
 178 print STDERR "ID = $id | dir = $dir\n";
 179 error "No distros specified" if !@distrouse;
 180 die "$error errors seen, aborted" if $error;
 181
 182 sub writefile
 183 {
 184   my($fname,$content)=@_;
 185
 186   local *F;
 187   open F,">$fname" or die $fname;
 188   print F $content or die $fname;
 189   close F or die $fname;
 190 }
 191
 192 spawn "renice 20 -p $$";
 193 newdir $dir;
 194 $log="$dir/log";
 195 my $resultid="$resultdir/$id";
 196 my $resultidxz="$resultid.tar.xz";
 197 newdir $resultdir,"mayexist";
 198 spawn "rm -rf $resultid" if -d $resultid && $force;
 199 newdir $resultid;
 200 unlink $resultidxz or $!{ENOENT} or die "unlink $resultidxz: $!";
 201 spawn "uname -r >$dir/kernel";
 202 my %dump=(
 203   "path"=>$path,
 204   "component"=>$component,
 205   "srcrpm"=>$srcrpm,
 206   "file"=>join("\n",@file),
 207   "configure"=>$configure,
 208 );
 209 while (my($name,$val)=each(%dump)) {
 210   next if !$val;
 211   writefile "$dir/$name","$val\n";
 212   link "$dir/$name","$resultid/$name" or warn "link $dir/$name $resultid/$name: $!";
 213 }
 214 for my $file (@file) {
 215   newdir "$dir/file.d","mayexist";
 216   (my $base=$file)=~s{^.*/}{};
 217   my $d="$dir/file.d/$base";
 218   link $file,$d or die "link $file $d: $!";
 219   newdir "$resultid/file.d","mayexist";
 220   link $d,"$resultid/file.d/$base" or warn "link $file $resultid/file.d/$base: $!";
 221 }
 222
 223 sub subst
 224 {
 225   my($sub,$in,$out)=@_;
 226
 227   $out||=$in;
 228
 229   local *F;
 230   open F,$in or die $in;
 231   local $_=do { local $/; <F>; } or die $in;
 232   close F or die $in;
 233
 234   &{$sub}() or die $_."\nError substituting $in";
 235
 236   writefile $out,$_;
 237 }
 238
 239 # PID->distro
 240 my %child;
 241 while (@distrouse || keys(%child)) {
 242   while (keys(%child)<$distrojobs && @distrouse) {
 243     my $distrouse=shift @distrouse;
 244     my $distro=$distrouse->{"distro"};
 245     my $componentdistro=$distrouse->{"componentdistro"};
 246     my $target=$distrouse->{"target"};
 247     my $rpmbuild="rpmbuild";
 248
 249     my $cvsbasedir;
 250     my $cvsroot;
 251     my $cvsrepo;
 252     if ($component=~/^fedora(.*)$/) {
 253       $cvsrepo=$1;
 254       $cvsbasedir="F-$1" if $componentdistro=~/^fedora-(\d+)$/;
 255       $cvsbasedir="devel" if $componentdistro=~/^fedora-rawhide$/;
 256       die "$component vs. $componentdistro" if !$cvsbasedir;
 257       $cvsroot=$fedoracvsroot;
 258     }
 259     if ($component=~/^rhel(.*)$/) {
 260       $cvsrepo=$1;
 261       $cvsbasedir="RHEL-$1" if $componentdistro=~/^epel-(\d+)$/;
 262       die "$component vs. $componentdistro" if !$cvsbasedir;
 263       $cvsroot=$rhelcvsroot;
 264       # EPEL still uses Berkeley DB version 8 while F-11+ (F-10?) uses version 9.
 265       # Using db_dump and db_load would no longer make it mock compatible.
 266       $rpmbuild.=q{ --dbpath $PWD --nodeps};
 267     }
 268
 269     my $distrodirbase=$distro;
 270     $distrodirbase.="-$target" if $target;
 271     my $distrodir="$dir/$distrodirbase";
 272     newdir $distrodir;
 273     $log="$distrodir/log";
 274     my $out="$distrodir/out";
 275
 276     if ($parallel>1) {
 277       my $pid=fork();
 278       die if !defined $pid;
 279       if ($pid) {
 280         $child{$pid}=$distrodirbase;
 281         next;
 282       }
 283     }
 284
 285     my $builddir="$distrodir/build";
 286     newdir $builddir;
 287
 288     # Do not use mockrun as the rpm database may be in a different version.
 289     spawn "rpm -r /var/lib/mock/$distro/root -qa|sort >$distrodir/rpm-qa";
 290
 291     $::distro=$distro;
 292     sub mockrun($)
 293     {
 294       my($c)=@_;
 295
 296       $c="export PATH=\"$path:\$PATH\"; $c" if $path;
 297       $c="export MAKEFLAGS=\"-j\$[`getconf _NPROCESSORS_ONLN`*3/2]\"; $c";
 298       $c="export http_proxy=http://127.0.0.1:3128/; $c";
 299       $c="set -ex; cd $builddir; $c";
 300       die "found ': $c" if $c=~/'/;
 301       spawn "mockrun $::distro '$c'";
 302     }
 303
 304     if ($cvsbasedir) {
 305       die if !$cvsroot;
 306       die if !$cvsrepo;
 307       spawn "cd $distrodir; cvs -q -z3 -d $cvsroot co rpms/$cvsrepo/$cvsbasedir";
 308       my $componentdir="$distrodir/rpms/$cvsrepo/$cvsbasedir";
 309       -d $componentdir or die "Failed checkout to: $componentdir";
 310       # Required for RHEL; Fedora does so automatically.
 311       spawn "cd $componentdir/..; cvs -q -z3 -d $cvsroot co common";
 312       # Workaround (RHEL-5?) curl which uses `Pragma: nocache' on $http_proxy.
 313       subst sub { s{echo "curl }{$&-H 'Pragma: cache' }; },"$componentdir/../common/Makefile.common";
 314
 315       for my $file (@file) {
 316         my $filebase=$file;
 317         $filebase=~s{^.*/}{};
 318         my $target="$componentdir/$filebase";
 319         # Some *.patch files may be new.
 320         # -f $target or die "File $file does not exist at $target";
 321         spawn "rm -f $target; cp -p $file $target";
 322       }
 323
 324       my $glob="$componentdir/*.src.rpm";
 325       @{[glob $glob]}==0 or die "Found some before test-srpm: $glob";
 326       # No `spawn' as we could get:
 327       # error: unpacking of archive failed on file X;4a56efef: cpio: MD5 sum mismatch
 328       mockrun "cd $componentdir; make test-srpm";
 329       my @srcrpm=(glob $glob);
 330       @srcrpm==1 or die "Did not find 1 srcrpm: @srcrpm";
 331       $srcrpm=$srcrpm[0];
 332     }
 333
 334     if ($srcrpm) {
 335       my $srcrpmbasename=$srcrpm;
 336       $srcrpmbasename=~s{^.*/}{};
 337       spawn "cp -p $srcrpm $builddir/$srcrpmbasename";
 338
 339       my $rpmbuildlocal=$rpmbuild.q{ --define "_topdir $PWD" --define "_builddir $PWD" --define "_rpmdir $PWD" --define "_sourcedir $PWD" --define "_specdir $PWD" --define "_srcrpmdir $PWD" --define "_build_name_fmt %%{NAME}-%%{VERSION}-%%{RELEASE}.%%{ARCH}.rpm"};
 340       $rpmbuildlocal="orphanripper $rpmbuildlocal" if $cvsrepo && $cvsrepo eq "glibc";
 341       mockrun $rpmbuildlocal." --rebuild --with testsuite".($parallel<2 ? "" : " --with parallel")." $srcrpmbasename";
 342     }
 343
 344     my $baretestsuite;
 345
 346     if ($component=~/^(gdb|binutils)cvs$/) {
 347       my $which=$1;
 348       my $cvsbare=$which eq "gdb" ? $gdbcvsbare : $binutilscvsbare;
 349       if (-d $cvsbare) {
 350         spawn "cp -a $cvsbare $builddir/src; cd $builddir/src; cvs update $cvsbranch";
 351       } else {
 352         spawn "cd $builddir; cvs -q -z3 -d :pserver:anoncvs:\@sourceware.org:/cvs/src co $cvsbranch $which";
 353       }
 354       spawn "cd $builddir/src; test -z \"\$(cvs update $cvsbranch)\"";
 355       $baretestsuite="$builddir/src";
 356     }
 357
 358     if ($component=~/^archer-/) {
 359       if (-d $archermaster) {
 360         spawn "cp -a $archermaster $builddir/$component; cd $builddir/$component; git pull"
 361       } else {
 362         spawn "cd $builddir; git clone git://sourceware.org/git/archer.git; mv -f archer $component";
 363       }
 364       spawn "cd $builddir/$component; git checkout -b $component origin/$component; [ \"`git status`\" = \"# On branch $component\nnothing to commit (working directory clean)\" ]";
 365       $baretestsuite="$builddir/$component";
 366     }
 367
 368     if ($component=~m{^/home/}) {
 369       spawn "cp -a $component $builddir/src; cd $builddir/src; find -name \"*.[oa]\" -o -name \"*.l[oa]\" -o -name gdb.sum -o -name gdb.log|xargs rm -f; make clean || :";
 370       $baretestsuite="$builddir/src";
 371     }
 372
 373     if ($baretestsuite) {
 374       for my $file (@file) {
 375         my $target="$baretestsuite/$file";
 376         if ($file=~m{[.](R?)patch$}) {
 377           my $R=$1;
 378           my $fileabs=$file;
 379           $fileabs=$ENV{"PWD"}."/$fileabs" if $fileabs!~m{^/};
 380           spawn "cd $baretestsuite; patch -${R}p".($component=~/binutils/ ? "0" : "1")." <$fileabs";
 381         } else {
 382           -f $target or $file=~m{/testsuite/} or die "File $file does not exist at $target";
 383           spawn "rm -f $target; cp -p $file $target";
 384         }
 385       }
 386
 387       my $errs1="errs1";
 388       $errs1.=" --target=$target" if $target;
 389       $errs1.=" $configure" if $configure;
 390
 391       if ($component eq "binutilscvs") {
 392         mockrun "cd $baretestsuite; $errs1; errs2; ulimit -c unlimited; orphanripper make -k check || :; mkdir $out; ".q{for file in {gas/testsuite/gas,ld/ld,binutils/binutils}.{sum,log};do ln $file}." $out/binutils-$distro-".q{$(basename $file) || :; done;};
 393       } else {
 394         my @check=($distro=~/-x86_64/ ? qw(-m64 -m32) : -m32);
 395         @check=map("check//unix/$_",@check);
 396         # FSF GDB has no PIE support.
 397         # @check=map({($_,"$_/-fPIE/-pie");} @check);
 398         # for i in ".join(" ",@check).";do orphanripper make -k \$i || :;done
 399         mockrun "cd $baretestsuite; $errs1; errs2; cd gdb; ulimit -c unlimited; orphanripper make -k ".join(" ",@check)." || :; mkdir $out; ".q{for t in sum log;do for file in testsuite*/gdb.$t;do suffix="${file#testsuite.unix.}"; suffix="${suffix%/gdb.$t}"; ln $file}." $out/gdb-$distro".q{$suffix.$t || :; done; done;};
 400       }
 401       # gdbunpack does:
 402       #         perl -i -pe 's{\Q'"$HOME"'\E/.*?/build/[^/]*/}{}g' "$base"/*
 403       my $HOME=$ENV{"HOME"};
 404       for my $file (<$out/*>) {
 405         subst sub { s{\Q$HOME\E/.*?/build/[^/]*/}{}g; },$file;
 406       }
 407     } else {
 408       die "internal error" if @target;
 409     }
 410
 411     # Call gdbunpack only if no direct $out directory will be created.
 412     # It is needed only for .src.rpm-built testsuites, no matter how .src.rpm
 413     # got created.
 414     my @testinlog;
 415     if ($component=~/^(?:fedora|rhel)glibc$/) {
 416       @testinlog=(qr/={20}TESTING DETAILS={17}/,qr/={20}PLT RELOCS END={18}/);
 417     }
 418     if (@testinlog) {
 419       subst sub { s{^.*?\n($testinlog[0]\n.*\n$testinlog[1]\n).*$}{$1}s; },$log,$out;
 420     } elsif ($cvsbasedir || $srcrpm) {
 421       # Applies both to gdb and binutils.
 422       spawn "gdbunpack $log";
 423     }
 424
 425     my $resultout="$resultdir/$id/$distrodirbase";
 426     newdir $resultout;
 427     $resultout.="/out";
 428     newdir $resultout;
 429     for my $fname (glob "$out/*") {
 430       (my $base=$fname)=~s{^.*/}{};
 431       my $d="$resultout/$base";
 432       warn "+ link $fname $d\n";
 433       link $fname,$d or warn $!;
 434     }
 435
 436     exit 0 if $parallel>1;
 437   }
 438
 439   print STDERR "waiting for ".scalar(keys(%child))." children, ".scalar(@distrouse)." distros to go...\n";
 440   my $pid=wait();
 441   next if $pid==-1 && $!==10; # 10==No child processes
 442   die "wait()==-1: $!" if $pid==-1;
 443   die "not found pid $pid" if !$child{$pid};
 444   error "weird status $? for pid $pid: ".$child{$pid} if $?;
 445   print STDERR "finished: $pid ".$child{$pid}."\n";
 446   delete $child{$pid};
 447 }
 448 die if keys(%child);
 449 die if @distrouse;
 450
 451 spawn "(set -e -o pipefail;cd $resultdir;tar cf - $id|xz -9e >$resultidxz;rm -rf $id)&","bare";
 452
 453 sub timestr($)
 454 {
 455   my($sec)=@_;
 456   my $r="";
 457
 458   if ($sec>=60*60) {
 459     $r.=int($sec/(60*60))."h";
 460     $sec%=60*60;
 461   }
 462   if ($r || $sec>=60) {
 463     $r.=int($sec/60)."m";
 464     $sec%=60;
 465   }
 466   $r.=$sec."s";
 467
 468   return $r;
 469 }
 470
 471 print STDERR "ID = $id | dir = $dir\n";
 472 my $time=timestr(time()-$start);
 473 print STDERR "total time=$time\n";
 474 writefile "$dir/time","$time\n";
 475 die "$error errors seen, aborted" if $error;
 476 print STDERR "done\n";