Web.pm

   1 # $Id$
   2 # Common functions for HTML/XHTML output generation
   3 # Copyright (C) 2003-2005 Jan Kratochvil <project-www.jankratochvil.net@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 package My::Web;
  20 require 5.6.0;  # at least 'use warnings;' but we need some 5.6.0+ modules anyway
  21 our $VERSION=do { my @r=(q$Revision$=~/\d+/g); sprintf "%d.".("%03d"x$#r),@r; };
  22 our $CVS_ID=q$Id$;
  23 use strict;
  24 use warnings;
  25
  26 use Exporter;
  27 sub Wrequire($);
  28 sub Wuse($@);
  29 our $W;
  30 our @EXPORT=qw(
  31                 &Wrequire &Wuse
  32                 &path_web &path_abs_disk
  33                 &uri_escaped
  34                 &a_href &a_href_cz
  35                 &vskip
  36                 &img &centerimg &rightimg
  37                 $W
  38                 &input_hidden_persistents
  39                 );
  40 our @ISA=qw(Tie::Handle Exporter);
  41
  42 my %packages_used_hash;
  43 my %packages_used_array;
  44
  45 BEGIN
  46 {
  47         use Carp qw(cluck confess);
  48         $W->{"__My::Web_init"}=1;
  49
  50         sub Wrequire ($)
  51         {
  52         my($file)=@_;
  53
  54 #               print STDERR "Wrequire $file\n";
  55                 $file=~s#/#::#g;
  56                 $file=~s/[.]pm$//;
  57                 my $class=$file;
  58                 $file=~s#::#/#g;
  59                 $file.=".pm";
  60                 my %callers;
  61                 for (my $depth=0;defined caller($depth);$depth++) {
  62                         $callers{caller($depth)}=1;
  63                         }
  64                 my $selfpkg=__PACKAGE__;
  65                 $callers{$selfpkg}=1;
  66                 for my $target ($class,__PACKAGE__) {
  67                         for my $caller (keys(%callers)) {
  68                                 next if $caller eq $target;
  69                                 next if $packages_used_hash{$caller}{$target}++;
  70                                 push @{$packages_used_array{$caller}},$target;
  71                                 }
  72                         }
  73                 eval { CORE::require "$file"; } or confess $@;
  74                 1;      # Otherwise 'require' would already file above.
  75         }
  76
  77         sub Wuse ($@)
  78         {
  79         my($file,@list)=@_;
  80
  81 #               print STDERR "Wuse $file\n";
  82                 Wrequire $file;
  83                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  84                 $file->import(@list);
  85                 1;
  86         }
  87
  88         sub import
  89         {
  90         my($class,@rest)=@_;
  91
  92                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  93                 Wrequire("$class");
  94                 return $class->SUPER::import(@rest);
  95         }
  96 }
  97
  98 use WebConfig;  # see also below: Wuse 'WebConfig';
  99 require CGI;    # for &escapeHTML
 100 require Image::Size;    # for &imgsize
 101 use File::Basename;     # &basename
 102 use Carp qw(cluck confess);
 103 use URI::Escape;
 104 require HTTP::BrowserDetect;
 105 require HTTP::Negotiate;
 106 my $have_Geo_IP; BEGIN { $have_Geo_IP=eval { require Geo::IP; 1; }; }
 107 # Do not: use ModPerl::Util qw(exit);
 108 # to prevent in mod_perl2: "exit" is not exported by the ModPerl::Util module
 109 # I do not know why.
 110 use POSIX qw(strftime);
 111 use Tie::Handle;
 112 use Apache2::Const qw(HTTP_MOVED_TEMPORARILY OK);
 113 use URI;
 114 use URI::QueryParam;
 115 use Cwd;
 116
 117
 118 #our $W;
 119                 # $W->{"title"}
 120                 # $W->{"head"}
 121                 # $W->{"force_charset"}
 122                 # $W->{"heading_done"}
 123                 # $W->{"footer_passed"}
 124                 # %{$W->{"headers"}}
 125                 # %{$W->{"headers_lc"}} # maps lc($headers_key)=>$headers_key
 126                 # %{$W->{"args"}}
 127
 128 sub cleanup($)
 129 {
 130 my($apache_request)=@_;
 131
 132         # Sanity protection.
 133         $W=undef();
 134         return OK;
 135 }
 136
 137 sub init ($%)
 138 {
 139 my($class,%args)=@_;
 140
 141         print STDERR "$class->init ".Apache2::RequestUtil->request()->unparsed_uri()."\n";
 142
 143         # We need to track package dependencies, so we need to call it from &init.
 144         # We cannot do it in BEGIN { } block
 145         # as it would not be tracked for each of the toplevel users later.
 146         Wuse 'WebConfig';
 147         Wrequire 'My::Hash::Sub';
 148
 149         $W={};
 150         tie %$W,"My::Hash::Sub";
 151         %$W=(%WebConfig,%args); # override %WebConfig settings
 152         $W->{"__PACKAGE__"}||=caller();
 153
 154         # {"__PACKAGE__"} is mandatory for mod_perl-2.0;
 155         # $Apache2::Registry::curstash is no longer supported.
 156         do { cluck "No $_" if !$W->{$_}; } for "__PACKAGE__";
 157
 158         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_ent");
 159         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_js");
 160         do { $W->{$_}=1  if !defined $W->{$_}; } for ("have_css");      # AFAIK it does not hurt anyone.
 161         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer");
 162         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_delimit");
 163         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_ids");
 164         do { $W->{$_}=1  if !defined $W->{$_}; } for ("indexme");
 165         do { $W->{$_}="" if !defined $W->{$_}; } for ("head");
 166         do { $W->{$_}="" if !defined $W->{$_}; } for ("body_attr");
 167         do { $W->{$_}="en-US" if !defined $W->{$_}; } for ("language");
 168
 169         my $footer_any=0;
 170         for (qw(footer_ids)) {
 171                 $W->{$_}=0 if !$W->{"footer"};
 172                 $footer_any=1 if $W->{$_};
 173                 }
 174         $W->{"footer"}=0 if !$footer_any;
 175         $W->{"footer_delimit"}=0 if !$W->{"footer"};
 176
 177         $W->{"r"}=Apache2::RequestUtil->request();
 178
 179         $W->{"r"}->push_handlers("PerlCleanupHandler"=>\&cleanup);
 180
 181         $W->{"web_hostname"}||=$W->{"r"}->hostname();
 182
 183         tie *STDOUT,$W->{"r"};
 184         select *STDOUT;
 185         $|=1;
 186
 187         $W->{"QUERY_STRING"}=$W->{"r"}->args() || "";
 188         if ($W->{"detect_ent"}) {
 189                          if ($W->{"QUERY_STRING"}=~/[&]amp;have_ent/)
 190                         { $W->{"have_ent"}=0; }
 191                 elsif ($W->{"QUERY_STRING"}=~    /[&]have_ent/)
 192                         { $W->{"have_ent"}=1; }
 193                 else
 194                         { delete $W->{"have_ent"}; }
 195                 if (!defined $W->{"have_ent"} && $W->{"r"}->method() eq "GET") {
 196                         $W->{"head"}.='<meta http-equiv="Refresh" content="0; URL='
 197                                         .escapeHTML("http://".$W->{"web_hostname"}."/".($W->{"r"}->uri()=~m#^/*(.*)$#)[0]
 198                                                         ."?".($W->{"QUERY_STRING"} || "detect_ent_glue=1").'&have_ent=detect')
 199                                         .'" />'."\n";
 200                         }
 201                 }
 202         $W->{"QUERY_STRING"}=~s/([&])amp;/$1/g;
 203         $W->{"r"}->args($W->{"QUERY_STRING"});
 204         # Workaround: &CGI::Vars behaves weird if strings passed both as POST data and in: $QUERY_STRING
 205         do { $W->{"r"}->args(""); delete $ENV{"QUERY_STRING"}; } if $W->{"r"}->method() eq "POST";
 206         # Do not: $W->{"r"}->args()
 207         # as it parses only QUERY_STRING (not POST data).
 208         $W->{"args"}={ CGI->new($W->{"r"})->Vars() };
 209         for my $name (keys(%{$W->{"args"}})) {
 210                 my @vals=split /\x00/,$W->{"args"}{$name};
 211                 next if @vals<=1;
 212                 $W->{"args"}{$name}=[@vals];
 213                 }
 214
 215         do { $W->{$_}=$W->{"r"}->headers_in()->{"Accept"}         if !defined $W->{$_}; } for ("accept");
 216         do { $W->{$_}=$W->{"r"}->headers_in()->{"User-Agent"}||"" if !defined $W->{$_}; } for ("user_agent");
 217
 218         $W->{"browser"}=HTTP::BrowserDetect->new($W->{"user_agent"});
 219
 220         if (!defined $W->{"have_style"}) {
 221                 $W->{"have_style"}=(!$W->{"browser"}->netscape() || ($W->{"browser"}->major() && $W->{"browser"}->major()>4) ? 1 : 0);
 222                 }
 223
 224         $W->{"have_js"}=($W->{"args"}{"have_js"} ? 1 : 0);
 225         if ($W->{"detect_js"} && !$W->{"have_js"}) {
 226                 $W->{"head"}.='<script type="text/javascript" src="'.path_web('/have_js.pm').'"></script>'."\n";
 227                 }
 228
 229         do { args_check(%$_) if $_; } for ($W->{"args_check"});
 230
 231         return bless $W,$class;
 232 }
 233
 234 # Although we have &tie-d *STDOUT we try to not to be dependent on it in My::Web itself.
 235 sub Wprint($%)
 236 {
 237 my($text,%args)=@_;
 238
 239         cluck "undef Wprint" if !defined $text && !$args{"undef"};
 240         delete $args{"undef"};
 241         cluck join(" ","Invalid arguments:",keys(%args)) if keys(%args);
 242         $W->{"r"}->puts($text) if defined $text;
 243 }
 244
 245 sub escapeHTML($)
 246 {
 247 my($text)=@_;
 248
 249         # Use &eval to prevent: Global $r object is not available. Set:\n\tPerlOptions +GlobalRequest\nin ...
 250         # CGI requires valid "r": check it beforehand here.
 251         confess "Calling dynamic URL generator from a static code" if !eval { Apache2::RequestUtil->request(); };
 252         return CGI::escapeHTML($text);
 253 }
 254
 255 # local *FH;
 256 # tie *FH,ref($W),$W;
 257 sub TIEHANDLE($)
 258 {
 259 my($class,$W)=@_;
 260
 261         my $self={};
 262         $self->{"W"}=$W or confess "Missing W";
 263         return bless $self,$class;
 264 }
 265
 266 sub WRITE
 267 {
 268 my($self,$scalar,$length,$offset)=@_;
 269
 270         Wprint substr($scalar,0,$length);
 271 }
 272
 273 # /home/user/www/webdir
 274 sub dir_top_abs_disk()
 275 {
 276         our $dir_top_abs_disk;
 277         if (!$dir_top_abs_disk) {
 278                 my $selfpkg_relpath=__PACKAGE__;
 279                 $selfpkg_relpath=~s{::}{/}g;
 280                 $selfpkg_relpath.=".pm";
 281                 my $selfpkg_abspath=$INC{$selfpkg_relpath} or do {
 282                         cluck "Unable to find self package $selfpkg_relpath";
 283                         return;
 284                         };
 285                 $selfpkg_abspath=~s{/*\Q$selfpkg_relpath\E$}{} or do {
 286                         cluck "Unable to strip myself \"$selfpkg_relpath\" from the abspath: $selfpkg_abspath";
 287                         return;
 288                         };
 289                 cluck "INC{myself} is relative?: $selfpkg_abspath" if $selfpkg_abspath!~m{^/};
 290                 $dir_top_abs_disk=$selfpkg_abspath;
 291                 }
 292         return $dir_top_abs_disk;
 293 }
 294
 295 sub unparsed_uri()
 296 {
 297         if (!$W->{"unparsed_uri"}) {
 298                 # Do not: $W->{"r"}
 299                 # as we may be called before &init from: &My::Project::init
 300                 my $r=Apache2::RequestUtil->request();
 301                 cluck "Calling ".'&unparsed_uri'." from a static code, going to fail" if !$r;
 302                 my $uri_string=$r->unparsed_uri() or cluck "Valid 'r' missing unparsed_uri()?";
 303                 my $uri=URI->new_abs($uri_string,"http://".$W->{"web_hostname"}."/");
 304                 $W->{"unparsed_uri"}=$uri;
 305                 }
 306         return $W->{"unparsed_uri"};
 307 }
 308
 309 sub in_to_uri_abs($)
 310 {
 311 my($in)=@_;
 312
 313         # Otherwise we may have been already processed and thus legally relativized.
 314         # FIXME data: Currently disabled, all the data are too violating such rule.
 315         if (0 && !ref $in) {
 316                 my $uri_check=URI->new($in);
 317                 $uri_check->scheme() || $in=~m{^\Q./\E} || $in=~m{^/}
 318                                 or cluck "Use './' or '/' prefix for all the local references: $in";
 319                 }
 320         my $uri=URI->new_abs($in,unparsed_uri());
 321         $uri=$uri->canonical();
 322         return $uri;
 323 }
 324
 325 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 326 # $args{"abs"}=1;
 327 sub path_web($%)
 328 {
 329 my($in,%args)=@_;
 330
 331         cluck if !$args{"uri_as_in"} && ref $in;
 332         my $uri=in_to_uri_abs($in);
 333         if (uri_is_local($uri)) {
 334                 # Prefer the $uri values over "args_persistent" values.
 335                 $uri->query_form_hash({
 336                                 map({
 337                                         my $key=$_;
 338                                         my $val=$W->{"args"}{$key};
 339                                         (!defined $val ? () : ($key=>$val));
 340                                         } keys(%{$W->{"args_persistent"}})),
 341                                 %{$uri->query_form_hash()},
 342                                 });
 343                 }
 344         return $uri->abs(unparsed_uri()) if $W->{"args"}{"Wabs"} || $args{"abs"};
 345         return $uri->rel(unparsed_uri());
 346 }
 347
 348 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 349 sub path_abs_disk($%)
 350 {
 351 my($in,%args)=@_;
 352
 353         cluck if !$args{"uri_as_in"} && ref $in;
 354         my $uri=in_to_uri_abs($in);
 355         cluck if !uri_is_local($uri);
 356         my $path=$uri->path();
 357         cluck "URI compatibility: ->path() not w/leading slash of URI \"$uri\"; path: $path" if $path!~m{^/};
 358         return dir_top_abs_disk().$path;
 359 }
 360
 361 sub fatal (;$);
 362
 363 sub args_check (%)
 364 {
 365 my(%tmpl)=@_;
 366
 367         while (my($name,$regex)=each(%tmpl)) {
 368                 my $name_html="Parameter <span class=\"quote\">".escapeHTML($name)."</span>";
 369                 $W->{"args"}{$name}="" if !defined $W->{"args"}{$name};
 370                 $W->{"args"}{$name}=[ $W->{"args"}{$name} ] if !ref $W->{"args"}{$name} && ref $regex;
 371                 fatal "$name_html passed as multivar although singlevar expected"
 372                                 if ref $W->{"args"}{$name} && !ref $regex;
 373                 $regex=$regex->[0] if ref $regex;
 374                 for my $val (!ref $W->{"args"}{$name} ? $W->{"args"}{$name} : @{$W->{"args"}{$name}}) {
 375                         $val="" if !defined $val;
 376                         fatal "$name_html <span class=\"quote\">".escapeHTML($val)."</span>"
 377                                                         ." does not match the required regex <span class=\"quote\">".escapeHTML($regex)."</span> "
 378                                         if $regex ne "" && $val!~/$regex/;
 379                         }
 380                 }
 381 }
 382
 383 sub vskip (;$)
 384 {
 385 my($height)=@_;
 386
 387         return '<p'.(!defined $height ? "" : ' style="height: '.$height.';"').'>&nbsp;</p>'."\n";
 388 }
 389
 390 sub fatal (;$)
 391 {
 392 my($msg)=@_;
 393
 394         $msg="UNKNOWN" if !$msg;
 395         cluck "FATAL: $msg";
 396
 397         # Do not send it unconditionally.
 398         # The intial duplicated '<?xml...' crashes Gecko parser.
 399         $W->{"heading_done"}=0 if $W->{"header_only"};
 400         # Do not send it unconditionally.
 401         # Prevents warn: Headers already sent
 402         if (!$W->{"heading_done"}) {
 403                 $W->{"indexme"}=0;      # For the case no heading was sent yet.
 404                 $W->{"header_only"}=0;  # assurance for &heading
 405                 My::Web->heading();
 406                 }
 407         Wprint "\n".vskip("3ex")."<hr /><h1 class=\"error\">FATAL ERROR: $msg!</h1>\n"
 408                         ."<p>You can report this problem's details to"
 409                         ." ".a_href("mailto:".$W->{"admin_mail"},"admin of this website").".</p>\n";
 410         footer();
 411 }
 412
 413 sub footer (;$)
 414 {
 415         exit 1 if $W->{"footer_passed"}++;      # deadlock prevention:
 416
 417         Wprint vskip if $W->{"footer_delimit"};
 418
 419         Wprint $W->{"footing_delimit"},"undef"=>1;
 420
 421         Wprint "<hr />\n" if $W->{"footer"};
 422
 423         my $packages_used=$packages_used_array{$W->{"__PACKAGE__"}};
 424
 425         if ($W->{"footer_ids"}) {
 426                 Wprint '<p class="cvs-id">';
 427                 Wprint join("<br />\n",map({ my $package=$_;
 428                         my $cvs_id=(eval('$'.$package."::CVS_ID")
 429 #                                       || $package     # debug
 430                                         );
 431                         if (!$cvs_id) {
 432                                 ();
 433                                 }
 434                         else {
 435                                 $cvs_id='$'.$cvs_id.'$';        # Eaten by 'q' operator.
 436                                 my @cvs_id_split=split / +/,$cvs_id;
 437                                 if (@cvs_id_split==8) {
 438                                         my $file=$package;
 439                                         $file=~s#::#/#g;
 440                                         my $ext;
 441                                         my @tried;
 442                                         for (qw(.pm)) {
 443                                                 $ext=$_;
 444                                                 my $path_abs_disk=path_abs_disk("/$file$ext");
 445                                                 push @tried,$path_abs_disk;
 446                                                 last if -r $path_abs_disk;
 447                                                 cluck "Class file $file not found; tried: ".join(" ",@tried) if !$ext;
 448                                                 }
 449                                         $file.=$ext;
 450                                         $cvs_id_split[2]=""
 451                                                         .a_href((map({ my $s=$_; $s=~s#/viewcvs/#$&~checkout~/#; $s; } $W->{"viewcvs"}))[0]."$file?rev=".$cvs_id_split[2],
 452                                                                         $cvs_id_split[2]);
 453                                         $cvs_id_split[1]=a_href($W->{"viewcvs"}.$file,
 454                                                         ($package!~/^Apache2::/ ? $package : $cvs_id_split[1]));
 455                                         $cvs_id_split[5]=&{$W->{"cvs_id_author_sub"}}($cvs_id_split[5]);
 456                                         }
 457                                 join " ",@cvs_id_split;
 458                                 }
 459                         } @$packages_used));
 460                 Wprint "</p>\n";
 461                 }
 462
 463         for my $package (@$packages_used) {
 464                 my $cvs_id=(eval('$'.$package."::CVS_ID")
 465 #                               || $package     # debug
 466                                 );
 467                 Wprint '<!-- '.$package.' - $'.$cvs_id.'$ -->'."\n" if $cvs_id;
 468                 }
 469
 470         Wprint $W->{"footing"},"undef"=>1;
 471
 472         Wprint "</body></html>\n";
 473         exit 0;
 474 }
 475
 476 sub header (%)
 477 {
 478 my(%pairs)=@_;
 479
 480         while (my($key,$val)=each(%pairs)) {
 481                 do { cluck "Headers already sent"; next; } if $W->{"heading_done"};
 482                 for ($W->{"headers_lc"}{lc $key} || ()) {
 483                         delete $W->{"headers"}{$_};
 484                         }
 485                 $W->{"headers_lc"}{lc $key}=$key;
 486                 $W->{"headers"}{$key}=$val;
 487                 }
 488 }
 489
 490 sub size_display ($)
 491 {
 492 my($size)=@_;
 493
 494            if ($size<4096)
 495                 {}
 496         elsif ($size<1024*1024)
 497                 { $size=sprintf "%.1fK",$size/1024; }
 498         else
 499                 { $size=sprintf "%.1fM",$size/1024/1024; }
 500         $size.="B";
 501         return $size;
 502 }
 503
 504 sub uri_is_local($)
 505 {
 506 my($in)=@_;
 507
 508         my $uri_rel=in_to_uri_abs($in)->rel(unparsed_uri());
 509         # Do not: defined $uri_rel->("userinfo"|"host"|"port")();
 510         # as they fail to be called for schemes not supporting them.
 511         return 0 if $uri_rel->scheme();
 512         return 0 if $uri_rel->authority();
 513         return 1;
 514 }
 515
 516 # &path_web still may be required for &uri_escaped !
 517 sub uri_escaped($)
 518 {
 519 my($uri)=@_;
 520
 521         cluck if !ref $uri;
 522         my $urient=escapeHTML($uri);
 523         return $uri    if $uri eq $urient;
 524         return $urient if uri_is_local $uri;
 525         return $uri    if defined $W->{"have_ent"} && !$W->{"have_ent"};        # non-ent client
 526         return $urient if $W->{"have_ent"};     # ent client
 527         # Unknown client, &escapeHTML should not be needed here:
 528         return escapeHTML(path_web('/Redirect.pm?location='.uri_escape($uri->abs(unparsed_uri()))));
 529 }
 530
 531 our $a_href_inhibited;
 532 sub a_href($;$%)
 533 {
 534 my($in,$contents,%args)=@_;
 535
 536         do { $$_=1 if !defined $$_; } for (\$args{"size"});
 537         if (!defined $contents) {
 538                 $contents=$in;
 539                 $contents=File::Basename::basename($contents) if $args{"basename"};
 540                 $contents=escapeHTML($contents);
 541                 }
 542         $contents=~s#<a\b[^>]*>##gi;
 543         $contents=~s#</a>##gi;
 544         return $contents if $a_href_inhibited;
 545
 546         my $path_web=path_web $in,%args;
 547         my $r="";
 548         $r.='<a href="';
 549         $r.=uri_escaped $path_web;
 550         $r.='"';
 551         do { $r.=" $_" if $_; } for ($args{"attr"});
 552         $r.='>'.$contents.'</a>';
 553         if ($args{"size"} && uri_is_local($in) && ($args{"size"}>=2 || $in=~/[.](?:gz|Z|rpm|zip|deb|lha)/)) {   # Downloadable?
 554                 my $path_abs_disk=path_abs_disk $in,%args;
 555                 cluck "File not readable: $path_abs_disk" if !-r $path_abs_disk;
 556                 $r.='&nbsp;('.size_display((stat($path_abs_disk))[7]).')';
 557                 }
 558         return $r;
 559 }
 560
 561 sub a_href_inhibit($$;@)
 562 {
 563 my($self,$sub,@sub_args)=@_;
 564
 565         local $a_href_inhibited=1;
 566         return &{$sub}(@sub_args);
 567 }
 568
 569 sub input_hidden_persistents()
 570 {
 571         return join("",map({
 572                 my $key=$_;
 573                 my $val=$W->{"args"}{$key};
 574                 (!defined $val ? () : '<input type="hidden"'
 575                                 .' name="'.escapeHTML($key).'"'
 576                                 .' value="'.escapeHTML($val).'"'
 577                                 .' />'."\n");
 578                 } (keys(%{$W->{"args_persistent"}}))));
 579 }
 580
 581 sub http_moved($$;$)
 582 {
 583 my($self,$url,$status)=@_;
 584
 585         $url=path_web($url,"abs"=>1);
 586         $status||=HTTP_MOVED_TEMPORARILY;
 587         $W->{"r"}->status($status);
 588         $W->{"r"}->headers_out()->{"Location"}=$url;
 589         $W->{"header_only"}=1;
 590         My::Web->heading();
 591         exit;
 592         die "NOTREACHED";
 593 }
 594
 595 sub remote_ip ()
 596 {
 597         # Do not: PerlModule                 Apache2::ForwardedFor
 598         #         PerlPostReadRequestHandler Apache2::ForwardedFor
 599         # As 'Apache2::ForwardedFor' takes the first of $ENV{"HTTP_X_FORWARDED_FOR"}
 600         # while the contents is '127.0.0.1, 213.220.195.171' if client has its own proxy.
 601         # We must take the last item ourselves.
 602         my $r=$W->{"r"}->headers_in()->{"X-Forwarded-For"} || $W->{"r"}->get_remote_host();
 603         $r=~s/^.*,\s*//;
 604         return $r;
 605 }
 606
 607 sub is_cz ()
 608 {
 609         return 0 if !$have_Geo_IP;
 610         return "CZ" eq Geo::IP->new()->country_code_by_addr(remote_ip());
 611 }
 612
 613 sub a_href_cz ($$;%)
 614 {
 615 my($url,$contents,%args)=@_;
 616
 617         return a_href $url,$contents,%args if is_cz();
 618         return $contents;
 619 }
 620
 621 sub make ($)
 622 {
 623 my($cmd)=@_;
 624
 625         # FIXME: &alarm, --timeout is now infinite.
 626         # FIXME: Try to remove bash(1).
 627         # FIXME: Use: @PATH_FLOCK@
 628         my @argv=('flock',dir_top_abs_disk(),'bash','-c',$cmd.' >&2');
 629         print STDERR join(" ","SPAWN:",@argv)."\n";
 630         system @argv;
 631 }
 632
 633 sub make_file($$)
 634 {
 635 my($self,$file)=@_;
 636
 637         cluck "Pathname not absolute: $file" if $file!~m{^/};
 638         return if -f $file;
 639         # TODO: Somehow quickly check dependencies?
 640         return make('make -s --no-print-directory'
 641                                         .' -C '."'".File::Basename::dirname($file)."' '".File::Basename::basename($file)."'");
 642 }
 643
 644 sub img_size ($$)
 645 {
 646 my($width,$height)=@_;
 647
 648         cluck if !defined $width || !defined $height;
 649         return ($W->{"have_style"} ? "style=\"border:0;width:${width}px;height:${height}px\"" : "border=\"0\"")
 650                         ." width=\"$width\" height=\"$height\"";
 651 }
 652
 653 sub negotiate_variant (%)
 654 {
 655 my(%args)=@_;
 656
 657         my @fields=("id","qs","content-type","encoding","charset","lang","size");
 658         return [ map(($args{$_}),@fields) ];
 659 }
 660
 661 # Input: $self is required!
 662 # Input: Put the fallback variant as the first one.
 663 # Returns: always only scalar!
 664 sub Negotiate_choose($$)
 665 {
 666 my($self,$variants)=@_;
 667
 668         my $best=HTTP::Negotiate::choose($variants,
 669                         # Do not: $W->{"r"}
 670                         # to prevent: Can't locate object method "scan" via package "Apache2::RequestRec" at HTTP/Negotiate.pm line 84.
 671                         # Do not: $W->{"r"}->headers_in()
 672                         # to prevent: Can't locate object method "scan" via package "APR::Table" at HTTP/Negotiate.pm line 84.
 673                         # Do not: HTTP::Headers->new($W->{"r"}->headers_in());
 674                         # to prevent empty result or even: Odd number of elements in anonymous hash
 675                         HTTP::Headers->new(%{$W->{"r"}->headers_in()}));
 676         $best||=$variants->[0][0];      # $variants->[0]{"id"}; &HTTP::Negotiate::choose failed?
 677         return $best;
 678 }
 679
 680 my @img_variants=(
 681                 { "id"=>"png","qs"=>0.9,"content-type"=>"image/png" },
 682                 { "id"=>"gif","qs"=>0.7,"content-type"=>"image/gif" },
 683                 );
 684 my $img_variants_re='[.](?:'.join('|',"jpeg",map(($_->{"id"}),@img_variants)).')$';
 685
 686 # Returns: ($path_web,$path_abs_disk)
 687 # URI path segments support ignored here. Where it is used? (';' path segment options)
 688 sub _img_src($%)
 689 {
 690 my($in,%args)=@_;
 691
 692         cluck if !uri_is_local $in;
 693         my $uri=in_to_uri_abs $in;
 694         my $path_abs_disk=path_abs_disk $uri,%args,"uri_as_in"=>1;
 695
 696         # Known image extension?
 697         return path_web($uri,%args,"uri_as_in"=>1),$path_abs_disk if $uri->path()=~m#$img_variants_re#o;
 698
 699         my @nego_variants;
 700         for my $var (@img_variants) {
 701                 my $path_abs_disk_variant=$path_abs_disk.".".$var->{"id"};
 702                 __PACKAGE__->make_file($path_abs_disk_variant);
 703                 push @nego_variants,negotiate_variant(
 704                                 %$var,
 705                                 "size"=>(stat $path_abs_disk_variant)[7],
 706                                 );
 707                 }
 708         my $ext=__PACKAGE__->Negotiate_choose(\@nego_variants);
 709
 710         $uri->path($uri->path().".$ext");
 711         return path_web($uri,%args,"uri_as_in"=>1),path_abs_disk($uri,%args,"uri_as_in"=>1);
 712 }
 713
 714 # $args{"attr"}
 715 sub img ($$%)
 716 {
 717 my($in,$alt,%args)=@_;
 718
 719         my($path_web,$path_abs_disk)=_img_src($in,%args);
 720         my($width,$height)=Image::Size::imgsize($path_abs_disk);
 721         $alt=~s/<[^>]*>//g;
 722         $alt=escapeHTML($alt);
 723         my $content="<img src=\"".uri_escaped($path_web)."\" alt=\"$alt\" title=\"$alt\" ".img_size($width,$height)
 724                         .(!$args{"attr"} ? "" : " ".$args{"attr"})." />";
 725         do { return a_href((_img_src($_))[0],$content,"uri_as_in"=>1) if $_; } for $args{"a_href_img"};
 726         do { return a_href $_,$content if $_; } for $args{"a_href"};
 727         return $content;
 728 }
 729
 730 sub centerimg
 731 {
 732         my $r="";
 733         $r.='<table border="0" width="100%"><tr>'."\n";
 734         @_=( [@_] ) if !ref $_[0];
 735         for (@_) {
 736                 $r.="\t".'<td align="center">'.&{\&img}(@$_).'</td>'."\n";
 737                 }
 738         $r.='</tr></table>'."\n";
 739         return $r;
 740 }
 741
 742 sub rightimg
 743 {
 744 my($text,@args_img)=@_;
 745
 746         # FIXME: Workaround bug of 'Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)':
 747         #        <col width="@{[ (!$W->{"browser"}->ie() ? "1*" : "90%" ) ]}" />
 748         #        <col width="@{[ (!$W->{"browser"}->ie() ? "0*" : "10%" ) ]}" />
 749         # causes whole invisible projects in: Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.7.10) Gecko/20050719 Galeon/1.3.21
 750         return <<"HERE";
 751 <table border="0" width="100%">
 752         <tr>
 753                 <td align="left">
 754                         @{[ $text ]}
 755                 </td>
 756                 <td align="right">
 757                         @{[ &{\&img}(@args_img) ]}
 758                 </td>
 759         </tr>
 760 </table>
 761 HERE
 762 }
 763
 764 sub readfile($$)
 765 {
 766 my($class,$filename)=@_;
 767
 768         local *F;
 769         open F,$filename or cluck "Cannot open \"$filename\": $!";
 770         my $F=do { local $/=undef(); <F>; };
 771         close F or cluck "Cannot close \"$filename\": $!";
 772         return $F;
 773 }
 774
 775 sub no_cache($)
 776 {
 777 my($self)=@_;
 778
 779         header("Expires"=>"Mon, 26 Jul 1997 05:00:00 GMT");     # date in the past
 780         header("Last-Modified"=>strftime("%a, %d %b %Y %H:%M:%S GMT",gmtime()));        # always modified
 781         header("Cache-Control"=>"no-cache, must-revalidate");   # HTTP/1.1
 782         header("Pragma"=>"no-cache");   # HTTP/1.0
 783 }
 784
 785 sub heading()
 786 {
 787 my($class)=@_;
 788
 789         # $ENV{"CLIENT_CHARSET"} ignored (mod_czech support dropped!)
 790         my $client_charset=$W->{"force_charset"} || "us-ascii";
 791         header("Content-Style-Type"=>"text/css");
 792         header("Content-Script-Type"=>"text/javascript");
 793         do { header("Content-Language"=>$_) if $_; } for $W->{"language"};
 794         $class->no_cache() if $W->{"no_cache"};
 795
 796         while (my($key,$val)=each(%{$W->{"headers"}})) {
 797                 $W->{"r"}->headers_out()->{$key}=$val;
 798                 }
 799         exit if $W->{"r"}->header_only();
 800         return if $W->{"header_only"};
 801         # We still can append headers before we put out some text.
 802         # FIXME: It is not clean to still append them without overwriting.
 803         return if $W->{"heading_done"}++;
 804
 805         # Workaround bug
 806         #   https://bugzilla.mozilla.org/show_bug.cgi?id=120556
 807         # of at least
 808         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
 809         my $mime;
 810         # http://validator.w3.org/ does not send ANY "Accept" headers!
 811         $mime||="application/xhtml+xml" if !$W->{"accept"} && $W->{"user_agent"}=~m{^W3C_Validator/}i;
 812         $mime||=$class->Negotiate_choose([
 813                         # Put the fallback variant as the first one.
 814                         # Rate both variants the same to prefer "text/html" for undecided clients.
 815                         # At least
 816                         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
 817                         # prefers "application/xhtml+xml" over "text/html" itself:
 818                         #   text/xml,application/xml,application/xhtml+xml,text/html;q=0.9,text/plain;q=0.8,image/png,*/*;q=0.5
 819                         negotiate_variant(
 820                                         "id"=>"text/html",
 821                                         "content-type"=>"text/html",
 822                                         "qs"=>0.6,
 823                                         "charset"=>$client_charset,
 824                                         "lang"=>$W->{"language"},
 825                                         ),
 826                         negotiate_variant(
 827                                         "id"=>"application/xhtml+xml",
 828                                         "content-type"=>"application/xhtml+xml",
 829                                         "qs"=>0.6,
 830                                         "charset"=>$client_charset,
 831                                         "lang"=>$W->{"language"},
 832                                         ),
 833                         # application/xml ?
 834                         # text/xml ?
 835                         ]);
 836         $W->{"r"}->content_type("$mime; charset=$client_charset");
 837         Wprint '<?xml version="1.0" encoding="'.$client_charset.'"?>'."\n" if $mime=~m{^application/\w+[+]xml$};
 838         return if $W->{"xml_header_only"};
 839         Wprint '<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN" "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">'."\n";
 840         Wprint '<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="'.$W->{"language"}.'">'."\n";
 841         my $title=$W->{"title_prefix"}.join("",map({ ': '.$_; } ($W->{"title"} || ())));
 842         # Do not: cluck if $title=~/[<>]/;
 843         # as it is not solved just by: &a_href_inhibit
 844         # as sometimes titles use also: <i>...</i>
 845         $title=~s#<[^>]*>##g;
 846         Wprint "<head>";
 847         Wprint "<title>$title</title>\n";
 848         if ($W->{"have_css"}) {
 849                 # Everything can get overriden later.
 850                 for my $css ("/My/Web.css",map((!$_ ? () : ("ARRAY" ne ref($_) ? $_ : @$_)),$W->{"css_push"})) {
 851                         Wprint <<"HERE";
 852 <link rel="stylesheet" type="text/css" href="@{[ uri_escaped(path_web $css) ]}" />
 853 HERE
 854                         }
 855                 }
 856         Wprint '<meta name="robots" content="'.($W->{"indexme"} ? "" : "no" ).'index,follow" />'."\n";
 857         Wprint $W->{"head"};
 858         for my $type (qw(prev next index contents start up)) {
 859                 do { Wprint '<link rel="'.$type.'" href="'.uri_escaped(path_web $_).'" />'."\n" if $_; }
 860                                 for ($W->{"rel_$type"});
 861                 }
 862         Wprint "</head><body";
 863 #       Wprint ' bgcolor="black" text="white" link="aqua" vlink="teal"'
 864 #                       if $W->{"browser"}->netscape() && (!$W->{"browser"}->major() || $W->{"browser"}->major()<=4);
 865         Wprint $W->{"body_attr"};
 866         Wprint ">\n";
 867
 868         Wprint $W->{"heading"},"undef"=>1;
 869 }
 870
 871 BEGIN {
 872         delete $W->{"__My::Web_init"};
 873         }
 874
 875 1;