configure.ac

   1 # $Id$
   2 # Source file to generate "./configure" to prepare package for compilation
   3 # Copyright (C) 2002-2003 Jan Kratochvil <project-captive@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 AC_INIT(src/libcaptive/Makefile-libcaptive.am)
  20 dnl 2.53 for AM_GLIB_GNU_GETTEXT:
  21 AC_PREREQ(2.53)
  22 dnl Not yet present in: Red Hat autoconf-2.57-3
  23 dnl AC_CONFIG_MACRO_DIR(macros)
  24 AM_INIT_AUTOMAKE(captive,1.1.6cvs)
  25 AM_CONFIG_HEADER(config.h)
  26 AM_MAINTAINER_MODE
  27 dnl Call AC_PROG_CC before AC_ISC_POSIX.
  28 AC_PROG_CC(gcc3 gcc-3.0 gcc cc)
  29 AC_TRY_CPP([
  30 #if __GNUC__ >= 3
  31 #else
  32 #error "GCC version 3.0+ required at least for ReactOS anonymous unions"
  33 #endif
  34 ],,[AC_MSG_ERROR([Captive requires GCC version 3.0+.])])
  35 dnl Prevent "AC_TRY_COMPILE was called before AC_ISC_POSIX":
  36 AC_ISC_POSIX
  37 AC_SYS_LARGEFILE
  38 AM_PROG_AS
  39 AM_DISABLE_STATIC
  40 AM_ENABLE_SHARED
  41 AM_PROG_LIBTOOL
  42
  43 dnl Workaround for autoconf-2.57:
  44 m4_pattern_allow([AC_MSG_WARN])
  45 m4_pattern_allow([AC_CHECK_LIB])
  46 m4_pattern_allow([AC_CHECK_HEADERS])
  47
  48 dnl gettext localization.
  49 dnl Use simpler AM_GLIB_GNU_GETTEXT instead of AM_GNU_GETTEXT
  50 dnl as we depend on glib and glib requires system installed gettext anyway.
  51 dnl http://lists.gnome.org/archives/gtk-devel-list/2003-April/msg00066.html
  52 dnl Special 'GETTEXT_PACKAGE' is required by glib gettext.
  53 ALL_LINGUAS="cs"
  54 GETTEXT_PACKAGE="$PACKAGE"
  55 AC_SUBST(GETTEXT_PACKAGE)
  56 AM_GLIB_GNU_GETTEXT
  57
  58 GTK_DOC_CHECK
  59 dnl AM_CONDITIONAL needs to be here explicitely for doc/apiref/Makefile rebuild
  60 AM_CONDITIONAL(ENABLE_GTK_DOC,[test x$enable_gtk_doc = xyes])
  61 AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL,[test -n "$LIBTOOL"])
  62
  63 dnl Do not discard 'CFLAGS' settings as they may have been passed us by rpmbuild(8)
  64
  65 dnl Define MAINTAINER_MODE in config.h.
  66 if test "$USE_MAINTAINER_MODE" = "yes";then
  67         AC_DEFINE(MAINTAINER_MODE,,[Turn even some software behaviour according to MAINTAINER_MODE.])
  68         CFLAGS="$CFLAGS -ggdb3 -Wall -Wstrict-prototypes -Wsign-compare"  ## FIXME: fix all sources: -Wsign-compare
  69         fi
  70 dnl Some Makefiles use additional tests etc.
  71 AM_CONDITIONAL(MAINTAINER_MODE,[test "$USE_MAINTAINER_MODE" = "yes"])
  72
  73
  74 AC_ARG_ENABLE(man-pages,
  75                 [  --enable-man-pages=no/yes/auto   pod2man(1) required for man pages (def.=yes)],,enable_man_pages=yes)
  76 AC_ARG_ENABLE(sbin-mountdir,
  77                 [  --enable-sbin-mountdir=DIR       mount(8) 'mount.captive' directory (def.=/sbin)],,
  78                 [ enable_sbin_mountdir="/sbin" ])
  79 AC_ARG_ENABLE(sbin-mount-fs,
  80                 [  --enable-sbin-mount-fs=FS1:FS2   sbin-mount pre-installed symlinks (def.=ntfs:fastfat:cdfs:ext2fsd)],,
  81                 [ enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd" ])
  82 AC_ARG_WITH(initddir,
  83                 [  --with-initddir=DIR              directory for captive FUSE shutdown (def.=/etc/rc.d/init.d)],,with_initddir=/etc/rc.d/init.d)
  84 AC_ARG_ENABLE(sandbox-setuid,
  85                 [  --enable-sandbox-setuid=USER     non-privileged user  for captive-sandbox-server (def.=captive)],
  86                 [ CAPTIVE_SANDBOX_SETUID="$enableval" ],[ CAPTIVE_SANDBOX_SETUID="captive" ])
  87 AC_ARG_ENABLE(sandbox-setgid,
  88                 [  --enable-sandbox-setgid=GROUP    non-privileged group for captive-sandbox-server (def.=captive)],
  89                 [ CAPTIVE_SANDBOX_SETGID="$enableval" ],[ CAPTIVE_SANDBOX_SETGID="captive" ])
  90 AC_ARG_ENABLE(sandbox-chroot,
  91                 [  --enable-sandbox-chroot=DIR      root-owned directory for captive-sandbox-server (def.=/var/lib/captive)],
  92                 [ CAPTIVE_SANDBOX_CHROOT="$enableval" ],[ CAPTIVE_SANDBOX_CHROOT="/var/lib/captive" ])
  93 AC_ARG_ENABLE(bug-replay,
  94                 [  --enable-bug-replay=no/yes/auto  compile debugging tool (def.=auto)],,enable_bug_replay=auto)
  95 AC_ARG_ENABLE(lufs,
  96                 [  --enable-lufs=no/yes/auto        compile LUFS filesystem module - DEPRECATED (def.=no)],,enable_lufs=no)
  97 AC_ARG_ENABLE(fuse,
  98                 [  --enable-fuse=no/yes/auto        compile FUSE filesystem module (def.=auto)],,enable_fuse=auto)
  99 AC_ARG_ENABLE(install-pkg,
 100                 [  --enable-install-pkg=no/yes/auto compile installation utils (def.=auto)],,enable_install_pkg=auto)
 101 AC_ARG_ENABLE(standalone,
 102                 [  --enable-standalone=no/yes       provide initialization for static-build (def.=no)],,enable_standalone=no)
 103 AC_ARG_ENABLE(standalone-fonts,
 104                 [  --enable-standalone-fonts=DIR    provide bundled Gnome fonts in directory (def.=no)],,enable_standalone_fonts=no)
 105
 106
 107 # AC_ARG_ENABLE(sbin-mountdir,[--enable-sbin-mountdir=DIR],,[enable_sbin_mountdir="/sbin"])
 108 AM_CONDITIONAL(ENABLE_SBIN_MOUNT,[test "$enable_sbin_mount" != "no"])
 109 AC_SUBST(enable_sbin_mountdir)
 110
 111 # AC_ARG_ENABLE(sbin-mount-fs,[--enable-sbin-mount-fs=FS1:FS2],,[enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd"])
 112 AC_SUBST(enable_sbin_mount_fs)
 113
 114 # AC_ARG_ENABLE(sandbox-setuid,[--enable-sandbox-setuid=USER],,[CAPTIVE_SANDBOX_SETUID="captive"])
 115 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETUID,"$CAPTIVE_SANDBOX_SETUID",
 116                 [non-privileged user  for captive-sandbox-server])
 117 AC_SUBST(CAPTIVE_SANDBOX_SETUID)
 118
 119 # AC_ARG_ENABLE(sandbox-setgid,[--enable-sandbox-setgid=GROUP],,[CAPTIVE_SANDBOX_SETGID="captive"])
 120 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETGID,"$CAPTIVE_SANDBOX_SETGID",
 121                 [non-privileged group for captive-sandbox-server])
 122 AC_SUBST(CAPTIVE_SANDBOX_SETGID)
 123
 124 # AC_ARG_ENABLE(sandbox-chroot,[--enable-sandbox-chroot=DIR],,[CAPTIVE_SANDBOX_CHROOT="/var/lib/captive"])
 125 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_CHROOT,"$CAPTIVE_SANDBOX_CHROOT",
 126                 [root-owned directory for captive-sandbox-server])
 127 AC_SUBST(CAPTIVE_SANDBOX_CHROOT)
 128
 129 dnl Permit 'if NEVER' for Makefile.am-s; symbol 'FALSE' forbidden by automake
 130 AM_CONDITIONAL(NEVER,false)
 131
 132 PERL=
 133 AC_PATH_PROGS(PERL,perl5 perl)
 134 if test '!' -f ./src/libcaptive/ke/exports.c -a -z "$PERL";then
 135         AC_MSG_ERROR([perl(1) required as './src/libcaptive/ke/exports.c' is not found.])
 136 fi
 137 AM_CONDITIONAL(HAVE_PERL,test -n "$PERL")
 138
 139 POD2MAN=
 140 AC_PATH_PROGS(POD2MAN,pod2man)
 141 AM_CONDITIONAL(HAVE_POD2MAN,[ test -n "$POD2MAN" ])
 142 if test x$enable_man_pages = xyes;then
 143         if test -z "$POD2MAN";then
 144                 AC_MSG_ERROR([captive requires pod2man(1) for man pages; try --disable-man-pages.])
 145         fi
 146         if test -z "$PERL";then
 147                 AC_MSG_ERROR([captive requires perl(1) for man pages; try --disable-man-pages.])
 148         fi
 149 elif test x$enable_man_pages != xno;then
 150         if test -z "$POD2MAN";then
 151                 AC_MSG_WARN([captive requires pod2man(1) for man pages by --enable-man-pages; mans will not be installed.])
 152         fi
 153         if test -z "$PERL";then
 154                 AC_MSG_WARN([captive requires perl(1) for man pages by --enable-man-pages; mans will not be installed.])
 155         fi
 156 fi
 157 AM_CONDITIONAL(ENABLE_MAN_PAGES,[ test x$enable_man_pages != xno -a -n "$POD2MAN" -a -n "$PERL" ])
 158
 159 dnl Separate 'acconfig.h' is no longer recommended by autoconf
 160 AH_TOP([
 161 #ifndef _CAPTIVE_CONFIG_H
 162 #define _CAPTIVE_CONFIG_H 1
 163 ])
 164 AH_BOTTOM([
 165 /* Do not place any stuff to AH_TOP as some of its includes
 166  * would discard the effect of _FILE_OFFSET_BITS by AC_SYS_LARGEFILE.
 167  */
 168
 169 #ifdef ENABLE_NLS
 170 /* <libintl.h> is taken from "$(top_srcdir)/intl" if system doesn't provide intl */
 171 #       include <libintl.h>
 172 #ifdef LIBCAPTIVE
 173 #       define _(String) dgettext (PACKAGE,String)
 174 #else
 175 #       define _(String) gettext (String)
 176 #endif /* LIBCAPTIVE */
 177 #       ifdef gettext_noop
 178 #               define N_(String) gettext_noop (String)
 179 #       else
 180 #               define N_(String) (String)
 181 #       endif
 182 #else /* !ENABLE_NLS */
 183 /* Stubs that do something close enough.  */
 184 #       define textdomain(String) (String)
 185 #       define gettext(String) (String)
 186 #       define dgettext(Domain,Message) (Message)
 187 #       define dcgettext(Domain,Message,Type) (Message)
 188 #       define bindtextdomain(Domain,Directory) (Domain)
 189 #       define _(String) (String)
 190 #       define N_(String) (String)
 191 #endif /* !ENABLE_NLS */
 192
 193 #include <glib/gtypes.h>        /* for 'gchar' */
 194 #define G_LOG_DOMAIN ((const gchar *)"Captive")
 195
 196 /* Ensure we have proper -I options: */
 197 #if defined(CAPTIVE_USE_GNOME_VFS_MODULE) || defined(CAPTIVE_USE_GNOME_VFS)
 198 #ifndef HAVE_GNOME_VFS_READ_ENTIRE_FILE
 199 #include <libgnomevfs/gnome-vfs-result.h>
 200 GnomeVFSResult gnome_vfs_read_entire_file(const char *uri,int *file_size,char **file_contents);
 201 #endif
 202 #endif
 203
 204 /* Supplemental definitions not possible in this file. */
 205 #ifdef LIBCAPTIVE
 206 #include "captive/config2.h"
 207 #endif
 208
 209 #endif /* !_CAPTIVE_CONFIG_H */
 210 ])
 211
 212 dnl Do not use PKG_CHECK_MODULES() as it would not set 'GLIB_GENMARSHAL' etc.
 213 AM_PATH_GLIB_2_0(,,[AC_MSG_ERROR([Captive requires glib-2.0 library.])],[gmodule gobject gthread])
 214 dnl Force glib for the whole package
 215 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 216 LIBS="$LIBS $GLIB_LIBS"
 217
 218 dnl popt
 219 AC_CHECK_LIB(popt,poptParseArgvString,[POPT_LIBS="-lpopt"],[AC_MSG_ERROR([Captive requires popt library.])])
 220 AC_SUBST(POPT_LIBS)
 221
 222 AC_ARG_WITH(readline,[  --with-readline=[no/yes/auto]   clients with line editing (def.=auto)],,with_readline=auto)
 223 AC_CHECK_HEADERS(readline/history.h)
 224 dnl Check for libraries, if needed by configuration options.
 225 if test "$with_readline" != "no"
 226 then
 227         if test -d "/usr/lib/termcap"
 228         then
 229                 READLINE_LDFLAGS="$READLINE_LDFLAGS -L/usr/lib/termcap"
 230         fi
 231         have_libreadline=false
 232         need_failed=""
 233         for need in "" termcap ncurses; do
 234                 if test "x$need" != "x"
 235                 then
 236                         captive_save_LIBS="$LIBS"
 237                         AC_CHECK_LIB($need,main,,
 238                                 [ need_failed="$need_failed $need"
 239                                 continue ]
 240                                 )
 241                         LIBS="$captive_save_LIBS"
 242                         lneed="-l$need"
 243                 else
 244                         lneed=""
 245                 fi
 246                 dnl Prevent AC_CHECK_LIB() here as it would _cache_ the value ignoring
 247                 dnl our ever-changing "additiona libraries" parameter
 248                 captive_save_LIBS="$LIBS"
 249                 LIBS="-lreadline $lneed $READLINE_LIBS"
 250                 AC_TRY_LINK(,[ main() ],
 251                         [ have_libreadline=true
 252                         READLINE_LIBS="$LIBS" ])
 253                 LIBS="$captive_save_LIBS"
 254                 if $have_libreadline
 255                 then
 256                         break
 257                 fi
 258         done
 259         if $have_libreadline
 260         then
 261                 AC_DEFINE(HAVE_LIBREADLINE,,[Use functions from libreadline?])
 262                 AC_CHECK_LIB(readline,add_history,
 263                         AC_DEFINE(HAVE_ADD_HISTORY,,[Use 'history' extension of libreadline?]),,
 264                         $READLINE_LIBS)
 265         else
 266                 for need in $need_failed; do
 267                         AC_MSG_WARN(captive recommends $need library as your readline library
 268                         probably needs it.)
 269                 done
 270                 if test "$with_readline" = "yes"
 271                 then
 272                         AC_MSG_ERROR([captive did not find the requested readline library for its client line editing capability.])
 273                 else
 274                         AC_MSG_WARN([captive recommends readline library for its client line editing capability.])
 275                 fi
 276         fi
 277 fi
 278 AC_SUBST(READLINE_LIBS)
 279 AC_SUBST(READLINE_LDFLAGS)
 280
 281 PKG_CHECK_MODULES(GNOME_VFS_MODULE,gnome-vfs-module-2.0)
 282 GNOME_VFS_MODULE_CFLAGS="$GNOME_VFS_MODULE_CFLAGS -DCAPTIVE_USE_GNOME_VFS_MODULE=1"
 283 AC_SUBST(GNOME_VFS_MODULE_CFLAGS)
 284 AC_SUBST(GNOME_VFS_MODULE_LIBS)
 285 PKG_CHECK_MODULES(GNOME_VFS,gnome-vfs-2.0)
 286 GNOME_VFS_CFLAGS="$GNOME_VFS_CFLAGS -DCAPTIVE_USE_GNOME_VFS=1"
 287 AC_SUBST(GNOME_VFS_CFLAGS)
 288 AC_SUBST(GNOME_VFS_LIBS)
 289
 290 # AC_ARG_ENABLE(bug-replay,[--enable-bug-replay=[no/yes/auto]],,enable_bug_replay=auto)
 291 dnl Check for 2.5.9 for: http://bugzilla.gnome.org/show_bug.cgi?id=117702
 292 dnl Check the version - impossible to reliably check the missing feature.
 293 PKG_CHECK_MODULES(LIBXML,libxml-2.0 >= 2.5.9,[ have_libxml_buffering=true ],[
 294         dnl Disable bug-replay(1) build if not met; --bug-pathname would be still OK.
 295         PKG_CHECK_MODULES(LIBXML,libxml-2.0,[ have_libxml_buffering=false ])
 296         ])
 297 dnl We also condition 'HAVE_LIBXML_XMLREADER_H' by 'HAVE_LIBXML_BUFFERING'
 298 dnl as we have no use for xmlreader without working libxml buffering of 2.5.9.
 299 AM_CONDITIONAL(ENABLE_BUG_REPLAY,[$have_libxml_buffering && test x$enable_bug_replay != xno])
 300 if $have_libxml_buffering;then
 301         AC_DEFINE(HAVE_LIBXML_BUFFERING,,[libxml2 correctly reads textnodes by its xmlTextReader.])
 302 else
 303         if test x$enable_bug_replay = xyes;then
 304                 AC_MSG_ERROR([captive require libxml2 at least 2.5.9 for --enable-bug-replay feature.])
 305         elif test x$enable_bug_replay != xno;then
 306                 AC_MSG_WARN([libxml2 at least 2.5.9 required --enable-bug-replay feature; disabled now.])
 307         fi
 308 fi
 309 AC_SUBST(LIBXML_CFLAGS)
 310 AC_SUBST(LIBXML_LIBS)
 311
 312 PKG_CHECK_MODULES(OPENSSL,openssl,,[
 313         dnl At least Debian-3.0r1 has openssl but without its .pc module.
 314         AC_CHECK_LIB(crypto,MD5,[
 315                 OPENSSL_CFLAGS=""
 316                 OPENSSL_LIBS="-lcrypto"
 317                 ],[AC_MSG_ERROR([Captive requires crypto library (of openssl).])])
 318         ])
 319 AC_SUBST(OPENSSL_CFLAGS)
 320 AC_SUBST(OPENSSL_LIBS)
 321
 322 # AC_ARG_ENABLE(lufs,[--enable-lufs=[no/yes/auto]],,enable_lufs=no)
 323 have_lufs_includes=false
 324 # Although it would be more appropriate to use lufsmount(1) instead of lufsd(1)
 325 # we use lufsd(1) as lufsmount(1) is just a dumb wrapper and it would cost us
 326 # another big binary file for the static build package version.
 327 PATH_LUFSD=""
 328 if test x$enable_lufs != xno;then
 329         have_lufs_includes=true
 330         dnl If ACTION-IF-NOT-FOUND is given, it is executed when one of the header
 331         dnl files is not found.
 332         AC_CHECK_HEADERS(lufs/fs.h lufs/proto.h,,[ have_lufs_includes=false ])
 333         if test x$have_lufs_includes = xfalse;then
 334                 if test x$enable_lufs = xyes;then
 335                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 336                 else
 337                         AC_MSG_WARN([LUFS client not being compiled as no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 338                 fi
 339         fi
 340         AC_CHECK_TYPES([struct lufs_sbattr],,[
 341                 dnl FIXME: Include 'lufs' version when 'lufs_sbattr' gets integrated:
 342                 if $have_lufs_includes && test x$enable_lufs = xyes;then
 343                         AC_MSG_ERROR([Although LUFS include files were found they are too old. You may also use --enable-lufs=auto.])
 344                 else
 345                         AC_MSG_WARN([Although LUFS include files were found they are too old. df(1) will not show available NTFS disk space.])
 346                 fi
 347                 ],[#include <lufs/proto.h>])
 348         AC_PATH_PROGS(PATH_LUFSD,lufsd)
 349         if test x$PATH_LUFSD = x;then
 350                 if test x$enable_lufs = xyes;then
 351                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no lufsd(1) binary was found. Install 'lufs-*-*captive*' package.])
 352                 else
 353                         AC_MSG_WARN([LUFS client not being compiled as no lufsd(1) binary was found. Install 'lufs-*-*captive*' package.])
 354                 fi
 355         fi
 356 fi
 357 AM_CONDITIONAL(ENABLE_LUFS,[ $have_lufs_includes && test x$PATH_LUFSD != x -a x$enable_lufs != no ])
 358 if test x$ENABLE_LUFS_TRUE = x;then
 359         AC_MSG_WARN([LUFS client is going to be compiled - LUFS is deprecated, FUSE module is recommended instead.])
 360 fi
 361 AC_SUBST(PATH_LUFSD)
 362
 363 # AC_ARG_ENABLE(fuse,[--enable-fuse=[no/yes/auto]],,enable_fuse=auto)
 364 have_fuse=false
 365 if test x$enable_fuse != xno;then
 366         PKG_CHECK_MODULES(FUSE,fuse,[ have_fuse=true ],[
 367                 if test x$enable_fuse = xyes;then
 368                         AC_MSG_ERROR([FUSE client was requested (--enable-fuse) but no FUSE pkg-config(1) module was found. Install 'fuse-devel' package.])
 369                 else
 370                         AC_MSG_WARN([FUSE client not being compiled as no FUSE pkg-config(1) module was found. Install 'fuse-devel' package.])
 371                 fi
 372                 ])
 373 fi
 374 AM_CONDITIONAL(ENABLE_FUSE,[ $have_fuse ])
 375 # Avoid default backward compatibility mode - see the heading of: <fuse.h>
 376 FUSE_CFLAGS="$FUSE_CFLAGS -DFUSE_USE_VERSION=22"
 377 AC_SUBST(FUSE_CFLAGS)
 378 AC_SUBST(FUSE_LIBS)
 379
 380 initddir=
 381 if test x$with_initddir != xno;then
 382         initddir="$with_initddir"
 383 fi
 384 AM_CONDITIONAL(WITH_INITDDIR,[ test x$with_initddir != xno ])
 385 AC_SUBST(initddir)
 386
 387 if test x$ENABLE_LUFS_TRUE = x -a x$ENABLE_FUSE_TRUE = x;then
 388         # mount.captive(8) file installation would conflict, that's all.
 389         AC_MSG_ERROR([Compilation of both FUSE and LUFS modules is currently not supported - use '--disable-lufs'.])
 390 fi
 391
 392 dnl for $(top_srcdir)/src/libcaptive/client/
 393 dnl Do not use '[client server]' as $4 to prevent: configure: test: too many arguments
 394 dnl  - currently this argument is not used by 'orbit2-config' in any way anyway
 395 dnl Do not use PKG_CHECK_MODULES() as it would not set 'ORBIT_IDL' etc.
 396 AM_PATH_ORBIT2(,,[AC_MSG_ERROR([Captive requires ORBit2 library.])])
 397
 398 AC_ARG_WITH(orbit-line,[  --with-orbit-line=[link/linc/auto]    Use 'link' for ORBit2 >=2.7.x+ (def.=auto)],,with_orbit_line=auto)
 399 captive_save_CFLAGS="$CFLAGS"
 400 captive_save_LIBS="$LIBS"
 401 CFLAGS="$CFLAGS $ORBIT_CFLAGS"
 402 LIBS="$LIBS $ORBIT_LIBS"
 403 AC_CHECK_FUNC(link_get_tmpdir,[
 404                 AC_DEFINE(HAVE_ORBIT_LINK,,[ORBit2 is 2.7.x+ and therefore includes its own 'link' library])
 405                 found_orbit_line=link
 406                 ],
 407         found_orbit_line=linc
 408         )
 409 CFLAGS="$captive_save_CFLAGS"
 410 LIBS="$captive_save_LIBS"
 411 if test "x$with_orbit_line" != "xauto" -a "x$with_orbit_line" != "x$found_orbit_line";then
 412         AC_MSG_ERROR([--with-orbit-line=$with_orbit_line specified but the detected line is $found_orbit_line])
 413 fi
 414
 415 if test "x$found_orbit_line" = "xlinc";then
 416         PKG_CHECK_MODULES(LINC,linc)
 417 fi
 418
 419 # AC_ARG_ENABLE(install-pkg,[--enable-install-pkg=[no/yes/auto]],,enable_install_pkg=auto)
 420 GLADE_W_INIT([
 421         ./src/install/acquire/ui-gnome-interface.c
 422         ./src/install/acquire/ui-gnome-interface.h
 423         ./src/install/acquire/ui-gnome-callbacks.h
 424         ./src/install/acquire/ui-gnome-support.c
 425         ./src/install/acquire/ui-gnome-support.h
 426         ],[$enable_install_pkg],[
 427                 AC_CHECK_LIB(ntfs,ntfs_mount,[
 428                         LIBNTFS_LIBS="-lntfs"
 429
 430                         have_libntfs_includes=true
 431                         AC_CHECK_HEADERS
 432                         # '#include "config.h"' may be required by <ntfs/*> include files.
 433                         # "config.h" may be already present while not yet being compilable.
 434                         rm -f config.h-ntfs_save
 435                         mv -f config.h config.h-ntfs_save 2>/dev/null
 436                         touch config.h
 437                         captive_save_CPPFLAGS="$CPPFLAGS"
 438                         CPPFLAGS="$CPPFLAGS -I."        # for "config.h" touched above
 439                         AC_CHECK_HEADERS(ntfs/types.h ntfs/volume.h,,[ have_libntfs_includes=false ])
 440                         CPPFLAGS="$captive_save_CPPFLAGS"
 441                         rm -f config.h
 442                         mv -f config.h-ntfs_save config.h 2>/dev/null
 443                         if $have_libntfs_includes;then
 444
 445                                 captive_save_CPPFLAGS="$CPPFLAGS"
 446                                 CPPFLAGS="$CPPFLAGS $LIBXML_CFLAGS"
 447                                 AC_CHECK_HEADERS(libxml/xmlreader.h,
 448                                         [ glade_addon=yes ],
 449                                         [ AC_MSG_WARN([Captive requires libxml >= 2.4.29 for --enable-install-pkg.]) ])
 450                                 CPPFLAGS="$captive_save_CPPFLAGS"
 451
 452                         else
 453                                 AC_MSG_WARN([Captive requires ntfs/* include files (of ntfsprogs-devel) for --enable-install-pkg.])
 454                         fi
 455                         ],[ AC_MSG_WARN([Captive requires libntfs (of ntfsprogs-devel) for --enable-install-pkg.]) ])
 456                 ])
 457 AC_SUBST(GNOMEUI_CFLAGS)
 458 AC_SUBST(GNOMEUI_LIBS)
 459 AC_SUBST(LIBNTFS_LIBS)
 460 dnl Do not: AM_CONDITIONAL(HAVE_LIBNTFS,[ test -n "$LIBNTFS_LIBS" ])
 461 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 462 AM_CONDITIONAL(HAVE_GLADE_WRITESOURCE,[ test "x$PATH_GLADE" != "x" ])
 463 dnl Do not: AM_CONDITIONAL(BUILD_GLADESRC,[ test "xyes" = "x$BUILD_GLADESRC" ])
 464 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 465 GNOME_ADDON_LIBS=""
 466 if test "x$BUILD_GLADESRC_TRUE" = "x"
 467 then
 468         AC_CHECK_LIB(Xi,XOpenDevice,GNOME_ADDON_LIBS="$GNOME_ADDON_LIBS -lXi")
 469 fi
 470 AC_SUBST(GNOME_ADDON_LIBS)
 471 dnl $BUILD_GLADESRC is already conditioned by $enable_install_pkg by GLADE_W_INIT()
 472 AM_CONDITIONAL(ENABLE_INSTALL_PKG,[ test "xyes" = "x$BUILD_GLADESRC" ])
 473
 474 dnl Do not use AC_REPLACE_FUNCS() as we need to link it selectively:
 475 GNOME_VFS_READ_ENTIRE_FILE_O=""
 476 captive_save_CFLAGS="$CFLAGS"
 477 captive_save_LIBS="$LIBS"
 478 CFLAGS="$CFLAGS $GNOME_VFS_MODULE_CFLAGS"
 479 LIBS="$LIBS $GNOME_VFS_MODULE_LIBS"
 480 AC_CHECK_FUNCS(gnome_vfs_read_entire_file,,
 481         [ GNOME_VFS_READ_ENTIRE_FILE_O='gnome_vfs_read_entire_file.$(OBJEXT)' ])
 482 CFLAGS="$captive_save_CFLAGS"
 483 LIBS="$captive_save_LIBS"
 484 AC_SUBST(GNOME_VFS_READ_ENTIRE_FILE_O)
 485
 486 if test x$enable_standalone = xyes;then
 487         AC_DEFINE(ENABLE_STANDALONE,,[Provide initialization for static-build])
 488 fi
 489
 490 fontsdir=
 491 if test x$enable_standalone_fonts != xno;then
 492         AC_DEFINE_UNQUOTED(STANDALONE_FONTSDIR,"$enable_standalone_fonts",
 493                         [Fonts installation directory for static-build])
 494         fontsdir="$enable_standalone_fonts"
 495 fi
 496 AC_SUBST(fontsdir)
 497 AM_CONDITIONAL(ENABLE_STANDALONE_FONTS,[test "$enable_standalone_fonts" != "no"])
 498 dnl $have_gnome should be provided by: GLADE_W_INIT()
 499 if test x$have_gnome != xtrue -a x$have_gnome != xfalse;then
 500         AC_MSG_ERROR([INTERNAL: [GLADE_W_INIT()] expected here])
 501 fi
 502 AM_CONDITIONAL(HAVE_GNOME,[test "$have_gnome" = "true"])
 503
 504 AC_SUBST(CFLAGS)
 505 AC_SUBST(LIBS)
 506
 507 dnl "Makefile" output files MUST have pathnames incl./excl. "./" prefix as specified!
 508 dnl FIXME: Why the rule above was written here?
 509 AC_OUTPUT([
 510 captive.spec
 511 ./src/libcaptive/captive.pod.pl
 512 ./src/libcaptive/client/options.pod.pl
 513 ./src/client/cmdline/captive-cmdline.pod.pl
 514 ./src/client/lufs/lufs-captivefs.pod.pl
 515 ./src/client/lufs/mount.captive.pod.pl
 516 ./src/client/lufs/mount.captive
 517 ./src/client/fuse/mount.captive.pod.pl
 518 ./src/client/sandbox-server/captive-sandbox-server.pod.pl
 519 ./src/install/fstab/captive-install-fstab.pod.pl
 520 ./src/install/acquire/captive-install-acquire.pod.pl
 521 ./src/client/gnomevfs/captive.conf
 522 ./po/Makefile.in
 523 ./macros/glade-w.sh
 524 ./debian/changelog
 525 Makefile
 526 ./macros/Makefile
 527 ./src/Makefile
 528 ./src/libcaptive/Makefile
 529 ./src/libcaptive/include/Makefile
 530 ./src/libcaptive/include/captive/Makefile
 531 ./src/libcaptive/include/reactos/Makefile
 532 ./src/libcaptive/include/reactos/ddk/Makefile
 533 ./src/libcaptive/include/reactos/ddk/i386/Makefile
 534 ./src/libcaptive/include/reactos/internal/Makefile
 535 ./src/libcaptive/include/reactos/internal/i386/Makefile
 536 ./src/libcaptive/include/reactos/napi/Makefile
 537 ./src/libcaptive/include/reactos/ntos/Makefile
 538 ./src/libcaptive/reactos/Makefile
 539 ./src/libcaptive/reactos/include/Makefile
 540 ./src/libcaptive/reactos/hal/Makefile
 541 ./src/libcaptive/reactos/hal/halx86/Makefile
 542 ./src/libcaptive/reactos/ntoskrnl/Makefile
 543 ./src/libcaptive/reactos/ntoskrnl/dbg/Makefile
 544 ./src/libcaptive/reactos/ntoskrnl/ex/Makefile
 545 ./src/libcaptive/reactos/ntoskrnl/fs/Makefile
 546 ./src/libcaptive/reactos/ntoskrnl/io/Makefile
 547 ./src/libcaptive/reactos/ntoskrnl/ke/Makefile
 548 ./src/libcaptive/reactos/ntoskrnl/ldr/Makefile
 549 ./src/libcaptive/reactos/ntoskrnl/mm/Makefile
 550 ./src/libcaptive/reactos/ntoskrnl/nt/Makefile
 551 ./src/libcaptive/reactos/ntoskrnl/ob/Makefile
 552 ./src/libcaptive/reactos/ntoskrnl/ps/Makefile
 553 ./src/libcaptive/reactos/ntoskrnl/rtl/Makefile
 554 ./src/libcaptive/reactos/ntoskrnl/rtl/i386/Makefile
 555 ./src/libcaptive/reactos/ntoskrnl/se/Makefile
 556 ./src/libcaptive/halcaptive/Makefile
 557 ./src/libcaptive/cc/Makefile
 558 ./src/libcaptive/cm/Makefile
 559 ./src/libcaptive/ex/Makefile
 560 ./src/libcaptive/fs/Makefile
 561 ./src/libcaptive/io/Makefile
 562 ./src/libcaptive/kd/Makefile
 563 ./src/libcaptive/ke/Makefile
 564 ./src/libcaptive/ldr/Makefile
 565 ./src/libcaptive/mm/Makefile
 566 ./src/libcaptive/nt/Makefile
 567 ./src/libcaptive/ob/Makefile
 568 ./src/libcaptive/po/Makefile
 569 ./src/libcaptive/ps/Makefile
 570 ./src/libcaptive/rtl/Makefile
 571 ./src/libcaptive/se/Makefile
 572 ./src/libcaptive/storage/Makefile
 573 ./src/libcaptive/sandbox/Makefile
 574 ./src/libcaptive/client/Makefile
 575 ./src/client/Makefile
 576 ./src/client/bug-replay/Makefile
 577 ./src/client/cmdline/Makefile
 578 ./src/client/gnomevfs/Makefile
 579 ./src/client/lufs/Makefile
 580 ./src/client/fuse/Makefile
 581 ./src/client/sandbox-server/Makefile
 582 ./src/install/Makefile
 583 ./src/install/libcaptive-install/Makefile
 584 ./src/install/fstab/Makefile
 585 ./src/install/acquire/Makefile
 586 ./src/TraceFS/Makefile
 587 ./src/w32-mod/Makefile
 588 ./doc/Makefile
 589 ./doc/apiref/Makefile
 590 ./fonts/Makefile
 591 ./fonts/fonts.conf
 592 ])
 593
 594 dnl FIXME: Why is "po/POTFILES" being substituted?
 595 make -C src distfiles DISTFILES_PRINT=1 \
 596                 |sed -n 's/^:DISTFILES: *\(.*\)$/\1/p'|tr ' ' '\n'|grep . >po/POTFILES.in
 597 make -C po Makefile
 598
 599 echo done.