#! /usr/bin/perl

use strict;
use warnings;
use POSIX qw(&strftime);
use Getopt::Long qw(:config no_ignore_case);
use Carp qw(&carp);
my $start=time();

my $gdbcvsmaster=$ENV{"HOME"}."/redhat/gdb-cvs-master";
my $binutilscvsmaster=$ENV{"HOME"}."/redhat/binutils-cvs-master";
my $archermaster=$ENV{"HOME"}."/redhat/gdb-master";
my $fedoragitroot=q{git://pkgs.fedoraproject.org};
#Unknown host cvs.devel.redhat.com.
#my $rhelcvsroot=q{:pserver:anonymous:@cvs.devel.redhat.com:/cvs/dist};
my $rhelcvsroot=q{:ext:cvs.devel.redhat.com:/cvs/dist};
my $arch_i386=qr{(?:x86|i\d86|ia32)}io;
my $arch_x86_64=qr{(?:x8664|x86_64|em64t)}io;
my $resultdir=$ENV{"HOME"}."/.hammock-result";
my @arches=qw(i386 x86_64);

my $error=0;
sub error
{
  carp @_;
  $error++;
}

my $userid;
my $force;
my $parallel=1;
my @distro;
my @componentdistro;
my @path;
my @arch;
my $component;
my $srcrpm;
my @file;
my @target;
my $configure;
my $branch;
# FIXME: Connect make paralellization to the children.
my $distrojobs;
my $gdbcvspie;
my $strip;
# FIXME: 20100911servpatched-f14:
# readchar: Connection reset by peer
# Remote side has terminated connection.  GDBserver will reopen the connection.
# Can't bind address: Address already in use.
# <last 2 lines repearing>
my $gdbserver;
my $valgrind;
my $gdbindex;
my $dwarf;
# Use --dwarf=40 for: --dwarf=4 -fno-debug-types-section
# Use --dwarf=41 for: --dwarf=4    -fdebug-types-section
my $debug_types_section;
my $orphanripper=1;
die if !GetOptions(
  "i|userid=s"=>\$userid,
    "force"=>\$force,
    "serial"=>sub { $parallel=0; },
    "parallel"=>sub { $parallel=1; },
  "d|distro=s{,}"=>\@distro,
    "cd|componentdistro=s{,}"=>\@componentdistro,
  "p|path=s{,}"=>\@path,
  "a|arch=s{,}"=>\@arch,
  "c|component=s"=>\$component,
  "s|srcrpm=s"=>\$srcrpm,
    "file=s{,}"=>\@file,
    "target=s{,}"=>\@target,
  "D|distrojobs=s"=>\$distrojobs,
    "configure=s"=>\$configure,
    "branch=s"=>\$branch,
    "gdbcvspie"=>\$gdbcvspie,
    "strip"=>\$strip,
    "gdbserver"=>\$gdbserver,
    "valgrind"=>\$valgrind,
    "gdbindex"=>\$gdbindex,
    "dwarf=i"=>\$dwarf,
    "orphanripper!"=>\$orphanripper,
);
$component and ($component=~m{^(?:(?:fedora|rhel)(?:gdb|binutils|glibc)|gdbcvs|binutilscvs|archer-.*|/home/.*)$} or die "-c|--component required to be: fedoragdb|rhelgdb|fedorabinutils|rhelbinutils|fedoraglibc|rhelglibc|gdbcvs|binutilscvs|archer-*|/home/*");
$component and $component=~m{^/home/} and (-f "$component/gdb/gdbtypes.c" or die "$component/gdb/gdbtypes.c not found");
$component and $srcrpm and die "-c|--component excludes -s|--srcrpm";
$component or $srcrpm or die "-c|--component or -s|--srcrpm required";
$component||="";  # Make `eq' not complaining.
my $cvsbranch;
if ($component=~/^(gdb|binutils)cvs$/) {
  $cvsbranch=(!$branch?"-A":"-r $branch");
} else {
  die "--branch currently unsupported for non-CVS sources" if $branch;
}
!$gdbcvspie or $component eq "gdbcvs" or die "--gdbcvspie requires -c gdbcvs";
@target and ($srcrpm or $component=~/^(?:fedora|rhel)/) and die "--target is available only for baretestsuite modes";
$strip and ($srcrpm or $component=~/^(?:fedora|rhel)/) and die "--strip is available only for baretestsuite modes";
$gdbserver and $component ne "gdbcvs" and die "--gdbserver is available only for gdbcvs";
$valgrind and $component ne "gdbcvs" and die "--valgrind is available only for gdbcvs";
$gdbserver and $valgrind and die "--gdbserver and --valgrind are mutually exclusive";
($gdbserver || $valgrind) and $gdbindex and die "--gdbserver|--valgrind and --gdbindex are mutually exclusive";
do { $debug_types_section=0; $dwarf=4; } if ($dwarf||0)==40;
do { $debug_types_section=1; $dwarf=4; } if ($dwarf||0)==41;
!defined $dwarf or ($dwarf>=2 && $dwarf<=4) or die "--dwarf requires DWARF version number";
($gdbserver || $valgrind || $gdbindex) and $dwarf and die "--gdbserver|--valgrind|--gdbindex and --dwarf are mutually exclusive";
$orphanripper=($orphanripper?"orphanripper":"");
my %target;
do { error "Duplicate target: $_\n" if $target{$_}++; } for @target;
@arch="x86_64" if @target&&!@arch;
for my $file (@file) {
  -f $file and -r $file or error "-f|--file $file not readable: $!";
}
$distrojobs=(@target?1:2) if !defined $distrojobs;
$distrojobs=~/^\d+$/ or die "-D|distrojobs must be a number: $distrojobs";
$distrojobs>=1 or die "-D|distrojobs must be positive: $distrojobs";
error "Excessive arguments: @ARGV" if @ARGV;
@arch=@arches if !@arch;
my $path=join(":",@path) if @path;
@componentdistro and @componentdistro!=@distro and die "--cd|--componentdistro must have the same elements count as -d|--distro";

sub distro_normalize($;$)
{
  my($name,$force)=@_;
  local $_=$name;

  s{^/var/lib/mock/+}{};
  s{/+$}{};
  s/^.*$/\L$&/s;
  s/^(?:devel|rawhide)\b/fedora-rawhide/;
  s/^(?:epel|centos)-?(\d)/epel-$1/;
  s/^(?:rhel)-?(\d)/rhel-$1/;
  s/^(?:f|fedora)-?(\d)/fedora-$1/;
  my @archuse;
  @archuse="" if -d "/var/lib/mock/$_";
  @archuse="i386" if s/-$arch_i386$//o;
  @archuse="x86_64" if s/-$arch_x86_64$//o;

  for my $arch (@archuse?@archuse:@arch) {
    my $dir="/var/lib/mock/$_".(!$arch?"":"-$arch");
    $force or -d $dir or error "No distro: $dir";
  }

  return ($_,@archuse);
}

# epel-\d-i386|fedora-\d-i386|fedora-rawhide-i386
my @distrouse;
for my $distroi (0..$#distro) {
  my $distro=$distro[$distroi];
  my $componentdistro=$componentdistro[$distroi];
  my @archuse;
  if ($componentdistro) {
    my $force=($componentdistro=~s/!$//);
    ($componentdistro,@archuse)=distro_normalize $componentdistro,$force;
    @archuse and die "--cd|--componentdistro must have no arch: ".join(" ",@archuse);
  }
  ($distro,@archuse)=distro_normalize $distro;
  $componentdistro||=$distro;
  @archuse=@arch if !@archuse;
  for my $archuse (@archuse) {
    for my $target (@target?@target:undef()) {
      push @distrouse,{"distro"=>$distro.(!$archuse?"":"-$archuse"),"componentdistro"=>$componentdistro,"target"=>$target};
    }
  }
}

# "-p", "mayexist"
sub newdir($;@)
{
  my($dir,@opt)=@_;

  my %opt=map(($_=>1),@opt);
  warn "+ mkdir".($opt{"-p"} ? " -p" : "")." $dir\n";
  mkdir $dir or ($opt{"mayexist"} && $!{EEXIST}) or die "mkdir $dir: $!";
}

my $log;
# "bare"
sub spawn($;%)
{
  my($cmd,@opt)=@_;

  my %opt=map(($_=>1),@opt);
  my $ok;
  if (!$opt{"bare"}) {
    $cmd="set -ex; $cmd";
    $ok="$log.ok" if $log;
    $cmd="($cmd; touch $ok) 2>&1|tee -a $log; test -f $ok" if $log;
    unlink $ok if $ok;
  } else {
    warn "+ $cmd\n";
  }
  # warn "+ $cmd\n";
  system $cmd and die "$cmd: $!";
  unlink $ok if $ok;
}

my $basedir=$ENV{"HOME"}."/hammock";
newdir $basedir,"mayexist";
my $idbase=strftime("%Y%m%d",localtime());
my $id;
my $dir;
for my $seq (defined $userid ? $userid : (0..99)) {
  $id=$idbase.(defined $userid ? $seq : sprintf("%02d",$seq));
  $dir="$basedir/$id";
  last if ! -e $dir;
}
spawn "chmod -R u+w $dir; rm -rf $dir" if -d $dir && $force && defined $userid;
error "Directory not free: $dir" if !$id || !$dir || -e $dir;
print STDERR "ID = $id | dir = $dir\n";
error "No distros specified" if !@distrouse;
die "$error errors seen, aborted" if $error;

sub writefile
{
  my($fname,$content)=@_;

  local *F;
  open F,">$fname" or die $fname;
  print F $content or die $fname;
  close F or die $fname;
}

# /etc/cgconfig.conf
spawn "cgclassify -g '*':hammock $$ || :";

spawn "renice +19 -p $$";
spawn "ionice -c3 -p $$";
newdir $dir;
$log="$dir/log";
my $resultid="$resultdir/$id";
my $resultidxz="$resultid.tar.xz";
newdir $resultdir,"mayexist";
spawn "rm -rf $resultid" if -d $resultid && $force;
newdir $resultid;
unlink $resultidxz or $!{ENOENT} or die "unlink $resultidxz: $!";
spawn "uname -r >$dir/kernel";
my %dump=(
  "path"=>$path,
  "component"=>$component,
  "branch"=>$branch,
  "srcrpm"=>$srcrpm,
  "file"=>join("\n",@file),
  "configure"=>$configure,
  "gdbcvspie"=>$gdbcvspie,
  "gdbserver"=>$gdbserver,
  "valgrind"=>$valgrind,
  "gdbindex"=>$gdbindex,
  "dwarf"=>$dwarf,
  "debug_types_section"=>$debug_types_section,
  "orphanripper"=>$orphanripper,
);
while (my($name,$val)=each(%dump)) {
  next if !$val;
  writefile "$dir/$name","$val\n";
  link "$dir/$name","$resultid/$name" or warn "link $dir/$name $resultid/$name: $!";
}
for my $file (@file) {
  newdir "$dir/file.d","mayexist";
  (my $base=$file)=~s{^.*/}{};
  my $d="$dir/file.d/$base";
  link $file,$d or die "link $file $d: $!";
  newdir "$resultid/file.d","mayexist";
  link $d,"$resultid/file.d/$base" or warn "link $file $resultid/file.d/$base: $!";
}

sub subst
{
  my($sub,$in,$out)=@_;

  $out||=$in;

  local *F;
  open F,$in or die $in;
  local $_=do { local $/; <F>; } or die $in;
  close F or die $in;

  &{$sub}() or die $_."\nError substituting $in";

  writefile $out,$_;
}

sub copyfiles($)
{
  my($targetdir)=@_;

  for my $file (@file) {
    my $filebase=$file;
    $filebase=~s{^.*/}{};
    my $target="$targetdir/$filebase";
    # Some *.patch files may be new.
    # -f $target or die "File $file does not exist at $target";
    spawn "rm -f $target; cp -p $file $target";
  }
}

# PID->distro
my %child;
while (@distrouse || keys(%child)) {
  while (keys(%child)<$distrojobs && @distrouse) {
    my $distrouse=shift @distrouse;
    my $distro=$distrouse->{"distro"};
    my $componentdistro=$distrouse->{"componentdistro"};
    my $target=$distrouse->{"target"};
    my $rpmbuild="rpmbuild";

    my $cvsbasedir;
    my $gitbranch;
    my $cvsroot;
    my $gitroot;
    my $cvsrepo;
    my $gitrepo;
    if ($component=~/^fedora(.*)$/) {
      $gitrepo=$1;
      $gitbranch="f$1" if $componentdistro=~/^fedora-(\d+)$/;
      $gitbranch="master" if $componentdistro=~/^fedora-rawhide$/;
      die "$component vs. $componentdistro" if !$gitbranch;
      $gitroot=$fedoragitroot;
    }
    if ($component=~/^rhel(.*)$/) {
      $cvsrepo=$1;
      $cvsbasedir="RHEL-$1" if $componentdistro=~/^(?:epel|rhel)-(\d+)$/;
      die "$component vs. $componentdistro" if !$cvsbasedir;
      $cvsroot=$rhelcvsroot;
      # EPEL still uses Berkeley DB version 8 while F-11+ (F-10?) uses version 9.
      # Using db_dump and db_load would no longer make it mock compatible.
      $rpmbuild.=q{ --dbpath $PWD --nodeps};
    }

    my $distrodirbase=$distro;
    $distrodirbase.="-$target" if $target;
    my $distrodir="$dir/$distrodirbase";
    newdir $distrodir;
    $log="$distrodir/log";
    my $out="$distrodir/out";
    newdir $out;

    if ($parallel) {
      my $pid=fork();
      die if !defined $pid;
      if ($pid) {
	$child{$pid}=$distrodirbase;
	next;
      }
    }

    my $builddir="$distrodir/build";
    newdir $builddir;

    # Do not use mockrun as the rpm database may be in a different version.
    spawn "rpm -r /var/lib/mock/$distro/root -qa|sort >$out/rpm-qa";

    $::distro=$distro;
    sub mockrun($)
    {
      my($c)=@_;

      $c="export PATH=\"$path:\$PATH\"; $c" if $path;
      $c="export MAKEFLAGS=\"-j\$[`getconf _NPROCESSORS_ONLN`*3/2]\"; $c";
      $c="export http_proxy=http://127.0.0.1:3128/; $c";
      $c="set -ex; cd $builddir; $c";
      die "found ': $c" if $c=~/'/;
      spawn "mockrun $::distro '$c'";
    }

    if ($gitbranch) {
      die if !$gitroot;
      die if !$gitrepo;
      die if !$gitbranch;
      spawn "cd $distrodir; git clone -b $gitbranch $gitroot/$gitrepo $component";
      my $componentdir="$distrodir/$component";
      -d $componentdir or die "Failed checkout to: $componentdir";
      copyfiles $componentdir;
      spawn "cd $componentdir; fedpkg verrel >$out/verrel";
      my $glob="$componentdir/*.src.rpm";
      @{[glob $glob]}==0 or die "Found some before test-srpm: $glob";
      # No `spawn' as we could get:
      # error: unpacking of archive failed on file X;4a56efef: cpio: MD5 sum mismatch
      mockrun "cd $componentdir; fedpkg srpm";
      my @srcrpm=(glob $glob);
      @srcrpm==1 or die "Did not find 1 srcrpm: @srcrpm";
      $srcrpm=$srcrpm[0];
    }

    if ($cvsbasedir) {
      die if !$cvsroot;
      die if !$cvsrepo;
      die if !$cvsbasedir;
      spawn "cd $distrodir; cvs -q -z3 -d $cvsroot co rpms/$cvsrepo/$cvsbasedir";
      my $componentdir="$distrodir/rpms/$cvsrepo/$cvsbasedir";
      -d $componentdir or die "Failed checkout to: $componentdir";
      # Required for RHEL; Fedora does so automatically.
      spawn "cd $componentdir/..; cvs -q -z3 -d $cvsroot co common";
      # Workaround (RHEL-5?) curl which uses `Pragma: nocache' on $http_proxy.
      subst sub { s{echo "curl }{$&-H 'Pragma: cache' }; },"$componentdir/../common/Makefile.common";
      copyfiles $componentdir;
      spawn "cd $componentdir; make verrel >$out/verrel";
      my $glob="$componentdir/*.src.rpm";
      @{[glob $glob]}==0 or die "Found some before test-srpm: $glob";
      # No `spawn' as we could get:
      # error: unpacking of archive failed on file X;4a56efef: cpio: MD5 sum mismatch
      mockrun "cd $componentdir; make test-srpm";
      my @srcrpm=(glob $glob);
      @srcrpm==1 or die "Did not find 1 srcrpm: @srcrpm";
      $srcrpm=$srcrpm[0];
    }

    if ($srcrpm) {
      my $srcrpmbasename=$srcrpm;
      $srcrpmbasename=~s{^.*/}{};
      spawn "cp -p $srcrpm $builddir/$srcrpmbasename";

      my $rpmbuildlocal=$rpmbuild.q{ --define "_topdir $PWD" --define "_builddir $PWD" --define "_rpmdir $PWD" --define "_sourcedir $PWD" --define "_specdir $PWD" --define "_srcrpmdir $PWD" --define "_build_name_fmt %%{NAME}-%%{VERSION}-%%{RELEASE}.%%{ARCH}.rpm"};
      $rpmbuildlocal="$orphanripper $rpmbuildlocal" if $cvsrepo && $cvsrepo eq "glibc";
      mockrun $rpmbuildlocal." --rebuild --with testsuite $srcrpmbasename";
    }

    my $baretestsuite;

    if ($component=~/^(gdb|binutils)cvs$/) {
      my $which=$1;
      my $cvsmaster=$which eq "gdb" ? $gdbcvsmaster : $binutilscvsmaster;
      if (-d $cvsmaster) {
	spawn "cp -a $cvsmaster $builddir/src; cd $builddir/src; cvs update $cvsbranch";
      } else {
	spawn "cd $builddir; cvs -q -z3 -d :pserver:anoncvs:\@sourceware.org:/cvs/src co $cvsbranch $which";
      }
      spawn "cd $builddir/src; test -z \"\$(cvs update $cvsbranch)\"";
      $baretestsuite="$builddir/src";
    }

    if ($component=~/^archer-/) {
      spawn "git clone ".(!-d $archermaster ? "" : "--reference $archermaster")." git://sourceware.org/git/archer.git $builddir/$component";
      spawn "cd $builddir/$component; git fetch";
      spawn "cd $builddir/$component; git checkout -b $component origin/$component; [ \"`git status`\" = \"# On branch $component\nnothing to commit (working directory clean)\" ]";
      $baretestsuite="$builddir/$component";
    }

    if ($component=~m{^/home/}) {
      spawn "cp -a $component $builddir/src; cd $builddir/src; find -name \"*.[oa]\" -o -name \"*.l[oa]\" -o -name gdb.sum -o -name gdb.log|xargs rm -f; make clean || :";
      $baretestsuite="$builddir/src";
    }

    if ($baretestsuite) {
      for my $file (@file) {
	my $target="$baretestsuite/$file";
	if ($file=~m{[.](R?)patch$}) {
	  my $R=$1;
	  my $fileabs=$file;
	  $fileabs=$ENV{"PWD"}."/$fileabs" if $fileabs!~m{^/};
	  spawn "cd $baretestsuite; patch -${R}p1 <$fileabs";
	} else {
	  -f $target or $file=~m{/testsuite/} or die "File $file does not exist at $target";
	  spawn "rm -f $target; cp -p $file $target";
	}
      }

      my $errs12="errs12";
      $errs12.=" -s" if $strip;
      $errs12.=" --target=$target" if $target;
      $errs12.=" $configure" if $configure;

      if ($component eq "binutilscvs") {
	mockrun "cd $baretestsuite; $errs12; ulimit -c unlimited; $orphanripper make -k check || :; ".q{for file in {gas/testsuite/gas,ld/ld,binutils/binutils}.{sum,log};do ln $file}." $out/binutils-$distro-".q{$(basename $file) || :; done;};
      } else {
	if ($valgrind) {
	  # FIXME
	  do { unlink $_ or warn "$_: $!"; } for "$baretestsuite/gdb/testsuite/gdb.base/break-interp.exp";
	}
	my @check=($distro=~/-x86_64/ ? qw(-m64 -m32) : -m32);
	@check=map("check//unix/$_",@check);
	@check=map({($_,"$_/-fPIE/-pie");} @check) if $gdbcvspie;
	# for i in ".join(" ",@check).";do $orphanripper make -k \$i || :;done
	sub runtestcc($)
	{
	  local($_)=@_;
	  s/ /\\ /g;
	  return ' RUNTESTFLAGS="CC_FOR_TARGET=gcc\ '.$_.' CXX_FOR_TARGET=g++\ '.$_.'"'
	}
	mockrun "cd $baretestsuite;"
		.(!$valgrind?"":' HAMMOCK_VALGRIND=1')
		." $errs12"
		.(!$valgrind?"":' --without-python')	# FIXME: Fix valgrind --suppressions
		."; cd gdb; ulimit -c unlimited; "
		.(!$gdbserver?"":'DEJAGNU=$HOME/src/runtest-gdbserver/site.exp ')
		.(!$valgrind?"":'DEJAGNU=$HOME/src/runtest-valgrind/site.exp ')
		."$orphanripper make -k ".join(" ",@check)
		# Ensure serial run if FORCE_PARALLEL=1 is not present
		." RUNTESTFLAGS=DUMMY=dummy"
		.(!$gdbserver?"":' RUNTESTFLAGS=--target_board=native-gdbserver')
		.(!$valgrind?"":' RUNTESTFLAGS=--target_board=valgrind')
		.(!$gdbindex?"":' RUNTESTFLAGS="CC_FOR_TARGET=/bin/sh\ $PWD/cc-with-index.sh\ gcc CXX_FOR_TARGET=/bin/sh\ $PWD/cc-with-index.sh\ g++"')
		.(!$dwarf?"":runtestcc "-gdwarf-$dwarf".(!defined $debug_types_section?"":'\ '.($debug_types_section?"-fdebug-types-section":"-fno-debug-types-section"))." -g0")
		.(!$parallel?"":' FORCE_PARALLEL=1')
		." || :; ".q{for t in sum log;do for file in testsuite*/gdb.$t;do suffix="${file#testsuite.unix.}"; suffix="${suffix%/gdb.$t}"; ln $file}." $out/gdb".q{$suffix.$t || :; done; done;};
      }
      # gdbunpack does:
      #		perl -i -pe 's{\Q'"$HOME"'\E/.*?/build/[^/]*/}{}g' "$base"/*
      my $HOME=$ENV{"HOME"};
      for my $file (glob("$out/*.sum"),glob("$out/*.log")) {
	subst sub { s{\Q$HOME\E/.*?/build/[^/]*/}{}g; },$file;
      }
    } else {
      die "internal error" if @target;
    }

    # Call gdbunpack only if no direct $out directory will be created.
    # It is needed only for .src.rpm-built testsuites, no matter how .src.rpm
    # got created.
    my @testinlog;
    if ($component=~/^(?:fedora|rhel)glibc$/) {
      @testinlog=(qr/={20}TESTING DETAILS={17}/,qr/={20}PLT RELOCS END={18}/);
    }
    if (@testinlog) {
      subst sub { s{^.*?\n($testinlog[0]\n.*\n$testinlog[1]\n).*$}{$1}s; },$log,$out;
    } elsif ($cvsbasedir || $srcrpm) {
      # Applies both to gdb and binutils.
      spawn "mv $out $out.x; gdbunpack $log; mv $out.x/* $out/; rmdir $out.x";
    }

    if ($valgrind) {
      for my $from (glob "$out/*.log") {
	(my $to=$from).="filt";
	spawn q{sed -n 's/^==[0-9]*== \([A-Z]\)/\1/p' <}.$from.q{|grep -v '^\(Conditional jump \|Invalid read \|Use of uninitialised value \|Syscall param .* uninitialised byte\)' >}.$to;
      }
    }

    my $resultout="$resultdir/$id/$distrodirbase";
    newdir $resultout;
    $resultout.="/out";
    newdir $resultout;
    for my $fname (glob "$out/*") {
      (my $base=$fname)=~s{^.*/}{};
      my $d="$resultout/$base";
      warn "+ link $fname $d\n";
      link $fname,$d or warn $!;
    }

    exit 0 if $parallel;
  }

  print STDERR "waiting for ".scalar(keys(%child))." children, ".scalar(@distrouse)." distros to go...\n";
  my $pid=wait();
  next if $pid==-1 && $!==10; # 10==No child processes
  die "wait()==-1: $!" if $pid==-1;
  die "not found pid $pid" if !$child{$pid};
  error "weird status $? for pid $pid: ".$child{$pid} if $?;
  print STDERR "finished: $pid ".$child{$pid}."\n";
  delete $child{$pid};
}
die if keys(%child);
die if @distrouse;

spawn "(set -e -o pipefail;cd $resultdir;tar cf - $id|xz -9e >$resultidxz;rm -rf $id)&","bare";

sub timestr($)
{
  my($sec)=@_;
  my $r="";

  if ($sec>=60*60) {
    $r.=int($sec/(60*60))."h";
    $sec%=60*60;
  }
  if ($r || $sec>=60) {
    $r.=int($sec/60)."m";
    $sec%=60;
  }
  $r.=$sec."s";

  return $r;
}

print STDERR "ID = $id | dir = $dir\n";
my $time=timestr(time()-$start);
print STDERR "total time=$time\n";
writefile "$dir/time","$time\n";
die "$error errors seen, aborted" if $error;
print STDERR "done\n";