Web.pm

   1 # $Id$
   2 # Common functions for HTML/XHTML output generation
   3 # Copyright (C) 2003-2005 Jan Kratochvil <project-www.jankratochvil.net@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 package My::Web;
  20 require 5.6.0;  # at least 'use warnings;' but we need some 5.6.0+ modules anyway
  21 our $VERSION=do { my @r=(q$Revision$=~/\d+/g); sprintf "%d.".("%03d"x$#r),@r; };
  22 our $CVS_ID=q$Id$;
  23 use strict;
  24 use warnings;
  25
  26 use Exporter;
  27 sub Wrequire($);
  28 sub Wuse($@);
  29 our $W;
  30 our @EXPORT=qw(
  31                 &Wrequire &Wuse
  32                 &path_web &path_abs_disk
  33                 &uri_escaped
  34                 &a_href &a_href_cc
  35                 &vskip
  36                 &img &centerimg &rightimg
  37                 $W
  38                 &input_hidden_persistents
  39                 &escapeHTML
  40                 );
  41 our @ISA=qw(Tie::Handle Exporter);
  42
  43 my %packages_used_hash; # $packages_used_hash{$W->{"__PACKAGE__"}}{"_done"}=1;
  44 my %packages_used_array;
  45
  46 BEGIN
  47 {
  48         use Carp qw(cluck confess);
  49         $W->{"__My::Web_init"}=1;
  50
  51         sub Wrequire ($)
  52         {
  53         my($file)=@_;
  54
  55 #               print STDERR "Wrequire $file\n";
  56                 $file=~s#/#::#g;
  57                 $file=~s/[.]pm$//;
  58                 my $class=$file;
  59                 $file=~s#::#/#g;
  60                 $file.=".pm";
  61                 my %callers;
  62                 for (my $depth=0;defined caller($depth);$depth++) {
  63                         $callers{caller($depth)}=1;
  64                         }
  65                 my $selfpkg=__PACKAGE__;
  66                 $callers{$selfpkg}=1;
  67                 for my $target ($class,__PACKAGE__) {
  68                         for my $caller (keys(%callers)) {
  69                                 next if $caller eq $target;
  70                                 next if $packages_used_hash{$caller}{$target}++;
  71                                 push @{$packages_used_array{$caller}},$target;
  72                                 }
  73                         }
  74                 eval { CORE::require "$file"; } or confess $@;
  75                 1;      # Otherwise 'require' would already file above.
  76         }
  77
  78         sub Wuse ($@)
  79         {
  80         my($file,@list)=@_;
  81
  82 #               print STDERR "Wuse $file\n";
  83                 Wrequire $file;
  84                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  85                 $file->import(@list);
  86                 1;
  87         }
  88
  89         sub import
  90         {
  91         my($class,@rest)=@_;
  92
  93                 local $Exporter::ExportLevel=$Exporter::ExportLevel+1;
  94                 Wrequire("$class");
  95                 return $class->SUPER::import(@rest);
  96         }
  97 }
  98
  99 use WebConfig;  # see also below: Wuse 'WebConfig';
 100 require CGI;
 101 require Image::Size;    # for &imgsize
 102 use File::Basename;     # &basename
 103 use Carp qw(cluck confess);
 104 use URI::Escape;
 105 require HTTP::BrowserDetect;
 106 require HTTP::Negotiate;
 107 our $have_Geo_IP; BEGIN { $have_Geo_IP=eval { require Geo::IP; 1; }; }
 108 # Do not: use ModPerl::Util qw(exit);
 109 # to prevent in mod_perl2: "exit" is not exported by the ModPerl::Util module
 110 # I do not know why.
 111 use POSIX qw(strftime);
 112 use Tie::Handle;
 113 use Apache2::Const qw(HTTP_MOVED_TEMPORARILY OK HTTP_OK);
 114 use URI;
 115 use URI::QueryParam;
 116 use Cwd;
 117 require HTTP::Date;
 118 require Storable;
 119 require Digest::MD5;
 120 require Data::Compare;
 121 use Data::Dumper;
 122 require Encode;
 123 use Apache2::Filter;
 124 use Apache2::Connection;
 125
 126
 127 #our $W;
 128
 129 sub cleanup($)
 130 {
 131 my($apache_request)=@_;
 132
 133         $packages_used_hash{$W->{"__PACKAGE__"}}{"_done"}=1;
 134         cache_finish();
 135         # Sanity protection.
 136         $W=undef();
 137         return OK;
 138 }
 139
 140 sub request_check(;$)
 141 {
 142 my($self)=@_;
 143
 144         # Use &eval to prevent: Global $r object is not available. Set:\n\tPerlOptions +GlobalRequest\nin ...
 145         # CGI requires valid "r": check it beforehand here.
 146         confess "Calling sensitive dynamic code from a static code" if !eval { Apache2::RequestUtil->request(); };
 147         # Do not: confess "Calling sensitive dynamic code without My::Web::init" if !$W->{"__PACKAGE__"};
 148         # as it is valid at least while preparing arguments to call: &project::Lib::init
 149 }
 150
 151 sub init ($%)
 152 {
 153 my($class,%args)=@_;
 154
 155         print STDERR "$class->init ".Apache2::RequestUtil->request()->unparsed_uri()."\n";
 156
 157         # We need to track package dependencies, so we need to call it from &init.
 158         # We cannot do it in BEGIN { } block
 159         # as it would not be tracked for each of the toplevel users later.
 160         Wuse 'WebConfig';
 161         Wrequire 'My::Hash';
 162
 163         $W=My::Hash->new({
 164                 "__PACKAGE__"=>scalar(caller()),
 165                 %WebConfig,
 166                 %args,  # override %WebConfig settings
 167                 },"My::Hash::Sub","My::Hash::Push");
 168
 169         # {"__PACKAGE__"} is mandatory for mod_perl-2.0;
 170         # $Apache2::Registry::curstash is no longer supported.
 171         do { cluck "No $_" if !$W->{$_}; } for "__PACKAGE__";
 172
 173         # See: &escapeHTML
 174         do { cluck "charset==$_, expecting ISO-8859-1" if $_ ne "ISO-8859-1"; } for CGI::charset();
 175         CGI::charset("utf-8");
 176
 177         do { $W->{$_}=0  if !defined $W->{$_}; } for "detect_ent";
 178         do { $W->{$_}=0  if !defined $W->{$_}; } for "detect_js";
 179         do { $W->{$_}=1  if !defined $W->{$_}; } for "have_css";        # AFAIK it does not hurt anyone.
 180         do { $W->{$_}=0  if !defined $W->{$_}; } for "css_inherit";
 181         do { $W->{$_}=1  if !defined $W->{$_}; } for "footer";
 182         do { $W->{$_}=1  if !defined $W->{$_}; } for "footer_delimit";
 183         do { $W->{$_}=1  if !defined $W->{$_}; } for "footer_ids";
 184         do { $W->{$_}=1  if !defined $W->{$_}; } for "indexme";
 185         do { $W->{$_}="" if !defined $W->{$_}; } for "head";
 186         do { $W->{$_}="" if !defined $W->{$_}; } for "body_attr";
 187         do { $W->{$_}="en-US" if !defined $W->{$_}; } for "language";
 188
 189         my $footer_any=0;
 190         for (qw(footer_ids)) {
 191                 $W->{$_}=0 if !$W->{"footer"};
 192                 $footer_any=1 if $W->{$_};
 193                 }
 194         $W->{"footer"}=0 if !$footer_any;
 195         $W->{"footer_delimit"}=0 if !$W->{"footer"};
 196
 197         $W->{"r"}=Apache2::RequestUtil->request();
 198
 199         $W->{"r"}->push_handlers("PerlCleanupHandler"=>\&cleanup);
 200
 201         $W->{"web_hostname"}||=$W->{"r"}->hostname();
 202
 203         tie *STDOUT,$W->{"r"};
 204         select *STDOUT;
 205         $|=1;
 206
 207         $W->{"QUERY_STRING"}=$W->{"r"}->args() || "";
 208         if ($W->{"detect_ent"}) {
 209                          if ($W->{"QUERY_STRING"}=~/[&]amp;have_ent/)
 210                         { $W->{"have_ent"}=0; }
 211                 elsif ($W->{"QUERY_STRING"}=~    /[&]have_ent/)
 212                         { $W->{"have_ent"}=1; }
 213                 else
 214                         { delete $W->{"have_ent"}; }
 215                 if (!defined $W->{"have_ent"} && $W->{"r"}->method() eq "GET") {
 216                         $W->{"head"}.='<meta http-equiv="Refresh" content="0; URL='
 217                                         .escapeHTML("http://".$W->{"web_hostname"}."/".($W->{"r"}->uri()=~m#^/*(.*)$#)[0]
 218                                                         ."?".($W->{"QUERY_STRING"} || "detect_ent_glue=1").'&have_ent=detect')
 219                                         .'" />'."\n";
 220                         }
 221                 }
 222         $W->{"QUERY_STRING"}=~s/([&])amp;/$1/g;
 223         $W->{"r"}->args($W->{"QUERY_STRING"});
 224         # Workaround: &CGI::Vars behaves weird if strings passed both as POST data and in: $QUERY_STRING
 225         do { $W->{"r"}->args(""); delete $ENV{"QUERY_STRING"}; } if $W->{"r"}->method() eq "POST";
 226         # Do not: $W->{"r"}->args()
 227         # as it parses only QUERY_STRING (not POST data).
 228         $W->{"args_orig_array"}=[ CGI->new($W->{"r"})->Vars() ];
 229         $W->{"args"}={ @{$W->{"args_orig_array"}} };
 230         for my $name (keys(%{$W->{"args"}})) {
 231                 my @vals=split /\x00/,$W->{"args"}{$name};
 232                 next if @vals<=1;
 233                 $W->{"args"}{$name}=[@vals];
 234                 }
 235
 236         $W->{"headers_in"}=$W->{"r"}->headers_in();
 237         Wrequire 'My::Hash::Merge';
 238         $W->{"headers_in"}=My::Hash::Merge->new(
 239                         $W->{"headers_in"},
 240                         My::Hash::Sub->new({
 241                                 "_remote_ip"=>sub { return $W->{"r"}->connection()->remote_ip(); },
 242                                 }),
 243                         );
 244         Wrequire 'My::Hash::Readonly';
 245         $W->{"headers_in"}=My::Hash::Readonly->new($W->{"headers_in"});
 246
 247         if ($W->{"r"}->method() eq "GET" || $W->{"r"}->method() eq "HEAD") {
 248                 for (\$W->{"http_safe"}) {
 249                         # Do not: # Extend the current ETag system instead if you would need it:
 250                         #         cluck "Explicitely NOT HTTP-Safe for method \"".$W->{"r"}->method()."\"?!?"
 251                         #                       if defined($$_) && !$$_;
 252                         # as sometimes it just does not make sense to cache it.
 253                         $$_=1 if !defined $$_;
 254                         }
 255                 }
 256         else {
 257                 for (\$W->{"http_safe"}) {
 258                         cluck "Undefined HTTP-Safe-ty for method \"".$W->{"r"}->method()."\"!"
 259                                         if !defined($$_);
 260                         $$_=0 if !defined $$_;
 261                         }
 262                 }
 263         if ($W->{"http_safe"}) {
 264                 Wrequire 'My::Hash::RecordKeys';
 265                 $W->{"headers_in_RecordKeys"}=My::Hash::RecordKeys->new($W->{"headers_in"});
 266                 $W->{"headers_in"}=$W->{"headers_in_RecordKeys"};
 267                 }
 268
 269         $W->{"browser"}=HTTP::BrowserDetect->new($W->{"headers_in"}{"User-Agent"});
 270
 271         if (!defined $W->{"have_style"}) {
 272                 $W->{"have_style"}=(!$W->{"browser"}->netscape() || ($W->{"browser"}->major() && $W->{"browser"}->major()>4) ? 1 : 0);
 273                 }
 274
 275         $W->{"have_js"}=($W->{"args"}{"have_js"} ? 1 : 0);
 276         if ($W->{"detect_js"} && !$W->{"have_js"}) {
 277                 $W->{"head"}.='<script type="text/javascript" src="'.uri_escaped(path_web('/My/HaveJS.pm')).'"></script>'."\n";
 278                 }
 279
 280         do { _args_check(%$_) if $_; } for ($W->{"args_check"});
 281
 282         return bless $W,$class;
 283 }
 284
 285 # Be aware other parts of code (non-My::Web) will NOT use this function!
 286 # Do not: Wprint $W->{"heading"},"undef"=>1;
 287 # as we would need to undef() it to turn it off and it would get defaulted in such case.
 288 # Do not: exists $W->{"heading"}
 289 # as we use a lot of 'for $W->{"heading"}' which instantiates it with the value: undef()
 290 sub Wprint($%)
 291 {
 292 my($text,%args)=@_;
 293
 294         cluck "undef Wprint" if !defined $text && !$args{"undef"};
 295         delete $args{"undef"};
 296         cluck join(" ","Invalid arguments:",keys(%args)) if keys(%args);
 297         return if !defined $text;
 298         cluck "utf-8 untested" if Encode::is_utf8($text);
 299         $W->{"r"}->puts($text);
 300 }
 301
 302 sub escapeHTML($)
 303 {
 304 my($text)=@_;
 305
 306         # Prevent &CGI::escapeHTML breaking utf-8 strings like: \xC4\x9B eq \x{11B}
 307         # Prevent case if we run under mod_perl but still just initializing:
 308         request_check() if $ENV{"MOD_PERL"};
 309         # Generally we are initialized from &init but we may be used without it without mod_perl
 310         # and in such case check the change on all non-first invocations.
 311         our $init;
 312         if (!$ENV{"MOD_PERL"} && $init++) {
 313                 do { cluck "charset==$_" if $_ ne "utf-8"; } for CGI::charset();
 314                 }
 315         CGI::charset("utf-8");
 316
 317         return CGI::escapeHTML($text);
 318 }
 319
 320 # /home/user/www/webdir
 321 sub dir_top_abs_disk()
 322 {
 323         our $dir_top_abs_disk;
 324         if (!$dir_top_abs_disk) {
 325                 my $selfpkg_relpath=__PACKAGE__;
 326                 $selfpkg_relpath=~s{::}{/}g;
 327                 $selfpkg_relpath.=".pm";
 328                 my $selfpkg_abspath=$INC{$selfpkg_relpath} or do {
 329                         cluck "Unable to find self package $selfpkg_relpath";
 330                         return;
 331                         };
 332                 $selfpkg_abspath=~s{/*\Q$selfpkg_relpath\E$}{} or do {
 333                         cluck "Unable to strip myself \"$selfpkg_relpath\" from the abspath: $selfpkg_abspath";
 334                         return;
 335                         };
 336                 cluck "INC{myself} is relative?: $selfpkg_abspath" if $selfpkg_abspath!~m{^/};
 337                 $dir_top_abs_disk=$selfpkg_abspath;
 338                 }
 339         return $dir_top_abs_disk;
 340 }
 341
 342 sub unparsed_uri()
 343 {
 344         request_check();
 345         if (!$W->{"unparsed_uri"}) {
 346                 # Do not: $W->{"r"}
 347                 # as we may be called before &init from: &My::Project::init
 348                 my $r=Apache2::RequestUtil->request();
 349                 cluck "Calling ".'&unparsed_uri'." from a static code, going to fail" if !$r;
 350                 my $uri_string=$r->unparsed_uri() or cluck "Valid 'r' missing unparsed_uri()?";
 351                 my $uri=URI->new_abs($uri_string,"http://".$W->{"web_hostname"}."/");
 352                 $W->{"unparsed_uri"}=$uri;
 353                 }
 354         return $W->{"unparsed_uri"};
 355 }
 356
 357 sub in_to_uri_abs($)
 358 {
 359 my($in)=@_;
 360
 361         # Otherwise we may have been already processed and thus legally relativized.
 362         # FIXME data: Currently disabled, all the data are too violating such rule.
 363         if (0 && !ref $in) {
 364                 my $uri_check=URI->new($in);
 365                 $uri_check->scheme() || $in=~m{^\Q./\E} || $in=~m{^/}
 366                                 or cluck "Use './' or '/' prefix for all the local references: $in";
 367                 }
 368         my $uri=URI->new_abs($in,unparsed_uri());
 369         $uri=$uri->canonical();
 370         return $uri;
 371 }
 372
 373 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 374 # $args{"abs"}=1;
 375 sub path_web($%)
 376 {
 377 my($in,%args)=@_;
 378
 379         cluck if !$args{"uri_as_in"} && ref $in;
 380         my $uri=in_to_uri_abs($in);
 381         if (uri_is_local($uri)) {
 382                 # Prefer the $uri values over "args_persistent" values.
 383                 $uri->query_form_hash({
 384                                 map({
 385                                         my $key=$_;
 386                                         my $val=$W->{"args"}{$key};
 387                                         (!defined $val ? () : ($key=>$val));
 388                                         } keys(%{$W->{"args_persistent"}})),
 389                                 %{$uri->query_form_hash()},
 390                                 });
 391                 }
 392         return $uri->abs(unparsed_uri()) if $W->{"args"}{"Wabs"} || $args{"abs"};
 393         return $uri->rel(unparsed_uri());
 394 }
 395
 396 sub path_abs_disk_register($)
 397 {
 398 my($path_abs_disk)=@_;
 399
 400         $W->{"path_abs_disk_register"}{$path_abs_disk}=1;
 401 }
 402
 403 # $args{"uri_as_in"}=1 to permit passing URI objects as: $in
 404 sub path_abs_disk($%)
 405 {
 406 my($in,%args)=@_;
 407
 408         cluck if !$args{"uri_as_in"} && ref $in;
 409         my $uri=in_to_uri_abs($in);
 410         cluck if !uri_is_local($uri);
 411         my $path=$uri->path();
 412         cluck "URI compatibility: ->path() not w/leading slash of URI \"$uri\"; path: $path" if $path!~m{^/};
 413         my $r=dir_top_abs_disk().$path;
 414         path_abs_disk_register $r if !defined $args{"register"} || $args{"register"};
 415         return $r;
 416 }
 417
 418 sub fatal (;$);
 419
 420 sub _args_check (%)
 421 {
 422 my(%tmpl)=@_;
 423
 424         while (my($name,$regex)=each(%tmpl)) {
 425                 my $name_html="Parameter <span class=\"quote\">".escapeHTML($name)."</span>";
 426                 $W->{"args"}{$name}="" if !defined $W->{"args"}{$name};
 427                 $W->{"args"}{$name}=[ $W->{"args"}{$name} ] if !ref $W->{"args"}{$name} && ref $regex;
 428                 fatal "$name_html passed as multivar although singlevar expected"
 429                                 if ref $W->{"args"}{$name} && !ref $regex;
 430                 $regex=$regex->[0] if ref $regex;
 431                 for my $val (!ref $W->{"args"}{$name} ? $W->{"args"}{$name} : @{$W->{"args"}{$name}}) {
 432                         $val="" if !defined $val;
 433                         fatal "$name_html <span class=\"quote\">".escapeHTML($val)."</span>"
 434                                                         ." does not match the required regex <span class=\"quote\">".escapeHTML($regex)."</span> "
 435                                         if $regex ne "" && $val!~/$regex/;
 436                         }
 437                 }
 438 }
 439
 440 sub vskip (;$)
 441 {
 442 my($height)=@_;
 443
 444         return '<p'.(!defined $height ? "" : ' style="height: '.$height.';"').'>&nbsp;</p>'."\n";
 445 }
 446
 447 sub fatal (;$)
 448 {
 449 my($msg)=@_;
 450
 451         $msg="UNKNOWN" if !$msg;
 452         cluck "FATAL: $msg";
 453
 454         # Do not send it unconditionally.
 455         # The intial duplicated '<?xml...' crashes Gecko parser.
 456         $W->{"heading_done"}=0 if $W->{"header_only"};
 457         # Do not send it unconditionally.
 458         # Prevents warn: Headers already sent
 459         if (!$W->{"heading_done"}) {
 460                 $W->{"indexme"}=0;      # For the case no heading was sent yet.
 461                 $W->{"header_only"}=0;  # assurance for &heading
 462                 My::Web->heading();
 463                 }
 464         Wprint "\n".vskip("3ex")."<hr /><h1 class=\"error\">FATAL ERROR: $msg!</h1>\n"
 465                         ."<p>You can report this problem's details to"
 466                         ." ".a_href("mailto:".$W->{"admin_mail"},"admin of this website").".</p>\n";
 467         footer();
 468 }
 469
 470 sub footer (;$)
 471 {
 472         exit 1 if $W->{"footer_passed"}++;      # deadlock prevention:
 473
 474         Wprint vskip if $W->{"footer_delimit"};
 475
 476         do { Wprint $_ if $_; } for $W->{"footing_delimit"};
 477
 478         Wprint "<hr />\n" if $W->{"footer"};
 479
 480         my $packages_used=$packages_used_array{$W->{"__PACKAGE__"}};
 481
 482         if ($W->{"footer_ids"}) {
 483                 Wprint '<p class="cvs-id">';
 484                 Wprint join("<br />\n",map({ my $package=$_;
 485                         my $cvs_id=(eval('$'.$package."::CVS_ID")
 486 #                                       || $package     # debug
 487                                         );
 488                         if (!$cvs_id) {
 489                                 ();
 490                                 }
 491                         else {
 492                                 $cvs_id='$'.$cvs_id.'$';        # Eaten by 'q' operator.
 493                                 my @cvs_id_split=split / +/,$cvs_id;
 494                                 if (@cvs_id_split==8) {
 495                                         my $file=$package;
 496                                         $file=~s#::#/#g;
 497                                         my $ext;
 498                                         my @tried;
 499                                         for (qw(.pm)) {
 500                                                 $ext=$_;
 501                                                 my $path_abs_disk=path_abs_disk("/$file$ext");
 502                                                 push @tried,$path_abs_disk;
 503                                                 last if -r $path_abs_disk;
 504                                                 cluck "Class file $file not found; tried: ".join(" ",@tried) if !$ext;
 505                                                 }
 506                                         $file.=$ext;
 507                                         $cvs_id_split[2]=""
 508                                                         .a_href((map({ my $s=$_; $s=~s#/viewcvs/#$&~checkout~/#; $s; } $W->{"viewcvs"}))[0]."$file?rev=".$cvs_id_split[2],
 509                                                                         $cvs_id_split[2]);
 510                                         $cvs_id_split[1]=a_href($W->{"viewcvs"}.$file,
 511                                                         ($package!~/^Apache2::/ ? $package : $cvs_id_split[1]));
 512                                         $cvs_id_split[5]=&{$W->{"cvs_id_author_sub"}}($cvs_id_split[5]);
 513                                         }
 514                                 join " ",@cvs_id_split;
 515                                 }
 516                         } @$packages_used));
 517                 Wprint "</p>\n";
 518                 }
 519
 520         for my $package (@$packages_used) {
 521                 my $cvs_id=(eval('$'.$package."::CVS_ID")
 522 #                               || $package     # debug
 523                                 );
 524                 Wprint '<!-- '.$package.' - $'.$cvs_id.'$ -->'."\n" if $cvs_id;
 525                 }
 526
 527         do { Wprint $_ if $_; } for $W->{"footing"};
 528
 529         Wprint "</body></html>\n";
 530         exit 0;
 531 }
 532
 533 # Existing entries are overwritten.
 534 sub header(%)
 535 {
 536 my(%pairs)=@_;
 537
 538         while (my($key,$val)=each(%pairs)) {
 539                 do { cluck "Headers already sent"; next; } if $W->{"heading_done"};
 540                 $W->{"r"}->headers_out()->set($key,$val);
 541                 }
 542 }
 543
 544 sub size_display ($)
 545 {
 546 my($size)=@_;
 547
 548            if ($size<4096)
 549                 {}
 550         elsif ($size<1024*1024)
 551                 { $size=sprintf "%.1fK",$size/1024; }
 552         else
 553                 { $size=sprintf "%.1fM",$size/1024/1024; }
 554         $size.="B";
 555         return $size;
 556 }
 557
 558 sub uri_is_local($)
 559 {
 560 my($in)=@_;
 561
 562         my $uri_rel=in_to_uri_abs($in)->rel(unparsed_uri());
 563         # Do not: defined $uri_rel->("userinfo"|"host"|"port")();
 564         # as they fail to be called for schemes not supporting them.
 565         return 0 if $uri_rel->scheme();
 566         return 0 if $uri_rel->authority();
 567         return 1;
 568 }
 569
 570 # &path_web still may be required for &uri_escaped !
 571 sub uri_escaped($)
 572 {
 573 my($uri)=@_;
 574
 575         cluck if !ref $uri;
 576         my $urient=escapeHTML($uri);
 577         return $uri    if $uri eq $urient;
 578         request_check();
 579         return $urient if uri_is_local $uri;
 580         return $uri    if defined $W->{"have_ent"} && !$W->{"have_ent"};        # non-ent client
 581         return $urient if $W->{"have_ent"};     # ent client
 582         # Unknown client, &escapeHTML should not be needed here:
 583         return escapeHTML(path_web('/My/Redirect.pm?location='.uri_escape($uri->abs(unparsed_uri()))));
 584 }
 585
 586 our $a_href_inhibited;
 587 sub a_href($;$%)
 588 {
 589 my($in,$contents,%args)=@_;
 590
 591         request_check();
 592         do { $$_=1 if !defined $$_; } for (\$args{"size"});
 593         if (!defined $contents) {
 594                 $contents=$in;
 595                 $contents=File::Basename::basename($contents) if $args{"basename"};
 596                 $contents=escapeHTML($contents);
 597                 }
 598         $contents=~s#<a\b[^>]*>##gi;
 599         $contents=~s#</a>##gi;
 600         return $contents if $a_href_inhibited;
 601
 602         my $path_web=path_web $in,%args;
 603         my $r="";
 604         $r.='<a href="';
 605         $r.=uri_escaped $path_web;
 606         $r.='"';
 607         do { $r.=" $_" if $_; } for ($args{"attr"});
 608         $r.='>'.$contents.'</a>';
 609         if ($args{"size"} && uri_is_local($in) && ($args{"size"}>=2 || $in=~/[.](?:gz|Z|rpm|zip|deb|lha)/)) {   # Downloadable?
 610                 my $path_abs_disk=path_abs_disk $in,%args;
 611                 cluck "File not readable: $path_abs_disk" if !-r $path_abs_disk;
 612                 $r.='&nbsp;('.size_display((stat($path_abs_disk))[7]).')';
 613                 }
 614         return $r;
 615 }
 616
 617 sub a_href_inhibit($$;@)
 618 {
 619 my($self,$sub,@sub_args)=@_;
 620
 621         local $a_href_inhibited=1;
 622         return &{$sub}(@sub_args);
 623 }
 624
 625 sub input_hidden_persistents()
 626 {
 627         request_check();
 628         return join("",map({
 629                 my $key=$_;
 630                 my $val=$W->{"args"}{$key};
 631                 (!defined $val ? () : '<input type="hidden"'
 632                                 .' name="'.escapeHTML($key).'"'
 633                                 .' value="'.escapeHTML($val).'"'
 634                                 .' />'."\n");
 635                 } (keys(%{$W->{"args_persistent"}}))));
 636 }
 637
 638 sub http_moved($$;$)
 639 {
 640 my($self,$url,$status)=@_;
 641
 642         $url=path_web($url,"abs"=>1);
 643         $status||=HTTP_MOVED_TEMPORARILY;
 644         $W->{"r"}->status($status);
 645         $W->{"r"}->headers_out()->{"Location"}=$url;
 646         $W->{"header_only"}=1;
 647         My::Web->heading();
 648         exit;
 649         die "NOTREACHED";
 650 }
 651
 652 sub remote_ip ()
 653 {
 654         # Do not: PerlModule                 Apache2::ForwardedFor
 655         #         PerlPostReadRequestHandler Apache2::ForwardedFor
 656         # As 'Apache2::ForwardedFor' takes the first of $ENV{"HTTP_X_FORWARDED_FOR"}
 657         # while the contents is '127.0.0.1, 213.220.195.171' if client has its own proxy.
 658         # We must take the last item ourselves.
 659         # Be VERY sure you always retrieve all the headers unconditionally to hit: My::Hash::RecordKeys
 660         my $x_forwarded_for=$W->{"headers_in"}{"X-Forwarded-For"};
 661         $x_forwarded_for=~s/^.*,\s*// if $x_forwarded_for;
 662         my $remote_ip=$W->{"headers_in"}{"_remote_ip"};
 663         my $r;
 664         $r||=$x_forwarded_for;
 665         $r||=$remote_ip;
 666         return $r;
 667 }
 668
 669 # $url={"JP"=>"http://specific",...};
 670 # $url={""=>"http://default",...};
 671 sub a_href_cc($$;%)
 672 {
 673 my($url,$contents,%args)=@_;
 674
 675         # A bit ineffective but we must process all the possibilities to get stable 'headers_in' hits!
 676         my %map=map(($_=>a_href($url->{$_},$contents,%args)),keys(%$url));
 677         my $cc;
 678         $cc||=Geo::IP->new()->country_code_by_addr(remote_ip()) if $have_Geo_IP;
 679         $cc||="";
 680         my $r=$map{$cc};
 681         return $r if $r;
 682         return $contents;
 683 }
 684
 685 sub make ($)
 686 {
 687 my($cmd)=@_;
 688
 689         # FIXME: &alarm, --timeout is now infinite.
 690         # FIXME: Try to remove bash(1).
 691         # FIXME: Use: @PATH_FLOCK@
 692         my @argv=('flock',dir_top_abs_disk(),'bash','-c',$cmd.' >&2');
 693         print STDERR join(" ","SPAWN:",@argv)."\n";
 694         system @argv;
 695 }
 696
 697 sub make_file($$)
 698 {
 699 my($self,$file)=@_;
 700
 701         cluck "Pathname not absolute: $file" if $file!~m{^/};
 702         return if -f $file;
 703         # TODO: Somehow quickly check dependencies?
 704         return make('make -s --no-print-directory'
 705                                         .' -C '."'".File::Basename::dirname($file)."' '".File::Basename::basename($file)."'");
 706 }
 707
 708 sub img_size ($$)
 709 {
 710 my($width,$height)=@_;
 711
 712         cluck if !defined $width || !defined $height;
 713         return ($W->{"have_style"} ? "style=\"border:0;width:${width}px;height:${height}px\"" : "border=\"0\"")
 714                         ." width=\"$width\" height=\"$height\"";
 715 }
 716
 717 sub negotiate_variant (%)
 718 {
 719 my(%args)=@_;
 720
 721         my @fields=("id","qs","content-type","encoding","charset","lang","size");
 722         return [ map(($args{$_}),@fields) ];
 723 }
 724
 725 # Input: $self is required!
 726 # Input: Put the fallback variant as the first one.
 727 # Returns: always only scalar!
 728 sub Negotiate_choose($$)
 729 {
 730 my($self,$variants)=@_;
 731
 732         # Limit these entries to generate proper 'Vary' header.
 733         my %hash=(map(($_=>$W->{"headers_in"}{$_}),qw(
 734                         Accept
 735                         Accept-Charset
 736                         Accept-Encoding
 737                         Accept-Language
 738                         )));
 739         my $best=HTTP::Negotiate::choose($variants,
 740                         # Do not: $W->{"r"}
 741                         # to prevent: Can't locate object method "scan" via package "Apache2::RequestRec" at HTTP/Negotiate.pm line 84.
 742                         # Do not: $W->{"r"}->headers_in()
 743                         # to prevent: Can't locate object method "scan" via package "APR::Table" at HTTP/Negotiate.pm line 84.
 744                         # Do not: HTTP::Headers->new($W->{"r"}->headers_in());
 745                         # to prevent empty result or even: Odd number of elements in anonymous hash
 746                         HTTP::Headers->new(%hash));
 747         $best||=$variants->[0][0];      # $variants->[0]{"id"}; &HTTP::Negotiate::choose failed?
 748         return $best;
 749 }
 750
 751 my @img_variants=(
 752                 { "id"=>"png","qs"=>0.9,"content-type"=>"image/png" },
 753                 { "id"=>"gif","qs"=>0.7,"content-type"=>"image/gif" },
 754                 );
 755 my $img_variants_re='[.](?:'.join('|',"jpeg",map(($_->{"id"}),@img_variants)).')$';
 756
 757 # Returns: ($path_web,$path_abs_disk)
 758 # URI path segments support ignored here. Where it is used? (';' path segment options)
 759 sub _img_src($%)
 760 {
 761 my($in,%args)=@_;
 762
 763         cluck if !uri_is_local $in;
 764         my $uri=in_to_uri_abs $in;
 765         my $path_abs_disk=path_abs_disk $uri,%args,"uri_as_in"=>1,"register"=>0;
 766
 767         # Known image extension?
 768         return path_web($uri,%args,"uri_as_in"=>1),$path_abs_disk if $uri->path()=~m#$img_variants_re#o;
 769
 770         my @nego_variants;
 771         for my $var (@img_variants) {
 772                 my $path_abs_disk_variant=$path_abs_disk.".".$var->{"id"};
 773                 path_abs_disk_register($path_abs_disk_variant);
 774                 __PACKAGE__->make_file($path_abs_disk_variant);
 775                 push @nego_variants,negotiate_variant(
 776                                 %$var,
 777                                 "size"=>(stat $path_abs_disk_variant)[7],
 778                                 );
 779                 }
 780         my $ext=__PACKAGE__->Negotiate_choose(\@nego_variants);
 781
 782         $uri->path($uri->path().".$ext");
 783         return path_web($uri,%args,"uri_as_in"=>1),path_abs_disk($uri,%args,"uri_as_in"=>1);
 784 }
 785
 786 # $args{"attr"}
 787 sub img ($$%)
 788 {
 789 my($in,$alt,%args)=@_;
 790
 791         request_check();
 792         my($path_web,$path_abs_disk)=_img_src($in,%args);
 793         my($width,$height)=Image::Size::imgsize($path_abs_disk);
 794         $alt=~s/<[^>]*>//g;
 795         $alt=escapeHTML($alt);
 796         my $content="<img src=\"".uri_escaped($path_web)."\" alt=\"$alt\" title=\"$alt\" ".img_size($width,$height)
 797                         .(!$args{"attr"} ? "" : " ".$args{"attr"})." />";
 798         do { return a_href((_img_src($_))[0],$content,"uri_as_in"=>1) if $_; } for $args{"a_href_img"};
 799         do { return a_href $_,$content if $_; } for $args{"a_href"};
 800         return $content;
 801 }
 802
 803 sub centerimg
 804 {
 805         my $r="";
 806         $r.='<table border="0" width="100%"><tr>'."\n";
 807         @_=( [@_] ) if !ref $_[0];
 808         for (@_) {
 809                 $r.="\t".'<td align="center">'.&{\&img}(@$_).'</td>'."\n";
 810                 }
 811         $r.='</tr></table>'."\n";
 812         return $r;
 813 }
 814
 815 sub rightimg
 816 {
 817 my($text,@args_img)=@_;
 818
 819         # FIXME: Workaround bug of 'Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)':
 820         #        <col width="@{[ (!$W->{"browser"}->ie() ? "1*" : "90%" ) ]}" />
 821         #        <col width="@{[ (!$W->{"browser"}->ie() ? "0*" : "10%" ) ]}" />
 822         # causes whole invisible projects in: Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.7.10) Gecko/20050719 Galeon/1.3.21
 823         return <<"HERE";
 824 <table border="0" width="100%">
 825         <tr>
 826                 <td align="left">
 827                         @{[ $text ]}
 828                 </td>
 829                 <td align="right">
 830                         @{[ &{\&img}(@args_img) ]}
 831                 </td>
 832         </tr>
 833 </table>
 834 HERE
 835 }
 836
 837 sub readfile($$)
 838 {
 839 my($class,$filename)=@_;
 840
 841         local *F;
 842         open F,$filename or cluck "Cannot open \"$filename\": $!";
 843         my $F=do { local $/=undef(); <F>; };
 844         close F or cluck "Cannot close \"$filename\": $!";
 845         return $F;
 846 }
 847
 848 sub _no_cache($)
 849 {
 850 my($self)=@_;
 851
 852         header("Expires"=>HTTP::Date::time2str(1000000000));    # date in the past
 853         header("Last-Modified"=>HTTP::Date::time2str());        # always modified
 854         header("Cache-Control"=>join(", ",
 855                         "no-cache",
 856                         "no-store",
 857                         "must-revalidate",
 858                         "max-age=0",
 859                         "pre-check=0",  # MSIE
 860                         "post-check=0", # MSIE
 861                         ));     # HTTP/1.1
 862         header("Pragma"=>"no-cache");   # HTTP/1.0
 863         header("Vary"=>"*");    # content may ba based on unpredictable sources
 864 }
 865
 866 sub headers_in_filtered(@)
 867 {
 868 my(@keys)=@_;
 869
 870         return map(($_=>$W->{"headers_in"}{$_}),@keys);
 871 }
 872
 873 our %uri_args_frozen_to_headers_in_keys;
 874 our %uri_args_headers_in_frozen_to_headers_out;
 875
 876 sub uri_args_headers_in_frozen_get($)
 877 {
 878 my($headers_in_keys_arrayref)=@_;
 879
 880         my %uri_args_headers_in_hash=(
 881                 "uri_args_frozen"=>$W->{"uri_args_frozen"},
 882                 "headers_in"=>{ headers_in_filtered(@$headers_in_keys_arrayref) },
 883                 );
 884         return do { local $Storable::canonical=1; Storable::freeze(\%uri_args_headers_in_hash); };
 885 }
 886
 887 sub cache_output_filter($)
 888 {
 889 my($f)=@_;
 890
 891         while ($f->read(my $text,0x400)) {
 892                 cluck "utf-8 untested" if Encode::is_utf8($text);       # Possible here at all?
 893                 $f->print($text);
 894                 $W->{"digest-md5"}->add($text);
 895                 }
 896         return OK;
 897 }
 898
 899 sub cache_start()
 900 {
 901         if (!$W->{"http_safe"}) {
 902                 __PACKAGE__->_no_cache();
 903                 return;
 904                 }
 905
 906         {
 907                 # &Wrequire it here even if it will not be later used; to be stable!
 908                 Wrequire 'My::Hash::RestrictTo';
 909                 my %uri_args_hash=(
 910                         "uri"=>"http://".$W->{"web_hostname"}."/".$W->{"r"}->uri(),
 911                         "args"=>$W->{"args_orig_array"},
 912                         );
 913                 $W->{"uri_args_frozen"}=do { local $Storable::canonical=1; Storable::freeze(\%uri_args_hash); };
 914                 last if !(my $headers_in_keys_arrayref=$uri_args_frozen_to_headers_in_keys{$W->{"uri_args_frozen"}});
 915
 916                 # Protection to be sure we are stable:
 917                 $W->{"headers_in"}=My::Hash::RestrictTo->new($W->{"headers_in"},@$headers_in_keys_arrayref);
 918
 919                 $W->{"uri_args_headers_in_frozen"}=uri_args_headers_in_frozen_get($headers_in_keys_arrayref);
 920                 last if !(my $headers_out_hashref=$uri_args_headers_in_frozen_to_headers_out{$W->{"uri_args_headers_in_frozen"}});
 921                 header(%$headers_out_hashref);
 922                 my $status;
 923                 {
 924                         # &meets_conditions will always deny the attempt if !2xx status().
 925                         # At least ap_read_request() sets: r->status=HTTP_REQUEST_TIME_OUT;     /* Until we get a request */
 926                         my $status_old=$W->{"r"}->status();
 927                         $W->{"r"}->status(HTTP_OK);
 928                         # Update httpd's 'r->mtime' as the header "Last-Modified" is just not enough for ap_meets_conditions():
 929                         # &update_mtime() argument is really in _secs_, not in _msecs_ as the docs claim.
 930                         # Be aware '*1000000' would overflow Perl integer anyway.
 931                         # &set_last_modified would also override the "Last-Modified" headers_out!
 932                         # &mtime may exist but somehow does not work.
 933                         $W->{"r"}->update_mtime(HTTP::Date::str2time($headers_out_hashref->{"Last-Modified"}));
 934                         $status=$W->{"r"}->meets_conditions();
 935                         $W->{"r"}->status($status_old);
 936                         }
 937                 last if OK==$status;
 938                 $W->{"r"}->status($status);
 939                 exit 0;
 940                 die "NOTREACHED";
 941                 }
 942
 943         $W->{"digest-md5"}=Digest::MD5->new();
 944         $W->{"cache_active"}=1;
 945         $W->{"r"}->add_output_filter(\&cache_output_filter);
 946 }
 947
 948 sub cache_finish_last_modified()
 949 {
 950         cluck "Not yet done now? W __PACKAGE__: ".$W->{"__PACKAGE__"}
 951                         if !$packages_used_hash{$W->{"__PACKAGE__"}}{"_done"};
 952         for my $package_orig (@{$packages_used_array{$W->{"__PACKAGE__"}}}) {
 953                 local $_=$package_orig.".pm";
 954                 s{::}{/}g;
 955                 path_abs_disk "/$_","register"=>1;
 956                 }
 957         my $mtime_newest;
 958         for my $path_abs_disk (keys(%{$W->{"path_abs_disk_register"}})) {
 959                 my $mtime=(stat $path_abs_disk)[9];
 960                 do { cluck "No mtime for: $path_abs_disk"; next; } if !$mtime;
 961                 $mtime_newest=$mtime if !$mtime_newest || $mtime_newest<$mtime;
 962                 }
 963         cluck "No mtime_newest found for the current W __PACKAGE__: ".$W->{"__PACKAGE__"}
 964                         if !$mtime_newest;
 965         return HTTP::Date::time2str($mtime_newest);
 966 }
 967
 968
 969 sub cache_finish()
 970 {
 971         # Do not: return if !$W->{"uri_args_frozen"};
 972         # as we may have just gave 304 and 'exit 0;' without starting the caching.
 973         return if !$W->{"cache_active"};
 974
 975         # Fill-in/check: %uri_args_frozen_to_headers_in_keys
 976         my $headers_in_keys_stored_arrayref_ref=\$uri_args_frozen_to_headers_in_keys{$W->{"uri_args_frozen"}};
 977         my @headers_in_keys=tied(%{$W->{"headers_in_RecordKeys"}})->accessed();
 978         if (!$$headers_in_keys_stored_arrayref_ref
 979                         || !Data::Compare::Compare(\@headers_in_keys,$$headers_in_keys_stored_arrayref_ref)) {
 980                 cluck "Non-matching generated 'headers_in_keys' per 'uri_args_frozen' key:\n"
 981                                                 .Dumper(\@headers_in_keys,$$headers_in_keys_stored_arrayref_ref)
 982                                 if $$headers_in_keys_stored_arrayref_ref;
 983                 # Build or possibly prevent such further warn dupes:
 984                 $$headers_in_keys_stored_arrayref_ref=\@headers_in_keys;
 985                 # Build or regenerate as obsoleted now:
 986                 $W->{"uri_args_headers_in_frozen"}=uri_args_headers_in_frozen_get(\@headers_in_keys);
 987                 }
 988
 989         # Prepare 'headers_out' for the future reusal:
 990         my %headers_out;
 991         $headers_out{"Content-MD5"}=$W->{"digest-md5"}->b64digest();
 992         # In fact we could also use MD5 for ETag as if we know ETag we also know MD5.
 993         # But this way we do not need to calculate MD5 and we still can provide such ETag. So.
 994         # $W->{"r"}->set_etag() ?
 995         $headers_out{"ETag"}='"'.Digest::MD5::md5_base64($W->{"uri_args_headers_in_frozen"}).'"';
 996         # $W->{"r"}->set_content_length() ?
 997         $headers_out{"Content-Length"}=$W->{"r"}->bytes_sent();
 998         my %Vary=map(($_=>1),(@headers_in_keys));
 999         for (keys(%Vary)) {
1000                 next if !/^_/;
1001                 $Vary{"*"}=1;
1002                 delete $Vary{$_};
1003                 }
1004         %Vary=("*"=>1) if $Vary{"*"};
1005         $headers_out{"Vary"}=join(", ",sort keys(%Vary));
1006         # $W->{"r"}->set_last_modified() ?
1007         $headers_out{"Last-Modified"}=cache_finish_last_modified();
1008
1009         # Fill-in/check: %uri_args_headers_in_frozen_to_headers_out
1010         my $headers_out_stored_hashref_ref=\$uri_args_headers_in_frozen_to_headers_out{$W->{"uri_args_headers_in_frozen"}};
1011         if (!$$headers_out_stored_hashref_ref
1012                         || !Data::Compare::Compare(\%headers_out,$$headers_out_stored_hashref_ref)) {
1013                 cluck "Non-matching generated 'headers_out' per 'uri_args_headers_in_frozen' key:\n"
1014                                                 .Dumper(\%headers_out,$$headers_out_stored_hashref_ref)
1015                                 if $$headers_out_stored_hashref_ref;
1016                 # Build or possibly prevent such further warn dupes:
1017                 $$headers_out_stored_hashref_ref=\%headers_out;
1018                 }
1019
1020 ###print STDERR Dumper(\%uri_args_frozen_to_headers_in_keys,\%uri_args_headers_in_frozen_to_headers_out);
1021 }
1022
1023 sub heading()
1024 {
1025 my($class)=@_;
1026
1027         if (!$W->{"header_only"}) {
1028                 header("Content-Style-Type"=>"text/css");
1029                 header("Content-Script-Type"=>"text/javascript");
1030                 # $W->{"r"}->content_languages() ?
1031                 do { header("Content-Language"=>$_) if $_; } for $W->{"language"};
1032                 }
1033         # TODO: Support also: private
1034         header("Cache-Control"=>"public");      # HTTP/1.1
1035
1036         # $ENV{"CLIENT_CHARSET"} ignored (mod_czech support dropped!)
1037         my $client_charset=$W->{"force_charset"} || "us-ascii";
1038
1039         # Workaround bug
1040         #   https://bugzilla.mozilla.org/show_bug.cgi?id=120556
1041         # of at least
1042         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
1043         my $mime;
1044         # http://validator.w3.org/ does not send ANY "Accept" headers!
1045         $mime||="application/xhtml+xml" if 1
1046                         && !$W->{"headers_in"}{"Accept"}
1047                         && ($W->{"headers_in"}{"User-Agent"}||"")=~m{^W3C_Validator/}i;
1048         $mime||=$class->Negotiate_choose([
1049                         # Put the fallback variant as the first one.
1050                         # Rate both variants the same to prefer "text/html" for undecided clients.
1051                         # At least
1052                         #   Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8b) Gecko/20050217
1053                         # prefers "application/xhtml+xml" over "text/html" itself:
1054                         #   text/xml,application/xml,application/xhtml+xml,text/html;q=0.9,text/plain;q=0.8,image/png,*/*;q=0.5
1055                         negotiate_variant(
1056                                         "id"=>"text/html",
1057                                         "content-type"=>"text/html",
1058                                         "qs"=>0.6,
1059                                         "charset"=>$client_charset,
1060                                         "lang"=>$W->{"language"},
1061                                         ),
1062                         negotiate_variant(
1063                                         "id"=>"application/xhtml+xml",
1064                                         "content-type"=>"application/xhtml+xml",
1065                                         "qs"=>0.6,
1066                                         "charset"=>$client_charset,
1067                                         "lang"=>$W->{"language"},
1068                                         ),
1069                         # application/xml ?
1070                         # text/xml ?
1071                         ]);
1072         # mod_perl doc: If you set this header via the headers_out table directly, it
1073         #               will be ignored by Apache. So do not do that.
1074         $W->{"r"}->content_type("$mime; charset=$client_charset");
1075
1076         cache_start();
1077         return if $W->{"header_only"};
1078         # We still can append headers before we put out some text.
1079         # FIXME: It is not clean to still append them without overwriting.
1080         return if $W->{"heading_done"}++;
1081
1082         Wprint '<?xml version="1.0" encoding="'.$client_charset.'"?>'."\n" if $mime=~m{^application/\w+[+]xml$};
1083         return if $W->{"xml_header_only"};
1084         Wprint '<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN" "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">'."\n";
1085         Wprint '<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="'.$W->{"language"}.'">'."\n";
1086         my $title=$W->{"title_prefix"}.join("",map({ ': '.$_; } ($W->{"title"} || ())));
1087         # Do not: cluck if $title=~/[<>]/;
1088         # as it is not solved just by: &a_href_inhibit
1089         # as sometimes titles use also: <i>...</i>
1090         $title=~s#<[^>]*>##g;
1091         Wprint "<head>";
1092         Wprint "<title>$title</title>\n";
1093         if ($W->{"have_css"}) {
1094                 # Everything can get overriden later.
1095                 for my $css ("/My/Web.css",map((!$_ ? () : ("ARRAY" ne ref($_) ? $_ : @$_)),$W->{"css_push"})) {
1096                         Wprint <<"HERE";
1097 <link rel="stylesheet" type="text/css" href="@{[ uri_escaped(path_web $css) ]}" />
1098 HERE
1099                         }
1100                 if ($W->{"css_inherit"}) {
1101                         Wprint <<"HERE";
1102 <script type="text/javascript" src="@{[ uri_escaped(path_web('/My/css_inherit.js')) ]}" />
1103 HERE
1104                         }
1105                 }
1106         Wprint '<meta name="robots" content="'.($W->{"indexme"} ? "" : "no" ).'index,follow" />'."\n";
1107         Wprint $W->{"head"};
1108         for my $type (qw(prev next index contents start up)) {
1109                 do { Wprint '<link rel="'.$type.'" href="'.uri_escaped(path_web $_).'" />'."\n" if $_; }
1110                                 for ($W->{"rel_$type"});
1111                 }
1112         Wprint "</head><body";
1113 #       Wprint ' bgcolor="black" text="white" link="aqua" vlink="teal"'
1114 #                       if $W->{"browser"}->netscape() && (!$W->{"browser"}->major() || $W->{"browser"}->major()<=4);
1115         Wprint $W->{"body_attr"};
1116         Wprint ">\n";
1117
1118         do { Wprint $_ if $_; } for $W->{"heading"};
1119 }
1120
1121 BEGIN {
1122         delete $W->{"__My::Web_init"};
1123         }
1124
1125 1;