Web.pm

   1 # $Id$
   2 # Common functions for HTML/XHTML output generation
   3 # Copyright (C) 2003-2005 Jan Kratochvil <project-www.jankratochvil.net@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 package My::Web;
  20 require 5.6.0;  # at least 'use warnings;' but we need some 5.6.0+ modules anyway
  21 our $VERSION=do { my @r=(q$Revision$=~/\d+/g); sprintf "%d.".("%03d"x$#r),@r; };
  22 our $CVS_ID=q$Id$;
  23 use strict;
  24 use warnings;
  25
  26 use Exporter;
  27 sub Wrequire($);
  28 sub Wuse($@);
  29 our $W;
  30 our @EXPORT=qw(
  31                 &Wrequire &Wuse
  32                 &path_web &path_abs_disk
  33                 &uri_escaped
  34                 &a_href &a_href_cz
  35                 &vskip
  36                 &img &centerimg &rightimg
  37                 $W
  38                 &input_hidden_persistents
  39                 );
  40 our @ISA=qw(Tie::Handle Exporter);
  41
  42 my %packages_used_hash;
  43 my %packages_used_array;
  44
  45 BEGIN
  46 {
  47         use Carp qw(cluck confess);
  48         $W->{"__My::Web_init"}=1;
  49
  50         sub Wrequire ($)
  51         {
  52         my($file)=@_;
  53
  54 #               print STDERR "Wrequire $file\n";
  55                 $file=~s#/#::#g;
  56                 $file=~s/[.]pm$//;
  57                 my $class=$file;
  58                 $file=~s#::#/#g;
  59                 $file.=".pm";
  60                 my %callers;
  61                 for (my $depth=0;defined caller($depth);$depth++) {
  62                         $callers{caller($depth)}=1;
  63                         }
  64                 my $selfpkg=__PACKAGE__;
  65                 $callers{$selfpkg}=1;
  66                 for my $target ($class,__PACKAGE__) {
  67                         for my $caller (keys(%callers)) {
  68                                 next if $caller eq $target;
  69                                 next if $packages_used_hash{$caller}{$target}++;
  70                                 push @{$packages_used_array{$caller}},$target;
  71                                 }
  72                         }
  73                 eval { CORE::require "$file"; } or confess $@;
  74                 1;      # Otherwise 'require' would already file above.
  75         }
  76
  77         sub Wuse ($@)
  78         {
  79         my($file,@list)=@_;
  80
  81 #               print STDERR "Wuse $file\n";
  82                 Wrequire $file;
  83                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  84                 $file->import(@list);
  85                 1;
  86         }
  87
  88         sub import
  89         {
  90         my($class,@rest)=@_;
  91
  92                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  93                 Wrequire("$class");
  94                 return $class->SUPER::import(@rest);
  95         }
  96 }
  97
  98 use WebConfig;  # see also below: Wuse 'WebConfig';
  99 require CGI;
 100 require Image::Size;    # for &imgsize
 101 use File::Basename;     # &basename
 102 use Carp qw(cluck confess);
 103 use URI::Escape;
 104 require HTTP::BrowserDetect;
 105 require HTTP::Negotiate;
 106 my $have_Geo_IP; BEGIN { $have_Geo_IP=eval { require Geo::IP; 1; }; }
 107 # Do not: use ModPerl::Util qw(exit);
 108 # to prevent in mod_perl2: "exit" is not exported by the ModPerl::Util module
 109 # I do not know why.
 110 use POSIX qw(strftime);
 111 use Tie::Handle;
 112 use Apache2::Const qw(HTTP_MOVED_TEMPORARILY OK);
 113 use URI;
 114 use URI::QueryParam;
 115 use Cwd;
 116
 117
 118 #our $W;
 119                 # $W->{"title"}
 120                 # $W->{"head"}
 121                 # $W->{"force_charset"}
 122                 # $W->{"heading_done"}
 123                 # $W->{"footer_passed"}
 124                 # %{$W->{"headers"}}
 125                 # %{$W->{"headers_lc"}} # maps lc($headers_key)=>$headers_key
 126                 # %{$W->{"args"}}
 127
 128 sub cleanup($)
 129 {
 130 my($apache_request)=@_;
 131
 132         # Sanity protection.
 133         $W=undef();
 134         return OK;
 135 }
 136
 137 sub init ($%)
 138 {
 139 my($class,%args)=@_;
 140
 141         print STDERR "$class->init ".Apache2::RequestUtil->request()->unparsed_uri()."\n";
 142
 143         # We need to track package dependencies, so we need to call it from &init.
 144         # We cannot do it in BEGIN { } block
 145         # as it would not be tracked for each of the toplevel users later.
 146         Wuse 'WebConfig';
 147         Wrequire 'My::Hash::Sub';
 148
 149         $W={};
 150         tie %$W,"My::Hash::Sub";
 151         %$W=(%WebConfig,%args); # override %WebConfig settings
 152         $W->{"__PACKAGE__"}||=caller();
 153
 154         # {"__PACKAGE__"} is mandatory for mod_perl-2.0;
 155         # $Apache2::Registry::curstash is no longer supported.
 156         do { cluck "No $_" if !$W->{$_}; } for "__PACKAGE__";
 157
 158         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_ent");
 159         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_js");
 160         do { $W->{$_}=1  if !defined $W->{$_}; } for ("have_css");      # AFAIK it does not hurt anyone.
 161         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer");
 162         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_delimit");
 163         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_ids");
 164         do { $W->{$_}=1  if !defined $W->{$_}; } for ("indexme");
 165         do { $W->{$_}="" if !defined $W->{$_}; } for ("head");
 166         do { $W->{$_}="" if !defined $W->{$_}; } for ("body_attr");
 167         do { $W->{$_}="en-US" if !defined $W->{$_}; } for ("language");
 168
 169         my $footer_any=0;
 170         for (qw(footer_ids)) {
 171                 $W->{$_}=0 if !$W->{"footer"};
 172                 $footer_any=1 if $W->{$_};
 173                 }
 174         $W->{"footer"}=0 if !$footer_any;
 175         $W->{"footer_delimit"}=0 if !$W->{"footer"};
 176
 177         $W->{"r"}=Apache2::RequestUtil->request();
 178
 179         $W->{"r"}->push_handlers("PerlCleanupHandler"=>\&cleanup);
 180
 181         $W->{"web_hostname"}||=$W->{"r"}->hostname();
 182
 183         tie *STDOUT,$W->{"r"};
 184         select *STDOUT;
 185         $|=1;
 186
 187         $W->{"QUERY_STRING"}=$W->{"r"}->args() || "";
 188         if ($W->{"detect_ent"}) {
 189                          if ($W->{"QUERY_STRING"}=~/[&]amp;have_ent/)
 190                         { $W->{"have_ent"}=0; }
 191                 elsif ($W->{"QUERY_STRING"}=~    /[&]have_ent/)
 192                         { $W->{"have_ent"}=1; }
 193                 else
 194                         { delete $W->{"have_ent"}; }
 195                 if (!defined $W->{"have_ent"} && $W->{"r"}->method() eq "GET") {
 196                         $W->{"head"}.='<meta http-equiv="Refresh" content="0; URL='
 197                                         .escapeHTML("http://".$W->{"web_hostname"}."/".($W->{"r"}->uri()=~m#^/*(.*)$#)[0]
 198                                                         ."?".($W->{"QUERY_STRING"} || "detect_ent_glue=1").'&have_ent=detect')
 199                                         .'" />'."\n";
 200                         }
 201                 }
 202         $W->{"QUERY_STRING"}=~s/([&])amp;/$1/g;
 203         $W->{"r"}->args($W->{"QUERY_STRING"});
 204         # Workaround: &CGI::Vars behaves weird if strings passed both as POST data and in: $QUERY_STRING
 205         do { $W->{"r"}->args(""); delete $ENV{"QUERY_STRING"}; } if $W->{"r"}->method() eq "POST";
 206         # Do not: $W->{"r"}->args()
 207         # as it parses only QUERY_STRING (not POST data).
 208         $W->{"args"}={ CGI->new($W->{"r"})->Vars() };
 209         for my $name (keys(%{$W->{"args"}})) {
 210                 my @vals=split /\x00/,$W->{"args"}{$name};
 211                 next if @vals<=1;
 212                 $W->{"args"}{$name}=[@vals];
 213                 }
 214
 215         do { $W->{$_}=$W->{"r"}->headers_in()->{"Accept"}         if !defined $W->{$_}; } for ("accept");
 216         do { $W->{$_}=$W->{"r"}->headers_in()->{"User-Agent"}||"" if !defined $W->{$_}; } for ("user_agent");
 217
 218         $W->{"browser"}=HTTP::BrowserDetect->new($W->{"user_agent"});
 219
 220         if (!defined $W->{"have_style"}) {
 221                 $W->{"have_style"}=(!$W->{"browser"}->netscape() || ($W->{"browser"}->major() && $W->{"browser"}->major()>4) ? 1 : 0);
 222                 }
 223
 224         $W->{"have_js"}=($W->{"args"}{"have_js"} ? 1 : 0);
 225         if ($W->{"detect_js"} && !$W->{"have_js"}) {
 226                 $W->{"head"}.='<script type="text/javascript" src="'.path_web('/have_js.pm').'"></script>'."\n";
 227                 }
 228
 229         do { args_check(%$_) if $_; } for ($W->{"args_check"});
 230
 231         return bless $W,$class;
 232 }
 233
 234 # Although we have &tie-d *STDOUT we try to not to be dependent on it in My::Web itself.
 235 # Do not: Wprint $W->{"heading"},"undef"=>1;
 236 # as we would need to undef() it to turn it off and it would get defaulted in such case.
 237 # Do not: exists $W->{"heading"}
 238 # as we use a lot of 'for $W->{"heading"}' which instantiates it with the value: undef()
 239 sub Wprint($%)
 240 {
 241 my($text,%args)=@_;
 242
 243         cluck "undef Wprint" if !defined $text && !$args{"undef"};
 244         delete $args{"undef"};
 245         cluck join(" ","Invalid arguments:",keys(%args)) if keys(%args);
 246         $W->{"r"}->puts($text) if defined $text;
 247 }
 248
 249 sub escapeHTML($)
 250 {
 251 my($text)=@_;
 252
 253         # Use &eval to prevent: Global $r object is not available. Set:\n\tPerlOptions +GlobalRequest\nin ...
 254         # CGI requires valid "r": check it beforehand here.
 255         confess "Calling dynamic URL generator from a static code" if !eval { Apache2::RequestUtil->request(); };
 256         # Prevent &CGI::escapeHTML breaking utf-8 strings like: \xC4\x9B eq \x{11B}
 257         do { cluck "charset==$_" if $_ && $_ ne "utf-8"; } for CGI::charset();
 258         CGI::charset("utf-8");
 259         return CGI::escapeHTML($text);
 260 }
 261
 262 # local *FH;
 263 # tie *FH,ref($W),$W;
 264 sub TIEHANDLE($)
 265 {
 266 my($class,$W)=@_;
 267
 268         my $self={};
 269         $self->{"W"}=$W or confess "Missing W";
 270         return bless $self,$class;
 271 }
 272
 273 sub WRITE
 274 {
 275 my($self,$scalar,$length,$offset)=@_;
 276
 277         Wprint substr($scalar,0,$length);
 278 }
 279
 280 # /home/user/www/webdir
 281 sub dir_top_abs_disk()
 282 {
 283         our $dir_top_abs_disk;
 284         if (!$dir_top_abs_disk) {
 285                 my $selfpkg_relpath=__PACKAGE__;
 286                 $selfpkg_relpath=~s{::}{/}g;
 287                 $selfpkg_relpath.=".pm";
 288                 my $selfpkg_abspath=$INC{$selfpkg_relpath} or do {
 289                         cluck "Unable to find self package $selfpkg_relpath";
 290                         return;
 291                         };
 292                 $selfpkg_abspath=~s{/*\Q$selfpkg_relpath\E$}{} or do {
 293                         cluck "Unable to strip myself \"$selfpkg_relpath\" from the abspath: $selfpkg_abspath";
 294                         return;
 295                         };
 296                 cluck "INC{myself} is relative?: $selfpkg_abspath" if $selfpkg_abspath!~m{^/};
 297                 $dir_top_abs_disk=$selfpkg_abspath;
 298                 }
 299         return $dir_top_abs_disk;
 300 }
 301
 302 sub unparsed_uri()
 303 {
 304         if (!$W->{"unparsed_uri"}) {
 305                 # Do not: $W->{"r"}
 306                 # as we may be called before &init from: &My::Project::init
 307                 my $r=Apache2::RequestUtil->request();
 308                 cluck "Calling ".'&unparsed_uri'." from a static code, going to fail" if !$r;
 309                 my $uri_string=$r->unparsed_uri() or cluck "Valid 'r' missing unparsed_uri()?";
 310                 my $uri=URI->new_abs($uri_string,"http://".$W->{"web_hostname"}."/");
 311                 $W->{"unparsed_uri"}=$uri;
 312                 }
 313         return $W->{"unparsed_uri"};
 314 }
 315
 316 sub in_to_uri_abs($)
 317 {
 318 my($in)=@_;
 319
 320         # Otherwise we may have been already processed and thus legally relativized.
 321         # FIXME data: Currently disabled, all the data are too violating such rule.
 322         if (0 && !ref $in) {
 323                 my $uri_check=URI->new($in);
 324                 $uri_check->scheme() || $in=~m{^\Q./\E} || $in=~m{^/}
 325                                 or cluck "Use './' or '/' prefix for all the local references: $in";
 326                 }
 327         my $uri=URI->new_abs($in,unparsed_uri());
 328         $uri=$uri->canonical();
 329         return $uri;
 330 }
 331
 332 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 333 # $args{"abs"}=1;
 334 sub path_web($%)
 335 {
 336 my($in,%args)=@_;
 337
 338         cluck if !$args{"uri_as_in"} && ref $in;
 339         my $uri=in_to_uri_abs($in);
 340         if (uri_is_local($uri)) {
 341                 # Prefer the $uri values over "args_persistent" values.
 342                 $uri->query_form_hash({
 343                                 map({
 344                                         my $key=$_;
 345                                         my $val=$W->{"args"}{$key};
 346                                         (!defined $val ? () : ($key=>$val));
 347                                         } keys(%{$W->{"args_persistent"}})),
 348                                 %{$uri->query_form_hash()},
 349                                 });
 350                 }
 351         return $uri->abs(unparsed_uri()) if $W->{"args"}{"Wabs"} || $args{"abs"};
 352         return $uri->rel(unparsed_uri());
 353 }
 354
 355 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 356 sub path_abs_disk($%)
 357 {
 358 my($in,%args)=@_;
 359
 360         cluck if !$args{"uri_as_in"} && ref $in;
 361         my $uri=in_to_uri_abs($in);
 362         cluck if !uri_is_local($uri);
 363         my $path=$uri->path();
 364         cluck "URI compatibility: ->path() not w/leading slash of URI \"$uri\"; path: $path" if $path!~m{^/};
 365         return dir_top_abs_disk().$path;
 366 }
 367
 368 sub fatal (;$);
 369
 370 sub args_check (%)
 371 {
 372 my(%tmpl)=@_;
 373
 374         while (my($name,$regex)=each(%tmpl)) {
 375                 my $name_html="Parameter <span class=\"quote\">".escapeHTML($name)."</span>";
 376                 $W->{"args"}{$name}="" if !defined $W->{"args"}{$name};
 377                 $W->{"args"}{$name}=[ $W->{"args"}{$name} ] if !ref $W->{"args"}{$name} && ref $regex;
 378                 fatal "$name_html passed as multivar although singlevar expected"
 379                                 if ref $W->{"args"}{$name} && !ref $regex;
 380                 $regex=$regex->[0] if ref $regex;
 381                 for my $val (!ref $W->{"args"}{$name} ? $W->{"args"}{$name} : @{$W->{"args"}{$name}}) {
 382                         $val="" if !defined $val;
 383                         fatal "$name_html <span class=\"quote\">".escapeHTML($val)."</span>"
 384                                                         ." does not match the required regex <span class=\"quote\">".escapeHTML($regex)."</span> "
 385                                         if $regex ne "" && $val!~/$regex/;
 386                         }
 387                 }
 388 }
 389
 390 sub vskip (;$)
 391 {
 392 my($height)=@_;
 393
 394         return '<p'.(!defined $height ? "" : ' style="height: '.$height.';"').'>&nbsp;</p>'."\n";
 395 }
 396
 397 sub fatal (;$)
 398 {
 399 my($msg)=@_;
 400
 401         $msg="UNKNOWN" if !$msg;
 402         cluck "FATAL: $msg";
 403
 404         # Do not send it unconditionally.
 405         # The intial duplicated '<?xml...' crashes Gecko parser.
 406         $W->{"heading_done"}=0 if $W->{"header_only"};
 407         # Do not send it unconditionally.
 408         # Prevents warn: Headers already sent
 409         if (!$W->{"heading_done"}) {
 410                 $W->{"indexme"}=0;      # For the case no heading was sent yet.
 411                 $W->{"header_only"}=0;  # assurance for &heading
 412                 My::Web->heading();
 413                 }
 414         Wprint "\n".vskip("3ex")."<hr /><h1 class=\"error\">FATAL ERROR: $msg!</h1>\n"
 415                         ."<p>You can report this problem's details to"
 416                         ." ".a_href("mailto:".$W->{"admin_mail"},"admin of this website").".</p>\n";
 417         footer();
 418 }
 419
 420 sub footer (;$)
 421 {
 422         exit 1 if $W->{"footer_passed"}++;      # deadlock prevention:
 423
 424         Wprint vskip if $W->{"footer_delimit"};
 425
 426         do { Wprint $_ if $_; } for $W->{"footing_delimit"};
 427
 428         Wprint "<hr />\n" if $W->{"footer"};
 429
 430         my $packages_used=$packages_used_array{$W->{"__PACKAGE__"}};
 431
 432         if ($W->{"footer_ids"}) {
 433                 Wprint '<p class="cvs-id">';
 434                 Wprint join("<br />\n",map({ my $package=$_;
 435                         my $cvs_id=(eval('$'.$package."::CVS_ID")
 436 #                                       || $package     # debug
 437                                         );
 438                         if (!$cvs_id) {
 439                                 ();
 440                                 }
 441                         else {
 442                                 $cvs_id='$'.$cvs_id.'$';        # Eaten by 'q' operator.
 443                                 my @cvs_id_split=split / +/,$cvs_id;
 444                                 if (@cvs_id_split==8) {
 445                                         my $file=$package;
 446                                         $file=~s#::#/#g;
 447                                         my $ext;
 448                                         my @tried;
 449                                         for (qw(.pm)) {
 450                                                 $ext=$_;
 451                                                 my $path_abs_disk=path_abs_disk("/$file$ext");
 452                                                 push @tried,$path_abs_disk;
 453                                                 last if -r $path_abs_disk;
 454                                                 cluck "Class file $file not found; tried: ".join(" ",@tried) if !$ext;
 455                                                 }
 456                                         $file.=$ext;
 457                                         $cvs_id_split[2]=""
 458                                                         .a_href((map({ my $s=$_; $s=~s#/viewcvs/#$&~checkout~/#; $s; } $W->{"viewcvs"}))[0]."$file?rev=".$cvs_id_split[2],
 459                                                                         $cvs_id_split[2]);
 460                                         $cvs_id_split[1]=a_href($W->{"viewcvs"}.$file,
 461                                                         ($package!~/^Apache2::/ ? $package : $cvs_id_split[1]));
 462                                         $cvs_id_split[5]=&{$W->{"cvs_id_author_sub"}}($cvs_id_split[5]);
 463                                         }
 464                                 join " ",@cvs_id_split;
 465                                 }
 466                         } @$packages_used));
 467                 Wprint "</p>\n";
 468                 }
 469
 470         for my $package (@$packages_used) {
 471                 my $cvs_id=(eval('$'.$package."::CVS_ID")
 472 #                               || $package     # debug
 473                                 );
 474                 Wprint '<!-- '.$package.' - $'.$cvs_id.'$ -->'."\n" if $cvs_id;
 475                 }
 476
 477         do { Wprint $_ if $_; } for $W->{"footing"};
 478
 479         Wprint "</body></html>\n";
 480         exit 0;
 481 }
 482
 483 sub header (%)
 484 {
 485 my(%pairs)=@_;
 486
 487         while (my($key,$val)=each(%pairs)) {
 488                 do { cluck "Headers already sent"; next; } if $W->{"heading_done"};
 489                 for ($W->{"headers_lc"}{lc $key} || ()) {
 490                         delete $W->{"headers"}{$_};
 491                         }
 492                 $W->{"headers_lc"}{lc $key}=$key;
 493                 $W->{"headers"}{$key}=$val;
 494                 }
 495 }
 496
 497 sub size_display ($)
 498 {
 499 my($size)=@_;
 500
 501            if ($size<4096)
 502                 {}
 503         elsif ($size<1024*1024)
 504                 { $size=sprintf "%.1fK",$size/1024; }
 505         else
 506                 { $size=sprintf "%.1fM",$size/1024/1024; }
 507         $size.="B";
 508         return $size;
 509 }
 510
 511 sub uri_is_local($)
 512 {
 513 my($in)=@_;
 514
 515         my $uri_rel=in_to_uri_abs($in)->rel(unparsed_uri());
 516         # Do not: defined $uri_rel->("userinfo"|"host"|"port")();
 517         # as they fail to be called for schemes not supporting them.
 518         return 0 if $uri_rel->scheme();
 519         return 0 if $uri_rel->authority();
 520         return 1;
 521 }
 522
 523 # &path_web still may be required for &uri_escaped !
 524 sub uri_escaped($)
 525 {
 526 my($uri)=@_;
 527
 528         cluck if !ref $uri;
 529         my $urient=escapeHTML($uri);
 530         return $uri    if $uri eq $urient;
 531         return $urient if uri_is_local $uri;
 532         return $uri    if defined $W->{"have_ent"} && !$W->{"have_ent"};        # non-ent client
 533         return $urient if $W->{"have_ent"};     # ent client
 534         # Unknown client, &escapeHTML should not be needed here:
 535         return escapeHTML(path_web('/Redirect.pm?location='.uri_escape($uri->abs(unparsed_uri()))));
 536 }
 537
 538 our $a_href_inhibited;
 539 sub a_href($;$%)
 540 {
 541 my($in,$contents,%args)=@_;
 542
 543         do { $$_=1 if !defined $$_; } for (\$args{"size"});
 544         if (!defined $contents) {
 545                 $contents=$in;
 546                 $contents=File::Basename::basename($contents) if $args{"basename"};
 547                 $contents=escapeHTML($contents);
 548                 }
 549         $contents=~s#<a\b[^>]*>##gi;
 550         $contents=~s#</a>##gi;
 551         return $contents if $a_href_inhibited;
 552
 553         my $path_web=path_web $in,%args;
 554         my $r="";
 555         $r.='<a href="';
 556         $r.=uri_escaped $path_web;
 557         $r.='"';
 558         do { $r.=" $_" if $_; } for ($args{"attr"});
 559         $r.='>'.$contents.'</a>';
 560         if ($args{"size"} && uri_is_local($in) && ($args{"size"}>=2 || $in=~/[.](?:gz|Z|rpm|zip|deb|lha)/)) {   # Downloadable?
 561                 my $path_abs_disk=path_abs_disk $in,%args;
 562                 cluck "File not readable: $path_abs_disk" if !-r $path_abs_disk;
 563                 $r.='&nbsp;('.size_display((stat($path_abs_disk))[7]).')';
 564                 }
 565         return $r;
 566 }
 567
 568 sub a_href_inhibit($$;@)
 569 {
 570 my($self,$sub,@sub_args)=@_;
 571
 572         local $a_href_inhibited=1;
 573         return &{$sub}(@sub_args);
 574 }
 575
 576 sub input_hidden_persistents()
 577 {
 578         return join("",map({
 579                 my $key=$_;
 580                 my $val=$W->{"args"}{$key};
 581                 (!defined $val ? () : '<input type="hidden"'
 582                                 .' name="'.escapeHTML($key).'"'
 583                                 .' value="'.escapeHTML($val).'"'
 584                                 .' />'."\n");
 585                 } (keys(%{$W->{"args_persistent"}}))));
 586 }
 587
 588 sub http_moved($$;$)
 589 {
 590 my($self,$url,$status)=@_;
 591
 592         $url=path_web($url,"abs"=>1);
 593         $status||=HTTP_MOVED_TEMPORARILY;
 594         $W->{"r"}->status($status);
 595         $W->{"r"}->headers_out()->{"Location"}=$url;
 596         $W->{"header_only"}=1;
 597         My::Web->heading();
 598         exit;
 599         die "NOTREACHED";
 600 }
 601
 602 sub remote_ip ()
 603 {
 604         # Do not: PerlModule                 Apache2::ForwardedFor
 605         #         PerlPostReadRequestHandler Apache2::ForwardedFor
 606         # As 'Apache2::ForwardedFor' takes the first of $ENV{"HTTP_X_FORWARDED_FOR"}
 607         # while the contents is '127.0.0.1, 213.220.195.171' if client has its own proxy.
 608         # We must take the last item ourselves.
 609         my $r=$W->{"r"}->headers_in()->{"X-Forwarded-For"} || $W->{"r"}->get_remote_host();
 610         $r=~s/^.*,\s*//;
 611         return $r;
 612 }
 613
 614 sub is_cz ()
 615 {
 616         return 0 if !$have_Geo_IP;
 617         return "CZ" eq Geo::IP->new()->country_code_by_addr(remote_ip());
 618 }
 619
 620 sub a_href_cz ($$;%)
 621 {
 622 my($url,$contents,%args)=@_;
 623
 624         return a_href $url,$contents,%args if is_cz();
 625         return $contents;
 626 }
 627
 628 sub make ($)
 629 {
 630 my($cmd)=@_;
 631
 632         # FIXME: &alarm, --timeout is now infinite.
 633         # FIXME: Try to remove bash(1).
 634         # FIXME: Use: @PATH_FLOCK@
 635         my @argv=('flock',dir_top_abs_disk(),'bash','-c',$cmd.' >&2');
 636         print STDERR join(" ","SPAWN:",@argv)."\n";
 637         system @argv;
 638 }
 639
 640 sub make_file($$)
 641 {
 642 my($self,$file)=@_;
 643
 644         cluck "Pathname not absolute: $file" if $file!~m{^/};
 645         return if -f $file;
 646         # TODO: Somehow quickly check dependencies?
 647         return make('make -s --no-print-directory'
 648                                         .' -C '."'".File::Basename::dirname($file)."' '".File::Basename::basename($file)."'");
 649 }
 650
 651 sub img_size ($$)
 652 {
 653 my($width,$height)=@_;
 654
 655         cluck if !defined $width || !defined $height;
 656         return ($W->{"have_style"} ? "style=\"border:0;width:${width}px;height:${height}px\"" : "border=\"0\"")
 657                         ." width=\"$width\" height=\"$height\"";
 658 }
 659
 660 sub negotiate_variant (%)
 661 {
 662 my(%args)=@_;
 663
 664         my @fields=("id","qs","content-type","encoding","charset","lang","size");
 665         return [ map(($args{$_}),@fields) ];
 666 }
 667
 668 # Input: $self is required!
 669 # Input: Put the fallback variant as the first one.
 670 # Returns: always only scalar!
 671 sub Negotiate_choose($$)
 672 {
 673 my($self,$variants)=@_;
 674
 675         my $best=HTTP::Negotiate::choose($variants,
 676                         # Do not: $W->{"r"}
 677                         # to prevent: Can't locate object method "scan" via package "Apache2::RequestRec" at HTTP/Negotiate.pm line 84.
 678                         # Do not: $W->{"r"}->headers_in()
 679                         # to prevent: Can't locate object method "scan" via package "APR::Table" at HTTP/Negotiate.pm line 84.
 680                         # Do not: HTTP::Headers->new($W->{"r"}->headers_in());
 681                         # to prevent empty result or even: Odd number of elements in anonymous hash
 682                         HTTP::Headers->new(%{$W->{"r"}->headers_in()}));
 683         $best||=$variants->[0][0];      # $variants->[0]{"id"}; &HTTP::Negotiate::choose failed?
 684         return $best;
 685 }
 686
 687 my @img_variants=(
 688                 { "id"=>"png","qs"=>0.9,"content-type"=>"image/png" },
 689                 { "id"=>"gif","qs"=>0.7,"content-type"=>"image/gif" },
 690                 );
 691 my $img_variants_re='[.](?:'.join('|',"jpeg",map(($_->{"id"}),@img_variants)).')$';
 692
 693 # Returns: ($path_web,$path_abs_disk)
 694 # URI path segments support ignored here. Where it is used? (';' path segment options)
 695 sub _img_src($%)
 696 {
 697 my($in,%args)=@_;
 698
 699         cluck if !uri_is_local $in;
 700         my $uri=in_to_uri_abs $in;
 701         my $path_abs_disk=path_abs_disk $uri,%args,"uri_as_in"=>1;
 702
 703         # Known image extension?
 704         return path_web($uri,%args,"uri_as_in"=>1),$path_abs_disk if $uri->path()=~m#$img_variants_re#o;
 705
 706         my @nego_variants;
 707         for my $var (@img_variants) {
 708                 my $path_abs_disk_variant=$path_abs_disk.".".$var->{"id"};
 709                 __PACKAGE__->make_file($path_abs_disk_variant);
 710                 push @nego_variants,negotiate_variant(
 711                                 %$var,
 712                                 "size"=>(stat $path_abs_disk_variant)[7],
 713                                 );
 714                 }
 715         my $ext=__PACKAGE__->Negotiate_choose(\@nego_variants);
 716
 717         $uri->path($uri->path().".$ext");
 718         return path_web($uri,%args,"uri_as_in"=>1),path_abs_disk($uri,%args,"uri_as_in"=>1);
 719 }
 720
 721 # $args{"attr"}
 722 sub img ($$%)
 723 {
 724 my($in,$alt,%args)=@_;
 725
 726         my($path_web,$path_abs_disk)=_img_src($in,%args);
 727         my($width,$height)=Image::Size::imgsize($path_abs_disk);
 728         $alt=~s/<[^>]*>//g;
 729         $alt=escapeHTML($alt);
 730         my $content="<img src=\"".uri_escaped($path_web)."\" alt=\"$alt\" title=\"$alt\" ".img_size($width,$height)
 731                         .(!$args{"attr"} ? "" : " ".$args{"attr"})." />";
 732         do { return a_href((_img_src($_))[0],$content,"uri_as_in"=>1) if $_; } for $args{"a_href_img"};
 733         do { return a_href $_,$content if $_; } for $args{"a_href"};
 734         return $content;
 735 }
 736
 737 sub centerimg
 738 {
 739         my $r="";
 740         $r.='<table border="0" width="100%"><tr>'."\n";
 741         @_=( [@_] ) if !ref $_[0];
 742         for (@_) {
 743                 $r.="\t".'<td align="center">'.&{\&img}(@$_).'</td>'."\n";
 744                 }
 745         $r.='</tr></table>'."\n";
 746         return $r;
 747 }
 748
 749 sub rightimg
 750 {
 751 my($text,@args_img)=@_;
 752
 753         # FIXME: Workaround bug of 'Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)':
 754         #        <col width="@{[ (!$W->{"browser"}->ie() ? "1*" : "90%" ) ]}" />
 755         #        <col width="@{[ (!$W->{"browser"}->ie() ? "0*" : "10%" ) ]}" />
 756         # causes whole invisible projects in: Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.7.10) Gecko/20050719 Galeon/1.3.21
 757         return <<"HERE";
 758 <table border="0" width="100%">
 759         <tr>
 760                 <td align="left">
 761                         @{[ $text ]}
 762                 </td>
 763                 <td align="right">
 764                         @{[ &{\&img}(@args_img) ]}
 765                 </td>
 766         </tr>
 767 </table>
 768 HERE
 769 }
 770
 771 sub readfile($$)
 772 {
 773 my($class,$filename)=@_;
 774
 775         local *F;
 776         open F,$filename or cluck "Cannot open \"$filename\": $!";
 777         my $F=do { local $/=undef(); <F>; };
 778         close F or cluck "Cannot close \"$filename\": $!";
 779         return $F;
 780 }
 781
 782 sub no_cache($)
 783 {
 784 my($self)=@_;
 785
 786         header("Expires"=>"Mon, 26 Jul 1997 05:00:00 GMT");     # date in the past
 787         header("Last-Modified"=>strftime("%a, %d %b %Y %H:%M:%S GMT",gmtime()));        # always modified
 788         header("Cache-Control"=>"no-cache, must-revalidate");   # HTTP/1.1
 789         header("Pragma"=>"no-cache");   # HTTP/1.0
 790 }
 791
 792 sub heading()
 793 {
 794 my($class)=@_;
 795
 796         # $ENV{"CLIENT_CHARSET"} ignored (mod_czech support dropped!)
 797         my $client_charset=$W->{"force_charset"} || "us-ascii";
 798         header("Content-Style-Type"=>"text/css");
 799         header("Content-Script-Type"=>"text/javascript");
 800         do { header("Content-Language"=>$_) if $_; } for $W->{"language"};
 801         $class->no_cache() if $W->{"no_cache"};
 802
 803         while (my($key,$val)=each(%{$W->{"headers"}})) {
 804                 $W->{"r"}->headers_out()->{$key}=$val;
 805                 }
 806         exit if $W->{"r"}->header_only();
 807         return if $W->{"header_only"};
 808         # We still can append headers before we put out some text.
 809         # FIXME: It is not clean to still append them without overwriting.
 810         return if $W->{"heading_done"}++;
 811
 812         # Workaround bug
 813         #   https://bugzilla.mozilla.org/show_bug.cgi?id=120556
 814         # of at least
 815         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
 816         my $mime;
 817         # http://validator.w3.org/ does not send ANY "Accept" headers!
 818         $mime||="application/xhtml+xml" if !$W->{"accept"} && $W->{"user_agent"}=~m{^W3C_Validator/}i;
 819         $mime||=$class->Negotiate_choose([
 820                         # Put the fallback variant as the first one.
 821                         # Rate both variants the same to prefer "text/html" for undecided clients.
 822                         # At least
 823                         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
 824                         # prefers "application/xhtml+xml" over "text/html" itself:
 825                         #   text/xml,application/xml,application/xhtml+xml,text/html;q=0.9,text/plain;q=0.8,image/png,*/*;q=0.5
 826                         negotiate_variant(
 827                                         "id"=>"text/html",
 828                                         "content-type"=>"text/html",
 829                                         "qs"=>0.6,
 830                                         "charset"=>$client_charset,
 831                                         "lang"=>$W->{"language"},
 832                                         ),
 833                         negotiate_variant(
 834                                         "id"=>"application/xhtml+xml",
 835                                         "content-type"=>"application/xhtml+xml",
 836                                         "qs"=>0.6,
 837                                         "charset"=>$client_charset,
 838                                         "lang"=>$W->{"language"},
 839                                         ),
 840                         # application/xml ?
 841                         # text/xml ?
 842                         ]);
 843         $W->{"r"}->content_type("$mime; charset=$client_charset");
 844         Wprint '<?xml version="1.0" encoding="'.$client_charset.'"?>'."\n" if $mime=~m{^application/\w+[+]xml$};
 845         return if $W->{"xml_header_only"};
 846         Wprint '<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN" "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">'."\n";
 847         Wprint '<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="'.$W->{"language"}.'">'."\n";
 848         my $title=$W->{"title_prefix"}.join("",map({ ': '.$_; } ($W->{"title"} || ())));
 849         # Do not: cluck if $title=~/[<>]/;
 850         # as it is not solved just by: &a_href_inhibit
 851         # as sometimes titles use also: <i>...</i>
 852         $title=~s#<[^>]*>##g;
 853         Wprint "<head>";
 854         Wprint "<title>$title</title>\n";
 855         if ($W->{"have_css"}) {
 856                 # Everything can get overriden later.
 857                 for my $css ("/My/Web.css",map((!$_ ? () : ("ARRAY" ne ref($_) ? $_ : @$_)),$W->{"css_push"})) {
 858                         Wprint <<"HERE";
 859 <link rel="stylesheet" type="text/css" href="@{[ uri_escaped(path_web $css) ]}" />
 860 HERE
 861                         }
 862                 }
 863         Wprint '<meta name="robots" content="'.($W->{"indexme"} ? "" : "no" ).'index,follow" />'."\n";
 864         Wprint $W->{"head"};
 865         for my $type (qw(prev next index contents start up)) {
 866                 do { Wprint '<link rel="'.$type.'" href="'.uri_escaped(path_web $_).'" />'."\n" if $_; }
 867                                 for ($W->{"rel_$type"});
 868                 }
 869         Wprint "</head><body";
 870 #       Wprint ' bgcolor="black" text="white" link="aqua" vlink="teal"'
 871 #                       if $W->{"browser"}->netscape() && (!$W->{"browser"}->major() || $W->{"browser"}->major()<=4);
 872         Wprint $W->{"body_attr"};
 873         Wprint ">\n";
 874
 875         do { Wprint $_ if $_; } for $W->{"heading"};
 876 }
 877
 878 BEGIN {
 879         delete $W->{"__My::Web_init"};
 880         }
 881
 882 1;