configure.ac

   1 # $Id$
   2 # Source file to generate "./configure" to prepare package for compilation
   3 # Copyright (C) 2002-2003 Jan Kratochvil <project-captive@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 AC_INIT(src/libcaptive/Makefile-libcaptive.am)
  20 dnl 2.53 for AM_GLIB_GNU_GETTEXT:
  21 AC_PREREQ(2.53)
  22 dnl Not yet present in: Red Hat autoconf-2.57-3
  23 dnl AC_CONFIG_MACRO_DIR(macros)
  24 AM_INIT_AUTOMAKE(captive,1.1.6cvs)
  25 AM_CONFIG_HEADER(config.h)
  26 AM_MAINTAINER_MODE
  27 dnl Call AC_PROG_CC before AC_ISC_POSIX.
  28 AC_PROG_CC(gcc3 gcc-3.0 gcc cc)
  29 AC_TRY_CPP([
  30 #if __GNUC__ >= 3
  31 #else
  32 #error "GCC version 3.0+ required at least for ReactOS anonymous unions"
  33 #endif
  34 ],,[AC_MSG_ERROR([Captive requires GCC version 3.0+.])])
  35 dnl Prevent "AC_TRY_COMPILE was called before AC_ISC_POSIX":
  36 AC_ISC_POSIX
  37 AC_SYS_LARGEFILE
  38 AM_PROG_AS
  39 AM_DISABLE_STATIC
  40 AM_ENABLE_SHARED
  41 AM_PROG_LIBTOOL
  42
  43 dnl Workaround for autoconf-2.57:
  44 m4_pattern_allow([AC_MSG_WARN])
  45 m4_pattern_allow([AC_CHECK_LIB])
  46 m4_pattern_allow([AC_CHECK_HEADERS])
  47
  48 dnl gettext localization.
  49 dnl Use simpler AM_GLIB_GNU_GETTEXT instead of AM_GNU_GETTEXT
  50 dnl as we depend on glib and glib requires system installed gettext anyway.
  51 dnl http://lists.gnome.org/archives/gtk-devel-list/2003-April/msg00066.html
  52 dnl Special 'GETTEXT_PACKAGE' is required by glib gettext.
  53 ALL_LINGUAS="cs"
  54 GETTEXT_PACKAGE="$PACKAGE"
  55 AC_SUBST(GETTEXT_PACKAGE)
  56 AM_GLIB_GNU_GETTEXT
  57
  58 GTK_DOC_CHECK
  59 dnl AM_CONDITIONAL needs to be here explicitely for doc/apiref/Makefile rebuild
  60 AM_CONDITIONAL(ENABLE_GTK_DOC,[test x$enable_gtk_doc = xyes])
  61 AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL,[test -n "$LIBTOOL"])
  62
  63 dnl Do not discard 'CFLAGS' settings as they may have been passed us by rpmbuild(8)
  64
  65 dnl Define MAINTAINER_MODE in config.h.
  66 if test "$USE_MAINTAINER_MODE" = "yes";then
  67         AC_DEFINE(MAINTAINER_MODE,,[Turn even some software behaviour according to MAINTAINER_MODE.])
  68         CFLAGS="$CFLAGS -ggdb3 -Wall -Wstrict-prototypes -Wsign-compare"  ## FIXME: fix all sources: -Wsign-compare
  69         fi
  70 dnl Some Makefiles use additional tests etc.
  71 AM_CONDITIONAL(MAINTAINER_MODE,[test "$USE_MAINTAINER_MODE" = "yes"])
  72
  73
  74 AC_ARG_ENABLE(man-pages,
  75                 [  --enable-man-pages=no/yes/auto   pod2man(1) required for man pages (def.=yes)],,enable_man_pages=yes)
  76 AC_ARG_ENABLE(sbin-mountdir,
  77                 [  --enable-sbin-mountdir=DIR       mount(8) 'mount.captive' directory (def.=/sbin)],,
  78                 [ enable_sbin_mountdir="/sbin" ])
  79 AC_ARG_ENABLE(sbin-mount-fs,
  80                 [  --enable-sbin-mount-fs=FS1:FS2   sbin-mount pre-installed symlinks (def.=ntfs:fastfat:cdfs:ext2fsd)],,
  81                 [ enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd" ])
  82 AC_ARG_WITH(initddir,
  83                 [  --with-initddir=DIR              directory for captive FUSE shutdown (def.=/etc/rc.d/init.d)],,with_initddir=/etc/rc.d/init.d)
  84 AC_ARG_ENABLE(sandbox-setuid,
  85                 [  --enable-sandbox-setuid=USER     non-privileged user  for captive-sandbox-server (def.=captive)],
  86                 [ CAPTIVE_SANDBOX_SETUID="$enableval" ],[ CAPTIVE_SANDBOX_SETUID="captive" ])
  87 AC_ARG_ENABLE(sandbox-setgid,
  88                 [  --enable-sandbox-setgid=GROUP    non-privileged group for captive-sandbox-server (def.=captive)],
  89                 [ CAPTIVE_SANDBOX_SETGID="$enableval" ],[ CAPTIVE_SANDBOX_SETGID="captive" ])
  90 AC_ARG_ENABLE(sandbox-chroot,
  91                 [  --enable-sandbox-chroot=DIR      root-owned directory for captive-sandbox-server (def.=/var/lib/captive)],
  92                 [ CAPTIVE_SANDBOX_CHROOT="$enableval" ],[ CAPTIVE_SANDBOX_CHROOT="/var/lib/captive" ])
  93 AC_ARG_ENABLE(bug-replay,
  94                 [  --enable-bug-replay=no/yes/auto  compile debugging tool (def.=auto)],,enable_bug_replay=auto)
  95 AC_ARG_ENABLE(lufs,
  96                 [  --enable-lufs=no/yes/auto        compile LUFS filesystem module - DEPRECATED (def.=no)],,enable_lufs=no)
  97 AC_ARG_ENABLE(fuse,
  98                 [  --enable-fuse=no/yes/auto        compile FUSE filesystem module (def.=auto)],,enable_fuse=auto)
  99 AC_ARG_ENABLE(install-pkg,
 100                 [  --enable-install-pkg=no/yes/auto compile installation utils (def.=auto)],,enable_install_pkg=auto)
 101 AC_ARG_ENABLE(standalone,
 102                 [  --enable-standalone=no/yes       provide initialization for static-build (def.=no)],,enable_standalone=no)
 103 AC_ARG_ENABLE(standalone-fonts,
 104                 [  --enable-standalone-fonts=DIR    provide bundled Gnome fonts in directory (def.=no)],,enable_standalone_fonts=no)
 105
 106
 107 # AC_ARG_ENABLE(sbin-mountdir,[--enable-sbin-mountdir=DIR],,[enable_sbin_mountdir="/sbin"])
 108 AM_CONDITIONAL(ENABLE_SBIN_MOUNT,[test "$enable_sbin_mount" != "no"])
 109 AC_SUBST(enable_sbin_mountdir)
 110
 111 # AC_ARG_ENABLE(sbin-mount-fs,[--enable-sbin-mount-fs=FS1:FS2],,[enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd"])
 112 AC_SUBST(enable_sbin_mount_fs)
 113
 114 # AC_ARG_ENABLE(sandbox-setuid,[--enable-sandbox-setuid=USER],,[CAPTIVE_SANDBOX_SETUID="captive"])
 115 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETUID,"$CAPTIVE_SANDBOX_SETUID",
 116                 [non-privileged user  for captive-sandbox-server])
 117 AC_SUBST(CAPTIVE_SANDBOX_SETUID)
 118
 119 # AC_ARG_ENABLE(sandbox-setgid,[--enable-sandbox-setgid=GROUP],,[CAPTIVE_SANDBOX_SETGID="captive"])
 120 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETGID,"$CAPTIVE_SANDBOX_SETGID",
 121                 [non-privileged group for captive-sandbox-server])
 122 AC_SUBST(CAPTIVE_SANDBOX_SETGID)
 123
 124 # AC_ARG_ENABLE(sandbox-chroot,[--enable-sandbox-chroot=DIR],,[CAPTIVE_SANDBOX_CHROOT="/var/lib/captive"])
 125 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_CHROOT,"$CAPTIVE_SANDBOX_CHROOT",
 126                 [root-owned directory for captive-sandbox-server])
 127 AC_SUBST(CAPTIVE_SANDBOX_CHROOT)
 128
 129 dnl Permit 'if NEVER' for Makefile.am-s; symbol 'FALSE' forbidden by automake
 130 AM_CONDITIONAL(NEVER,false)
 131
 132 PERL=
 133 AC_PATH_PROGS(PERL,perl5 perl)
 134 if test '!' -f ./src/libcaptive/ke/exports.c -a -z "$PERL";then
 135         AC_MSG_ERROR([perl(1) required as './src/libcaptive/ke/exports.c' is not found.])
 136 fi
 137 AM_CONDITIONAL(HAVE_PERL,test -n "$PERL")
 138
 139 POD2MAN=
 140 AC_PATH_PROGS(POD2MAN,pod2man)
 141 AM_CONDITIONAL(HAVE_POD2MAN,[ test -n "$POD2MAN" ])
 142 if test x$enable_man_pages = xyes;then
 143         if test -z "$POD2MAN";then
 144                 AC_MSG_ERROR([captive requires pod2man(1) for man pages; try --disable-man-pages.])
 145         fi
 146         if test -z "$PERL";then
 147                 AC_MSG_ERROR([captive requires perl(1) for man pages; try --disable-man-pages.])
 148         fi
 149 elif test x$enable_man_pages != xno;then
 150         if test -z "$POD2MAN";then
 151                 AC_MSG_WARN([captive requires pod2man(1) for man pages by --enable-man-pages; mans will not be installed.])
 152         fi
 153         if test -z "$PERL";then
 154                 AC_MSG_WARN([captive requires perl(1) for man pages by --enable-man-pages; mans will not be installed.])
 155         fi
 156 fi
 157 AM_CONDITIONAL(ENABLE_MAN_PAGES,[ test x$enable_man_pages != xno -a -n "$POD2MAN" -a -n "$PERL" ])
 158
 159 dnl Separate 'acconfig.h' is no longer recommended by autoconf
 160 AH_TOP([
 161 #ifndef _CAPTIVE_CONFIG_H
 162 #define _CAPTIVE_CONFIG_H 1
 163 ])
 164 AH_BOTTOM([
 165 /* Do not place any stuff to AH_TOP as some of its includes
 166  * would discard the effect of _FILE_OFFSET_BITS by AC_SYS_LARGEFILE.
 167  */
 168
 169 /* Supplemental definitions not possible in this file. */
 170 #include "captive/config2.h"
 171
 172 #endif /* !_CAPTIVE_CONFIG_H */
 173 ])
 174
 175 dnl Do not use PKG_CHECK_MODULES() as it would not set 'GLIB_GENMARSHAL' etc.
 176 AM_PATH_GLIB_2_0(,,[AC_MSG_ERROR([Captive requires glib-2.0 library.])],[gmodule gobject gthread])
 177 dnl Force glib for the whole package
 178 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 179 LIBS="$LIBS $GLIB_LIBS"
 180
 181 dnl popt
 182 AC_CHECK_LIB(popt,poptParseArgvString,[POPT_LIBS="-lpopt"],[AC_MSG_ERROR([Captive requires popt library.])])
 183 AC_SUBST(POPT_LIBS)
 184
 185 AC_ARG_WITH(readline,[  --with-readline=[no/yes/auto]   clients with line editing (def.=auto)],,with_readline=auto)
 186 AC_CHECK_HEADERS(readline/history.h)
 187 dnl Check for libraries, if needed by configuration options.
 188 if test "$with_readline" != "no"
 189 then
 190         if test -d "/usr/lib/termcap"
 191         then
 192                 READLINE_LDFLAGS="$READLINE_LDFLAGS -L/usr/lib/termcap"
 193         fi
 194         have_libreadline=false
 195         need_failed=""
 196         for need in "" termcap ncurses; do
 197                 if test "x$need" != "x"
 198                 then
 199                         captive_save_LIBS="$LIBS"
 200                         AC_CHECK_LIB($need,main,,
 201                                 [ need_failed="$need_failed $need"
 202                                 continue ]
 203                                 )
 204                         LIBS="$captive_save_LIBS"
 205                         lneed="-l$need"
 206                 else
 207                         lneed=""
 208                 fi
 209                 dnl Prevent AC_CHECK_LIB() here as it would _cache_ the value ignoring
 210                 dnl our ever-changing "additiona libraries" parameter
 211                 captive_save_LIBS="$LIBS"
 212                 LIBS="-lreadline $lneed $READLINE_LIBS"
 213                 AC_TRY_LINK(,[ main() ],
 214                         [ have_libreadline=true
 215                         READLINE_LIBS="$LIBS" ])
 216                 LIBS="$captive_save_LIBS"
 217                 if $have_libreadline
 218                 then
 219                         break
 220                 fi
 221         done
 222         if $have_libreadline
 223         then
 224                 AC_DEFINE(HAVE_LIBREADLINE,,[Use functions from libreadline?])
 225                 AC_CHECK_LIB(readline,add_history,
 226                         AC_DEFINE(HAVE_ADD_HISTORY,,[Use 'history' extension of libreadline?]),,
 227                         $READLINE_LIBS)
 228         else
 229                 for need in $need_failed; do
 230                         AC_MSG_WARN(captive recommends $need library as your readline library
 231                         probably needs it.)
 232                 done
 233                 if test "$with_readline" = "yes"
 234                 then
 235                         AC_MSG_ERROR([captive did not find the requested readline library for its client line editing capability.])
 236                 else
 237                         AC_MSG_WARN([captive recommends readline library for its client line editing capability.])
 238                 fi
 239         fi
 240 fi
 241 AC_SUBST(READLINE_LIBS)
 242 AC_SUBST(READLINE_LDFLAGS)
 243
 244 PKG_CHECK_MODULES(GNOME_VFS_MODULE,gnome-vfs-module-2.0)
 245 GNOME_VFS_MODULE_CFLAGS="$GNOME_VFS_MODULE_CFLAGS -DCAPTIVE_USE_GNOME_VFS_MODULE=1"
 246 AC_SUBST(GNOME_VFS_MODULE_CFLAGS)
 247 AC_SUBST(GNOME_VFS_MODULE_LIBS)
 248 PKG_CHECK_MODULES(GNOME_VFS,gnome-vfs-2.0)
 249 GNOME_VFS_CFLAGS="$GNOME_VFS_CFLAGS -DCAPTIVE_USE_GNOME_VFS=1"
 250 AC_SUBST(GNOME_VFS_CFLAGS)
 251 AC_SUBST(GNOME_VFS_LIBS)
 252
 253 # AC_ARG_ENABLE(bug-replay,[--enable-bug-replay=[no/yes/auto]],,enable_bug_replay=auto)
 254 dnl Check for 2.5.9 for: http://bugzilla.gnome.org/show_bug.cgi?id=117702
 255 dnl Check the version - impossible to reliably check the missing feature.
 256 PKG_CHECK_MODULES(LIBXML,libxml-2.0 >= 2.5.9,[ have_libxml_buffering=true ],[
 257         dnl Disable bug-replay(1) build if not met; --bug-pathname would be still OK.
 258         PKG_CHECK_MODULES(LIBXML,libxml-2.0,[ have_libxml_buffering=false ])
 259         ])
 260 dnl We also condition 'HAVE_LIBXML_XMLREADER_H' by 'HAVE_LIBXML_BUFFERING'
 261 dnl as we have no use for xmlreader without working libxml buffering of 2.5.9.
 262 AM_CONDITIONAL(ENABLE_BUG_REPLAY,[$have_libxml_buffering && test x$enable_bug_replay != xno])
 263 if $have_libxml_buffering;then
 264         AC_DEFINE(HAVE_LIBXML_BUFFERING,,[libxml2 correctly reads textnodes by its xmlTextReader.])
 265 else
 266         if test x$enable_bug_replay = xyes;then
 267                 AC_MSG_ERROR([captive require libxml2 at least 2.5.9 for --enable-bug-replay feature.])
 268         elif test x$enable_bug_replay != xno;then
 269                 AC_MSG_WARN([libxml2 at least 2.5.9 required --enable-bug-replay feature; disabled now.])
 270         fi
 271 fi
 272 AC_SUBST(LIBXML_CFLAGS)
 273 AC_SUBST(LIBXML_LIBS)
 274
 275 PKG_CHECK_MODULES(OPENSSL,openssl,,[
 276         dnl At least Debian-3.0r1 has openssl but without its .pc module.
 277         AC_CHECK_LIB(crypto,MD5,[
 278                 OPENSSL_CFLAGS=""
 279                 OPENSSL_LIBS="-lcrypto"
 280                 ],[AC_MSG_ERROR([Captive requires crypto library (of openssl).])])
 281         ])
 282 AC_SUBST(OPENSSL_CFLAGS)
 283 AC_SUBST(OPENSSL_LIBS)
 284
 285 # AC_ARG_ENABLE(lufs,[--enable-lufs=[no/yes/auto]],,enable_lufs=no)
 286 have_lufs_includes=false
 287 # Although it would be more appropriate to use lufsmount(1) instead of lufsd(1)
 288 # we use lufsd(1) as lufsmount(1) is just a dumb wrapper and it would cost us
 289 # another big binary file for the static build package version.
 290 PATH_LUFSD=""
 291 if test x$enable_lufs != xno;then
 292         have_lufs_includes=true
 293         dnl If ACTION-IF-NOT-FOUND is given, it is executed when one of the header
 294         dnl files is not found.
 295         AC_CHECK_HEADERS(lufs/fs.h lufs/proto.h,,[ have_lufs_includes=false ])
 296         if test x$have_lufs_includes = xfalse;then
 297                 if test x$enable_lufs = xyes;then
 298                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 299                 else
 300                         AC_MSG_WARN([LUFS client not being compiled as no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 301                 fi
 302         fi
 303         AC_CHECK_TYPES([struct lufs_sbattr],,[
 304                 dnl FIXME: Include 'lufs' version when 'lufs_sbattr' gets integrated:
 305                 if $have_lufs_includes && test x$enable_lufs = xyes;then
 306                         AC_MSG_ERROR([Although LUFS include files were found they are too old. You may also use --enable-lufs=auto.])
 307                 else
 308                         AC_MSG_WARN([Although LUFS include files were found they are too old. df(1) will not show available NTFS disk space.])
 309                 fi
 310                 ],[#include <lufs/proto.h>])
 311         AC_PATH_PROGS(PATH_LUFSD,lufsd)
 312         if test x$PATH_LUFSD = x;then
 313                 if test x$enable_lufs = xyes;then
 314                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no lufsd(1) binary was found. Install 'lufs-*-*captive*' package.])
 315                 else
 316                         AC_MSG_WARN([LUFS client not being compiled as no lufsd(1) binary was found. Install 'lufs-*-*captive*' package.])
 317                 fi
 318         fi
 319 fi
 320 AM_CONDITIONAL(ENABLE_LUFS,[ $have_lufs_includes && test x$PATH_LUFSD != x -a x$enable_lufs != no ])
 321 if test x$ENABLE_LUFS_TRUE = x;then
 322         AC_MSG_WARN([LUFS client is going to be compiled - LUFS is deprecated, FUSE module is recommended instead.])
 323 fi
 324 AC_SUBST(PATH_LUFSD)
 325
 326 # AC_ARG_ENABLE(fuse,[--enable-fuse=[no/yes/auto]],,enable_fuse=auto)
 327 have_fuse=false
 328 if test x$enable_fuse != xno;then
 329         PKG_CHECK_MODULES(FUSE,fuse,[ have_fuse=true ],[
 330                 if test x$enable_fuse = xyes;then
 331                         AC_MSG_ERROR([FUSE client was requested (--enable-fuse) but no FUSE pkg-config(1) module was found. Install 'fuse-devel' package.])
 332                 else
 333                         AC_MSG_WARN([FUSE client not being compiled as no FUSE pkg-config(1) module was found. Install 'fuse-devel' package.])
 334                 fi
 335                 ])
 336 fi
 337 AM_CONDITIONAL(ENABLE_FUSE,[ $have_fuse ])
 338 # Avoid default backward compatibility mode - see the heading of: <fuse.h>
 339 FUSE_CFLAGS="$FUSE_CFLAGS -DFUSE_USE_VERSION=22"
 340 AC_SUBST(FUSE_CFLAGS)
 341 AC_SUBST(FUSE_LIBS)
 342
 343 initddir=
 344 if test x$with_initddir != xno;then
 345         initddir="$with_initddir"
 346 fi
 347 AM_CONDITIONAL(WITH_INITDDIR,[ test x$with_initddir != xno ])
 348 AC_SUBST(initddir)
 349
 350 if test x$ENABLE_LUFS_TRUE = x -a x$ENABLE_FUSE_TRUE = x;then
 351         # mount.captive(8) file installation would conflict, that's all.
 352         AC_MSG_ERROR([Compilation of both FUSE and LUFS modules is currently not supported - use '--disable-lufs'.])
 353 fi
 354
 355 dnl for $(top_srcdir)/src/libcaptive/client/
 356 dnl Do not use '[client server]' as $4 to prevent: configure: test: too many arguments
 357 dnl  - currently this argument is not used by 'orbit2-config' in any way anyway
 358 dnl Do not use PKG_CHECK_MODULES() as it would not set 'ORBIT_IDL' etc.
 359 AM_PATH_ORBIT2(,,[AC_MSG_ERROR([Captive requires ORBit2 library.])])
 360
 361 AC_ARG_WITH(orbit-line,[  --with-orbit-line=[link/linc/auto]    Use 'link' for ORBit2 >=2.7.x+ (def.=auto)],,with_orbit_line=auto)
 362 captive_save_CFLAGS="$CFLAGS"
 363 captive_save_LIBS="$LIBS"
 364 CFLAGS="$CFLAGS $ORBIT_CFLAGS"
 365 LIBS="$LIBS $ORBIT_LIBS"
 366 AC_CHECK_FUNC(link_get_tmpdir,[
 367                 AC_DEFINE(HAVE_ORBIT_LINK,,[ORBit2 is 2.7.x+ and therefore includes its own 'link' library])
 368                 found_orbit_line=link
 369                 ],
 370         found_orbit_line=linc
 371         )
 372 CFLAGS="$captive_save_CFLAGS"
 373 LIBS="$captive_save_LIBS"
 374 if test "x$with_orbit_line" != "xauto" -a "x$with_orbit_line" != "x$found_orbit_line";then
 375         AC_MSG_ERROR([--with-orbit-line=$with_orbit_line specified but the detected line is $found_orbit_line])
 376 fi
 377
 378 if test "x$found_orbit_line" = "xlinc";then
 379         PKG_CHECK_MODULES(LINC,linc)
 380 fi
 381
 382 # AC_ARG_ENABLE(install-pkg,[--enable-install-pkg=[no/yes/auto]],,enable_install_pkg=auto)
 383 GLADE_W_INIT([
 384         ./src/install/acquire/ui-gnome-interface.c
 385         ./src/install/acquire/ui-gnome-interface.h
 386         ./src/install/acquire/ui-gnome-callbacks.h
 387         ./src/install/acquire/ui-gnome-support.c
 388         ./src/install/acquire/ui-gnome-support.h
 389         ],[$enable_install_pkg],[
 390                 AC_CHECK_LIB(ntfs,ntfs_mount,[
 391                         LIBNTFS_LIBS="-lntfs"
 392
 393                         have_libntfs_includes=true
 394                         AC_CHECK_HEADERS
 395                         # '#include "config.h"' may be required by <ntfs/*> include files.
 396                         # "config.h" may be already present while not yet being compilable.
 397                         rm -f config.h-ntfs_save
 398                         mv -f config.h config.h-ntfs_save 2>/dev/null
 399                         touch config.h
 400                         captive_save_CPPFLAGS="$CPPFLAGS"
 401                         CPPFLAGS="$CPPFLAGS -I."        # for "config.h" touched above
 402                         AC_CHECK_HEADERS(ntfs/types.h ntfs/volume.h,,[ have_libntfs_includes=false ])
 403                         CPPFLAGS="$captive_save_CPPFLAGS"
 404                         rm -f config.h
 405                         mv -f config.h-ntfs_save config.h 2>/dev/null
 406                         if $have_libntfs_includes;then
 407
 408                                 captive_save_CPPFLAGS="$CPPFLAGS"
 409                                 CPPFLAGS="$CPPFLAGS $LIBXML_CFLAGS"
 410                                 AC_CHECK_HEADERS(libxml/xmlreader.h,
 411                                         [ glade_addon=yes ],
 412                                         [ AC_MSG_WARN([Captive requires libxml >= 2.4.29 for --enable-install-pkg.]) ])
 413                                 CPPFLAGS="$captive_save_CPPFLAGS"
 414
 415                         else
 416                                 AC_MSG_WARN([Captive requires ntfs/* include files (of ntfsprogs-devel) for --enable-install-pkg.])
 417                         fi
 418                         ],[ AC_MSG_WARN([Captive requires libntfs (of ntfsprogs-devel) for --enable-install-pkg.]) ])
 419                 ])
 420 if $have_gnome;then
 421         GNOMEUI_CFLAGS="$GNOMEUI_CFLAGS -DCAPTIVE_USING_GNOMEUI"
 422 fi
 423 AC_SUBST(GNOMEUI_CFLAGS)
 424 AC_SUBST(GNOMEUI_LIBS)
 425 AC_SUBST(LIBNTFS_LIBS)
 426 dnl Do not: AM_CONDITIONAL(HAVE_LIBNTFS,[ test -n "$LIBNTFS_LIBS" ])
 427 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 428 AM_CONDITIONAL(HAVE_GLADE_WRITESOURCE,[ test "x$PATH_GLADE" != "x" ])
 429 dnl Do not: AM_CONDITIONAL(BUILD_GLADESRC,[ test "xyes" = "x$BUILD_GLADESRC" ])
 430 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 431 GNOME_ADDON_LIBS=""
 432 if test "x$BUILD_GLADESRC_TRUE" = "x"
 433 then
 434         AC_CHECK_LIB(Xi,XOpenDevice,GNOME_ADDON_LIBS="$GNOME_ADDON_LIBS -lXi")
 435 fi
 436 AC_SUBST(GNOME_ADDON_LIBS)
 437 dnl $BUILD_GLADESRC is already conditioned by $enable_install_pkg by GLADE_W_INIT()
 438 AM_CONDITIONAL(ENABLE_INSTALL_PKG,[ test "xyes" = "x$BUILD_GLADESRC" ])
 439
 440 dnl Do not use AC_REPLACE_FUNCS() as we need to link it selectively:
 441 GNOME_VFS_READ_ENTIRE_FILE_O=""
 442 captive_save_CFLAGS="$CFLAGS"
 443 captive_save_LIBS="$LIBS"
 444 CFLAGS="$CFLAGS $GNOME_VFS_MODULE_CFLAGS"
 445 LIBS="$LIBS $GNOME_VFS_MODULE_LIBS"
 446 AC_CHECK_FUNCS(gnome_vfs_read_entire_file,,
 447         [ GNOME_VFS_READ_ENTIRE_FILE_O='gnome_vfs_read_entire_file.$(OBJEXT)' ])
 448 CFLAGS="$captive_save_CFLAGS"
 449 LIBS="$captive_save_LIBS"
 450 AC_SUBST(GNOME_VFS_READ_ENTIRE_FILE_O)
 451
 452 if test x$enable_standalone = xyes;then
 453         AC_DEFINE(ENABLE_STANDALONE,,[Provide initialization for static-build])
 454 fi
 455
 456 fontsdir=
 457 if test x$enable_standalone_fonts != xno;then
 458         AC_DEFINE_UNQUOTED(STANDALONE_FONTSDIR,"$enable_standalone_fonts",
 459                         [Fonts installation directory for static-build])
 460         fontsdir="$enable_standalone_fonts"
 461 fi
 462 AC_SUBST(fontsdir)
 463 AM_CONDITIONAL(ENABLE_STANDALONE_FONTS,[test "$enable_standalone_fonts" != "no"])
 464 dnl $have_gnome should be provided by: GLADE_W_INIT()
 465 if test x$have_gnome != xtrue -a x$have_gnome != xfalse;then
 466         AC_MSG_ERROR([INTERNAL: [GLADE_W_INIT()] expected here])
 467 fi
 468 AM_CONDITIONAL(HAVE_GNOME,[test "$have_gnome" = "true"])
 469
 470 AC_SUBST(CFLAGS)
 471 AC_SUBST(LIBS)
 472
 473 dnl "Makefile" output files MUST have pathnames incl./excl. "./" prefix as specified!
 474 dnl FIXME: Why the rule above was written here?
 475 AC_OUTPUT([
 476 captive.spec
 477 ./src/libcaptive/captive.pod.pl
 478 ./src/libcaptive/client/options.pod.pl
 479 ./src/client/cmdline/captive-cmdline.pod.pl
 480 ./src/client/lufs/lufs-captivefs.pod.pl
 481 ./src/client/lufs/mount.captive.pod.pl
 482 ./src/client/lufs/mount.captive
 483 ./src/client/fuse/mount.captive.pod.pl
 484 ./src/client/sandbox-server/captive-sandbox-server.pod.pl
 485 ./src/install/fstab/captive-install-fstab.pod.pl
 486 ./src/install/acquire/captive-install-acquire.pod.pl
 487 ./src/client/gnomevfs/captive.conf
 488 ./po/Makefile.in
 489 ./macros/glade-w.sh
 490 ./debian/changelog
 491 Makefile
 492 ./macros/Makefile
 493 ./src/Makefile
 494 ./src/libcaptive/Makefile
 495 ./src/libcaptive/include/Makefile
 496 ./src/libcaptive/include/captive/Makefile
 497 ./src/libcaptive/include/reactos/Makefile
 498 ./src/libcaptive/include/reactos/ddk/Makefile
 499 ./src/libcaptive/include/reactos/ddk/i386/Makefile
 500 ./src/libcaptive/include/reactos/internal/Makefile
 501 ./src/libcaptive/include/reactos/internal/i386/Makefile
 502 ./src/libcaptive/include/reactos/napi/Makefile
 503 ./src/libcaptive/include/reactos/ntos/Makefile
 504 ./src/libcaptive/reactos/Makefile
 505 ./src/libcaptive/reactos/include/Makefile
 506 ./src/libcaptive/reactos/hal/Makefile
 507 ./src/libcaptive/reactos/hal/halx86/Makefile
 508 ./src/libcaptive/reactos/ntoskrnl/Makefile
 509 ./src/libcaptive/reactos/ntoskrnl/dbg/Makefile
 510 ./src/libcaptive/reactos/ntoskrnl/ex/Makefile
 511 ./src/libcaptive/reactos/ntoskrnl/fs/Makefile
 512 ./src/libcaptive/reactos/ntoskrnl/io/Makefile
 513 ./src/libcaptive/reactos/ntoskrnl/ke/Makefile
 514 ./src/libcaptive/reactos/ntoskrnl/ldr/Makefile
 515 ./src/libcaptive/reactos/ntoskrnl/mm/Makefile
 516 ./src/libcaptive/reactos/ntoskrnl/nt/Makefile
 517 ./src/libcaptive/reactos/ntoskrnl/ob/Makefile
 518 ./src/libcaptive/reactos/ntoskrnl/ps/Makefile
 519 ./src/libcaptive/reactos/ntoskrnl/rtl/Makefile
 520 ./src/libcaptive/reactos/ntoskrnl/rtl/i386/Makefile
 521 ./src/libcaptive/reactos/ntoskrnl/se/Makefile
 522 ./src/libcaptive/halcaptive/Makefile
 523 ./src/libcaptive/cc/Makefile
 524 ./src/libcaptive/cm/Makefile
 525 ./src/libcaptive/ex/Makefile
 526 ./src/libcaptive/fs/Makefile
 527 ./src/libcaptive/io/Makefile
 528 ./src/libcaptive/kd/Makefile
 529 ./src/libcaptive/ke/Makefile
 530 ./src/libcaptive/ldr/Makefile
 531 ./src/libcaptive/mm/Makefile
 532 ./src/libcaptive/nt/Makefile
 533 ./src/libcaptive/ob/Makefile
 534 ./src/libcaptive/po/Makefile
 535 ./src/libcaptive/ps/Makefile
 536 ./src/libcaptive/rtl/Makefile
 537 ./src/libcaptive/se/Makefile
 538 ./src/libcaptive/storage/Makefile
 539 ./src/libcaptive/sandbox/Makefile
 540 ./src/libcaptive/client/Makefile
 541 ./src/client/Makefile
 542 ./src/client/bug-replay/Makefile
 543 ./src/client/cmdline/Makefile
 544 ./src/client/gnomevfs/Makefile
 545 ./src/client/lufs/Makefile
 546 ./src/client/fuse/Makefile
 547 ./src/client/sandbox-server/Makefile
 548 ./src/install/Makefile
 549 ./src/install/libcaptive-install/Makefile
 550 ./src/install/fstab/Makefile
 551 ./src/install/acquire/Makefile
 552 ./src/TraceFS/Makefile
 553 ./src/w32-mod/Makefile
 554 ./doc/Makefile
 555 ./doc/apiref/Makefile
 556 ./fonts/Makefile
 557 ./fonts/fonts.conf
 558 ])
 559
 560 dnl FIXME: Why is "po/POTFILES" being substituted?
 561 make -C src distfiles DISTFILES_PRINT=1 \
 562                 |sed -n 's/^:DISTFILES: *\(.*\)$/\1/p'|tr ' ' '\n'|grep . >po/POTFILES.in
 563 make -C po Makefile
 564
 565 echo done.