configure.in

   1 # $Id$
   2 # Source file to generate "./configure" to prepare package for compilation
   3 # Copyright (C) 2002-2003 Jan Kratochvil <project-captive@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 AC_INIT(src/libcaptive/Makefile-libcaptive.am)
  20 dnl 2.53 for AM_GLIB_GNU_GETTEXT:
  21 AC_PREREQ(2.53)
  22 dnl Not yet present in: Red Hat autoconf-2.57-3
  23 dnl AC_CONFIG_MACRO_DIR(macros)
  24 AM_INIT_AUTOMAKE(captive,1.1.6cvs)
  25 AM_CONFIG_HEADER(config.h)
  26 AM_MAINTAINER_MODE
  27 dnl Call AC_PROG_CC before AC_ISC_POSIX.
  28 AC_PROG_CC(gcc3 gcc-3.0 gcc cc)
  29 AC_TRY_CPP([
  30 #if __GNUC__ >= 3
  31 #else
  32 #error "GCC version 3.0+ required at least for ReactOS anonymous unions"
  33 #endif
  34 ],,[AC_MSG_ERROR([Captive requires GCC version 3.0+.])])
  35 dnl Prevent "AC_TRY_COMPILE was called before AC_ISC_POSIX":
  36 AC_ISC_POSIX
  37 AC_SYS_LARGEFILE
  38 AM_PROG_AS
  39 AM_DISABLE_STATIC
  40 AM_ENABLE_SHARED
  41 AM_PROG_LIBTOOL
  42
  43 dnl Workaround for autoconf-2.57:
  44 m4_pattern_allow([AC_MSG_WARN])
  45 m4_pattern_allow([AC_CHECK_LIB])
  46 m4_pattern_allow([AC_CHECK_HEADERS])
  47
  48 dnl gettext localization.
  49 dnl Use simpler AM_GLIB_GNU_GETTEXT instead of AM_GNU_GETTEXT
  50 dnl as we depend on glib and glib requires system installed gettext anyway.
  51 dnl http://lists.gnome.org/archives/gtk-devel-list/2003-April/msg00066.html
  52 dnl Special 'GETTEXT_PACKAGE' is required by glib gettext.
  53 ALL_LINGUAS="cs"
  54 GETTEXT_PACKAGE="$PACKAGE"
  55 AC_SUBST(GETTEXT_PACKAGE)
  56 AM_GLIB_GNU_GETTEXT
  57
  58 GTK_DOC_CHECK
  59 dnl AM_CONDITIONAL needs to be here explicitely for doc/apiref/Makefile rebuild
  60 AM_CONDITIONAL(ENABLE_GTK_DOC,[test x$enable_gtk_doc = xyes])
  61 AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL,[test -n "$LIBTOOL"])
  62
  63 dnl Do not discard 'CFLAGS' settings as they may have been passed us by rpmbuild(8)
  64
  65 dnl Define MAINTAINER_MODE in config.h.
  66 if test "$USE_MAINTAINER_MODE" = "yes";then
  67         AC_DEFINE(MAINTAINER_MODE,,[Turn even some software behaviour according to MAINTAINER_MODE.])
  68         CFLAGS="$CFLAGS -ggdb3 -Wall -Wstrict-prototypes -Wsign-compare"  ## FIXME: fix all sources: -Wsign-compare
  69         fi
  70 dnl Some Makefiles use additional tests etc.
  71 AM_CONDITIONAL(MAINTAINER_MODE,[test "$USE_MAINTAINER_MODE" = "yes"])
  72
  73
  74 AC_ARG_ENABLE(man-pages,
  75                 [  --enable-man-pages=no/yes/auto   pod2man(1) required for man pages (def.=yes)],,enable_man_pages=yes)
  76 AC_ARG_ENABLE(sbin-mountdir,
  77                 [  --enable-sbin-mountdir=DIR       mount(8) 'mount.captive' directory (def.=/sbin)],,
  78                 [ enable_sbin_mountdir="/sbin" ])
  79 AC_ARG_ENABLE(sbin-mount-fs,
  80                 [  --enable-sbin-mount-fs=FS1:FS2   sbin-mount pre-installed symlinks (def.=ntfs:fastfat:cdfs:ext2fsd)],,
  81                 [ enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd" ])
  82 AC_ARG_ENABLE(sandbox-setuid,
  83                 [  --enable-sandbox-setuid=USER     non-privileged user  for captive-sandbox-server (def.=captive)],
  84                 [ CAPTIVE_SANDBOX_SETUID="$enableval" ],[ CAPTIVE_SANDBOX_SETUID="captive" ])
  85 AC_ARG_ENABLE(sandbox-setgid,
  86                 [  --enable-sandbox-setgid=GROUP    non-privileged group for captive-sandbox-server (def.=captive)],
  87                 [ CAPTIVE_SANDBOX_SETGID="$enableval" ],[ CAPTIVE_SANDBOX_SETGID="captive" ])
  88 AC_ARG_ENABLE(sandbox-chroot,
  89                 [  --enable-sandbox-chroot=DIR      root-owned directory for captive-sandbox-server (def.=/var/lib/captive)],
  90                 [ CAPTIVE_SANDBOX_CHROOT="$enableval" ],[ CAPTIVE_SANDBOX_CHROOT="/var/lib/captive" ])
  91 AC_ARG_ENABLE(bug-replay,
  92                 [  --enable-bug-replay=no/yes/auto  compile debugging tool (def.=auto)],,enable_bug_replay=auto)
  93 AC_ARG_ENABLE(lufs,
  94                 [  --enable-lufs=no/yes/auto        compile LUFS filesystem module (def.=auto)],,enable_lufs=auto)
  95 AC_ARG_ENABLE(install-pkg,
  96                 [  --enable-install-pkg=no/yes/auto compile installation utils (def.=auto)],,enable_install_pkg=auto)
  97
  98
  99 # AC_ARG_ENABLE(sbin-mountdir,[--enable-sbin-mountdir=DIR],,[enable_sbin_mountdir="/sbin"])
 100 AM_CONDITIONAL(ENABLE_SBIN_MOUNT,[test "$enable_sbin_mount" != "no"])
 101 AC_SUBST(enable_sbin_mountdir)
 102
 103 # AC_ARG_ENABLE(sbin-mount-fs,[--enable-sbin-mount-fs=FS1:FS2],,[enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd"])
 104 AC_SUBST(enable_sbin_mount_fs)
 105
 106 # AC_ARG_ENABLE(sandbox-setuid,[--enable-sandbox-setuid=USER],,[CAPTIVE_SANDBOX_SETUID="captive"])
 107 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETUID,"$CAPTIVE_SANDBOX_SETUID",
 108                 [non-privileged user  for captive-sandbox-server])
 109 AC_SUBST(CAPTIVE_SANDBOX_SETUID)
 110
 111 # AC_ARG_ENABLE(sandbox-setgid,[--enable-sandbox-setgid=GROUP],,[CAPTIVE_SANDBOX_SETGID="captive"])
 112 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETGID,"$CAPTIVE_SANDBOX_SETGID",
 113                 [non-privileged group for captive-sandbox-server])
 114 AC_SUBST(CAPTIVE_SANDBOX_SETGID)
 115
 116 # AC_ARG_ENABLE(sandbox-chroot,[--enable-sandbox-chroot=DIR],,[CAPTIVE_SANDBOX_CHROOT="/var/lib/captive"])
 117 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_CHROOT,"$CAPTIVE_SANDBOX_CHROOT",
 118                 [root-owned directory for captive-sandbox-server])
 119 AC_SUBST(CAPTIVE_SANDBOX_CHROOT)
 120
 121 dnl Permit 'if NEVER' for Makefile.am-s; symbol 'FALSE' forbidden by automake
 122 AM_CONDITIONAL(NEVER,false)
 123
 124 PERL=
 125 AC_PATH_PROGS(PERL,perl5 perl)
 126 if test '!' -f ./src/libcaptive/ke/exports.c -a -z "$PERL";then
 127         AC_MSG_ERROR([perl(1) required as './src/libcaptive/ke/exports.c' is not found.])
 128 fi
 129 AM_CONDITIONAL(HAVE_PERL,test -n "$PERL")
 130
 131 POD2MAN=
 132 AC_PATH_PROGS(POD2MAN,pod2man)
 133 AM_CONDITIONAL(HAVE_POD2MAN,[ test -n "$POD2MAN" ])
 134 if test x$enable_man_pages = xyes;then
 135         if test -z "$POD2MAN";then
 136                 AC_MSG_ERROR([captive requires pod2man(1) for man pages; try --disable-man-pages.])
 137         fi
 138         if test -z "$PERL";then
 139                 AC_MSG_ERROR([captive requires perl(1) for man pages; try --disable-man-pages.])
 140         fi
 141 elif test x$enable_man_pages != xno;then
 142         if test -z "$POD2MAN";then
 143                 AC_MSG_WARN([captive requires pod2man(1) for man pages by --enable-man-pages; mans will not be installed.])
 144         fi
 145         if test -z "$PERL";then
 146                 AC_MSG_WARN([captive requires perl(1) for man pages by --enable-man-pages; mans will not be installed.])
 147         fi
 148 fi
 149 AM_CONDITIONAL(ENABLE_MAN_PAGES,[ test x$enable_man_pages != xno -a -n "$POD2MAN" -a -n "$PERL" ])
 150
 151 dnl Separate 'acconfig.h' is no longer recommended by autoconf
 152 AH_TOP([
 153 #ifndef _CAPTIVE_CONFIG_H
 154 #define _CAPTIVE_CONFIG_H 1
 155 ])
 156 AH_BOTTOM([
 157 /* Do not place any stuff to AH_TOP as some of its includes
 158  * would discard the effect of _FILE_OFFSET_BITS by AC_SYS_LARGEFILE.
 159  */
 160
 161 #ifdef ENABLE_NLS
 162 /* <libintl.h> is taken from "$(top_srcdir)/intl" if system doesn't provide intl */
 163 #       include <libintl.h>
 164 #ifdef LIBCAPTIVE
 165 #       define _(String) dgettext (PACKAGE,String)
 166 #else
 167 #       define _(String) gettext (String)
 168 #endif /* LIBCAPTIVE */
 169 #       ifdef gettext_noop
 170 #               define N_(String) gettext_noop (String)
 171 #       else
 172 #               define N_(String) (String)
 173 #       endif
 174 #else /* !ENABLE_NLS */
 175 /* Stubs that do something close enough.  */
 176 #       define textdomain(String) (String)
 177 #       define gettext(String) (String)
 178 #       define dgettext(Domain,Message) (Message)
 179 #       define dcgettext(Domain,Message,Type) (Message)
 180 #       define bindtextdomain(Domain,Directory) (Domain)
 181 #       define _(String) (String)
 182 #       define N_(String) (String)
 183 #endif /* !ENABLE_NLS */
 184
 185 #include <glib/gtypes.h>        /* for 'gchar' */
 186 #define G_LOG_DOMAIN ((const gchar *)"Captive")
 187
 188 /* Ensure we have proper -I options: */
 189 #if defined(CAPTIVE_USE_GNOME_VFS_MODULE) || defined(CAPTIVE_USE_GNOME_VFS)
 190 #ifndef HAVE_GNOME_VFS_READ_ENTIRE_FILE
 191 #include <libgnomevfs/gnome-vfs-result.h>
 192 GnomeVFSResult gnome_vfs_read_entire_file(const char *uri,int *file_size,char **file_contents);
 193 #endif
 194 #endif
 195
 196 /* Supplemental definitions not possible in this file. */
 197 #ifdef LIBCAPTIVE
 198 #include "captive/config2.h"
 199 #endif
 200
 201 #endif /* !_CAPTIVE_CONFIG_H */
 202 ])
 203
 204 dnl Do not use PKG_CHECK_MODULES() as it would not set 'GLIB_GENMARSHAL' etc.
 205 AM_PATH_GLIB_2_0(,,[AC_MSG_ERROR([Captive requires glib-2.0 library.])],[gmodule gobject gthread])
 206 dnl Force glib for the whole package
 207 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 208 LIBS="$LIBS $GLIB_LIBS"
 209
 210 dnl popt
 211 AC_CHECK_LIB(popt,poptParseArgvString,[POPT_LIBS="-lpopt"],[AC_MSG_ERROR([Captive requires popt library.])])
 212 AC_SUBST(POPT_LIBS)
 213
 214 AC_ARG_WITH(readline,[  --with-readline=[no/yes/auto]   clients with line editing (def.=auto)],,with_readline=auto)
 215 AC_CHECK_HEADERS(readline/history.h)
 216 dnl Check for libraries, if needed by configuration options.
 217 if test "$with_readline" != "no"
 218 then
 219         if test -d "/usr/lib/termcap"
 220         then
 221                 READLINE_LDFLAGS="$READLINE_LDFLAGS -L/usr/lib/termcap"
 222         fi
 223         have_libreadline=false
 224         need_failed=""
 225         for need in "" termcap ncurses; do
 226                 if test "x$need" != "x"
 227                 then
 228                         captive_save_LIBS="$LIBS"
 229                         AC_CHECK_LIB($need,main,,
 230                                 [ need_failed="$need_failed $need"
 231                                 continue ]
 232                                 )
 233                         LIBS="$captive_save_LIBS"
 234                         lneed="-l$need"
 235                 else
 236                         lneed=""
 237                 fi
 238                 dnl Prevent AC_CHECK_LIB() here as it would _cache_ the value ignoring
 239                 dnl our ever-changing "additiona libraries" parameter
 240                 captive_save_LIBS="$LIBS"
 241                 LIBS="-lreadline $lneed $READLINE_LIBS"
 242                 AC_TRY_LINK(,[ main() ],
 243                         [ have_libreadline=true
 244                         READLINE_LIBS="$LIBS" ])
 245                 LIBS="$captive_save_LIBS"
 246                 if $have_libreadline
 247                 then
 248                         break
 249                 fi
 250         done
 251         if $have_libreadline
 252         then
 253                 AC_DEFINE(HAVE_LIBREADLINE,,[Use functions from libreadline?])
 254                 AC_CHECK_LIB(readline,add_history,
 255                         AC_DEFINE(HAVE_ADD_HISTORY,,[Use 'history' extension of libreadline?]),,
 256                         $READLINE_LIBS)
 257         else
 258                 for need in $need_failed; do
 259                         AC_MSG_WARN(captive recommends $need library as your readline library
 260                         probably needs it.)
 261                 done
 262                 if test "$with_readline" = "yes"
 263                 then
 264                         AC_MSG_ERROR([captive did not find the requested readline library for its client line editing capability.])
 265                 else
 266                         AC_MSG_WARN([captive recommends readline library for its client line editing capability.])
 267                 fi
 268         fi
 269 fi
 270 AC_SUBST(READLINE_LIBS)
 271 AC_SUBST(READLINE_LDFLAGS)
 272
 273 PKG_CHECK_MODULES(GNOME_VFS_MODULE,gnome-vfs-module-2.0)
 274 GNOME_VFS_MODULE_CFLAGS="$GNOME_VFS_MODULE_CFLAGS -DCAPTIVE_USE_GNOME_VFS_MODULE=1"
 275 AC_SUBST(GNOME_VFS_MODULE_CFLAGS)
 276 AC_SUBST(GNOME_VFS_MODULE_LIBS)
 277 PKG_CHECK_MODULES(GNOME_VFS,gnome-vfs-2.0)
 278 GNOME_VFS_CFLAGS="$GNOME_VFS_CFLAGS -DCAPTIVE_USE_GNOME_VFS=1"
 279 AC_SUBST(GNOME_VFS_CFLAGS)
 280 AC_SUBST(GNOME_VFS_LIBS)
 281
 282 # AC_ARG_ENABLE(bug-replay,[--enable-bug-replay=[no/yes/auto]],,enable_bug_replay=auto)
 283 dnl Check for 2.5.9 for: http://bugzilla.gnome.org/show_bug.cgi?id=117702
 284 dnl Check the version - impossible to reliably check the missing feature.
 285 PKG_CHECK_MODULES(LIBXML,libxml-2.0 >= 2.5.9,[ have_libxml_buffering=true ],[
 286         dnl Disable bug-replay(1) build if not met; --bug-pathname would be still OK.
 287         PKG_CHECK_MODULES(LIBXML,libxml-2.0,[ have_libxml_buffering=false ])
 288         ])
 289 dnl We also condition 'HAVE_LIBXML_XMLREADER_H' by 'HAVE_LIBXML_BUFFERING'
 290 dnl as we have no use for xmlreader without working libxml buffering of 2.5.9.
 291 AM_CONDITIONAL(ENABLE_BUG_REPLAY,[$have_libxml_buffering && test x$enable_bug_replay != xno])
 292 if $have_libxml_buffering;then
 293         AC_DEFINE(HAVE_LIBXML_BUFFERING,,[libxml2 correctly reads textnodes by its xmlTextReader.])
 294 else
 295         if test x$enable_bug_replay = xyes;then
 296                 AC_MSG_ERROR([captive require libxml2 at least 2.5.9 for --enable-bug-replay feature.])
 297         elif test x$enable_bug_replay != xno;then
 298                 AC_MSG_WARN([libxml2 at least 2.5.9 required --enable-bug-replay feature; disabled now.])
 299         fi
 300 fi
 301 AC_SUBST(LIBXML_CFLAGS)
 302 AC_SUBST(LIBXML_LIBS)
 303
 304 PKG_CHECK_MODULES(OPENSSL,openssl,,[
 305         dnl At least Debian-3.0r1 has openssl but without its .pc module.
 306         AC_CHECK_LIB(crypto,MD5,[
 307                 OPENSSL_CFLAGS=""
 308                 OPENSSL_LIBS="-lcrypto"
 309                 ],[AC_MSG_ERROR([Captive requires crypto library (of openssl).])])
 310         ])
 311 AC_SUBST(OPENSSL_CFLAGS)
 312 AC_SUBST(OPENSSL_LIBS)
 313
 314 # AC_ARG_ENABLE(lufs,[--enable-lufs=[no/yes/auto]],,enable_lufs=auto)
 315 have_lufs_includes=false
 316 # Although it would be more appropriate to use lufsmount(1) instead of lufsd(1)
 317 # we use lufsd(1) as lufsmount(1) is just a dumb wrapper and it would cost us
 318 # another big binary file for the static build package version.
 319 PATH_LUFSD=""
 320 if test x$enable_lufs != no;then
 321         have_lufs_includes=true
 322         dnl If ACTION-IF-NOT-FOUND is given, it is executed when one of the header
 323         dnl files is not found.
 324         AC_CHECK_HEADERS(lufs/fs.h lufs/proto.h,,[ have_lufs_includes=false ])
 325         if test x$have_lufs_includes = xfalse;then
 326                 if test x$enable_lufs = xyes;then
 327                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 328                 else
 329                         AC_MSG_WARN([LUFS client not being compiled as no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 330                 fi
 331         fi
 332         AC_CHECK_TYPES([struct lufs_sbattr],,[
 333                 dnl FIXME: Include 'lufs' version when 'lufs_sbattr' gets integrated:
 334                 if $have_lufs_includes && test x$enable_lufs = xyes;then
 335                         AC_MSG_ERROR([Although LUFS include files were found they are too old. You may also use --enable-lufs=auto.])
 336                 else
 337                         AC_MSG_WARN([Although LUFS include files were found they are too old. df(1) will not show available NTFS disk space.])
 338                 fi
 339                 ],[#include <lufs/proto.h>])
 340         AC_PATH_PROGS(PATH_LUFSD,lufsd)
 341         if test x$PATH_LUFSD = x;then
 342                 if test x$enable_lufs = xyes;then
 343                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no lufsd(1) binary was found. Install 'lufs-*-*captive*' package.])
 344                 else
 345                         AC_MSG_WARN([LUFS client not being compiled as no lufsd(1) binary was found. Install 'lufs-*-*captive*' package.])
 346                 fi
 347         fi
 348 fi
 349 AM_CONDITIONAL(ENABLE_LUFS,[ $have_lufs_includes && test x$PATH_LUFSD != x -a x$enable_lufs != no ])
 350 AC_SUBST(PATH_LUFSD)
 351
 352 dnl for $(top_srcdir)/src/libcaptive/client/
 353 dnl Do not use '[client server]' as $4 to prevent: configure: test: too many arguments
 354 dnl  - currently this argument is not used by 'orbit2-config' in any way anyway
 355 dnl Do not use PKG_CHECK_MODULES() as it would not set 'ORBIT_IDL' etc.
 356 AM_PATH_ORBIT2(,,[AC_MSG_ERROR([Captive requires ORBit2 library.])])
 357
 358 AC_ARG_WITH(orbit-line,[  --with-orbit-line=[link/linc/auto]    Use 'link' for ORBit2 >=2.7.x+ (def.=auto)],,with_orbit_line=auto)
 359 captive_save_CFLAGS="$CFLAGS"
 360 captive_save_LIBS="$LIBS"
 361 CFLAGS="$CFLAGS $ORBIT_CFLAGS"
 362 LIBS="$LIBS $ORBIT_LIBS"
 363 AC_CHECK_FUNC(link_get_tmpdir,[
 364                 AC_DEFINE(HAVE_ORBIT_LINK,,[ORBit2 is 2.7.x+ and therefore includes its own 'link' library])
 365                 found_orbit_line=link
 366                 ],
 367         found_orbit_line=linc
 368         )
 369 CFLAGS="$captive_save_CFLAGS"
 370 LIBS="$captive_save_LIBS"
 371 if test "x$with_orbit_line" != "xauto" -a "x$with_orbit_line" != "x$found_orbit_line";then
 372         AC_MSG_ERROR([--with-orbit-line=$with_orbit_line specified but the detected line is $found_orbit_line])
 373 fi
 374
 375 if test "x$found_orbit_line" = "xlinc";then
 376         PKG_CHECK_MODULES(LINC,linc)
 377 fi
 378
 379 # AC_ARG_ENABLE(install-pkg,[--enable-install-pkg=[no/yes/auto]],,enable_install_pkg=auto)
 380 GLADE_W_INIT([
 381         ./src/install/acquire/ui-gnome-interface.c
 382         ./src/install/acquire/ui-gnome-interface.h
 383         ./src/install/acquire/ui-gnome-callbacks.h
 384         ./src/install/acquire/ui-gnome-support.c
 385         ./src/install/acquire/ui-gnome-support.h
 386         ],[$enable_install_pkg],[
 387                 AC_CHECK_LIB(ntfs,ntfs_mount,[
 388                         LIBNTFS_LIBS="-lntfs"
 389
 390                         have_libntfs_includes=true
 391                         AC_CHECK_HEADERS
 392                         # '#include "config.h"' may be required by <ntfs/*> include files.
 393                         # "config.h" may be already present while not yet being compilable.
 394                         rm -f config.h-ntfs_save
 395                         mv -f config.h config.h-ntfs_save 2>/dev/null
 396                         touch config.h
 397                         captive_save_CPPFLAGS="$CPPFLAGS"
 398                         CPPFLAGS="$CPPFLAGS -I."        # for "config.h" touched above
 399                         AC_CHECK_HEADERS(ntfs/types.h ntfs/volume.h,,[ have_libntfs_includes=false ])
 400                         CPPFLAGS="$captive_save_CPPFLAGS"
 401                         rm -f config.h
 402                         mv -f config.h-ntfs_save config.h 2>/dev/null
 403                         if $have_libntfs_includes;then
 404
 405                                 captive_save_CPPFLAGS="$CPPFLAGS"
 406                                 CPPFLAGS="$CPPFLAGS $LIBXML_CFLAGS"
 407                                 AC_CHECK_HEADERS(libxml/xmlreader.h,
 408                                         [ glade_addon=yes ],
 409                                         [ AC_MSG_WARN([Captive requires libxml >= 2.4.29 for --enable-install-pkg.]) ])
 410                                 CPPFLAGS="$captive_save_CPPFLAGS"
 411
 412                         else
 413                                 AC_MSG_WARN([Captive requires ntfs/* include files (of ntfsprogs-devel) for --enable-install-pkg.])
 414                         fi
 415                         ],[ AC_MSG_WARN([Captive requires libntfs (of ntfsprogs-devel) for --enable-install-pkg.]) ])
 416                 ])
 417 AC_SUBST(GNOMEUI_CFLAGS)
 418 AC_SUBST(GNOMEUI_LIBS)
 419 AC_SUBST(LIBNTFS_LIBS)
 420 dnl Do not: AM_CONDITIONAL(HAVE_LIBNTFS,[ test -n "$LIBNTFS_LIBS" ])
 421 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 422 AM_CONDITIONAL(HAVE_GLADE_WRITESOURCE,[ test "x$PATH_GLADE" != "x" ])
 423 dnl Do not: AM_CONDITIONAL(BUILD_GLADESRC,[ test "xyes" = "x$BUILD_GLADESRC" ])
 424 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 425 GNOME_ADDON_LIBS=""
 426 if test "x$BUILD_GLADESRC_TRUE" = "x"
 427 then
 428         AC_CHECK_LIB(Xi,XOpenDevice,GNOME_ADDON_LIBS="$GNOME_ADDON_LIBS -lXi")
 429 fi
 430 AC_SUBST(GNOME_ADDON_LIBS)
 431 dnl $BUILD_GLADESRC is already conditioned by $enable_install_pkg by GLADE_W_INIT()
 432 AM_CONDITIONAL(ENABLE_INSTALL_PKG,[ test "xyes" = "x$BUILD_GLADESRC" ])
 433
 434 dnl Do not use AC_REPLACE_FUNCS() as we need to link it selectively:
 435 GNOME_VFS_READ_ENTIRE_FILE_O=""
 436 captive_save_CFLAGS="$CFLAGS"
 437 captive_save_LIBS="$LIBS"
 438 CFLAGS="$CFLAGS $GNOME_VFS_MODULE_CFLAGS"
 439 LIBS="$LIBS $GNOME_VFS_MODULE_LIBS"
 440 AC_CHECK_FUNCS(gnome_vfs_read_entire_file,,
 441         [ GNOME_VFS_READ_ENTIRE_FILE_O='gnome_vfs_read_entire_file.$(OBJEXT)' ])
 442 CFLAGS="$captive_save_CFLAGS"
 443 LIBS="$captive_save_LIBS"
 444 AC_SUBST(GNOME_VFS_READ_ENTIRE_FILE_O)
 445
 446 AC_SUBST(CFLAGS)
 447 AC_SUBST(LIBS)
 448
 449 dnl "Makefile" output files MUST have pathnames incl./excl. "./" prefix as specified!
 450 dnl FIXME: Why the rule above was written here?
 451 AC_OUTPUT([
 452 captive.spec
 453 ./src/libcaptive/captive.pod.pl
 454 ./src/libcaptive/client/options.pod.pl
 455 ./src/client/cmdline/captive-cmdline.pod.pl
 456 ./src/client/lufs/lufs-captivefs.pod.pl
 457 ./src/client/lufs/mount.captive.pod.pl
 458 ./src/client/lufs/mount.captive
 459 ./src/client/sandbox-server/captive-sandbox-server.pod.pl
 460 ./src/install/fstab/captive-install-fstab.pod.pl
 461 ./src/install/acquire/captive-install-acquire.pod.pl
 462 ./src/client/gnomevfs/captive.conf
 463 ./po/Makefile.in
 464 ./macros/glade-w.sh
 465 ./debian/changelog
 466 Makefile
 467 ./macros/Makefile
 468 ./src/Makefile
 469 ./src/libcaptive/Makefile
 470 ./src/libcaptive/include/Makefile
 471 ./src/libcaptive/include/captive/Makefile
 472 ./src/libcaptive/include/reactos/Makefile
 473 ./src/libcaptive/include/reactos/ddk/Makefile
 474 ./src/libcaptive/include/reactos/ddk/i386/Makefile
 475 ./src/libcaptive/include/reactos/internal/Makefile
 476 ./src/libcaptive/include/reactos/internal/i386/Makefile
 477 ./src/libcaptive/include/reactos/napi/Makefile
 478 ./src/libcaptive/include/reactos/ntos/Makefile
 479 ./src/libcaptive/reactos/Makefile
 480 ./src/libcaptive/reactos/include/Makefile
 481 ./src/libcaptive/reactos/hal/Makefile
 482 ./src/libcaptive/reactos/hal/halx86/Makefile
 483 ./src/libcaptive/reactos/ntoskrnl/Makefile
 484 ./src/libcaptive/reactos/ntoskrnl/dbg/Makefile
 485 ./src/libcaptive/reactos/ntoskrnl/ex/Makefile
 486 ./src/libcaptive/reactos/ntoskrnl/fs/Makefile
 487 ./src/libcaptive/reactos/ntoskrnl/io/Makefile
 488 ./src/libcaptive/reactos/ntoskrnl/ke/Makefile
 489 ./src/libcaptive/reactos/ntoskrnl/ldr/Makefile
 490 ./src/libcaptive/reactos/ntoskrnl/mm/Makefile
 491 ./src/libcaptive/reactos/ntoskrnl/nt/Makefile
 492 ./src/libcaptive/reactos/ntoskrnl/ob/Makefile
 493 ./src/libcaptive/reactos/ntoskrnl/ps/Makefile
 494 ./src/libcaptive/reactos/ntoskrnl/rtl/Makefile
 495 ./src/libcaptive/reactos/ntoskrnl/rtl/i386/Makefile
 496 ./src/libcaptive/reactos/ntoskrnl/se/Makefile
 497 ./src/libcaptive/halcaptive/Makefile
 498 ./src/libcaptive/cc/Makefile
 499 ./src/libcaptive/cm/Makefile
 500 ./src/libcaptive/ex/Makefile
 501 ./src/libcaptive/fs/Makefile
 502 ./src/libcaptive/io/Makefile
 503 ./src/libcaptive/kd/Makefile
 504 ./src/libcaptive/ke/Makefile
 505 ./src/libcaptive/ldr/Makefile
 506 ./src/libcaptive/mm/Makefile
 507 ./src/libcaptive/nt/Makefile
 508 ./src/libcaptive/ob/Makefile
 509 ./src/libcaptive/po/Makefile
 510 ./src/libcaptive/ps/Makefile
 511 ./src/libcaptive/rtl/Makefile
 512 ./src/libcaptive/se/Makefile
 513 ./src/libcaptive/storage/Makefile
 514 ./src/libcaptive/sandbox/Makefile
 515 ./src/libcaptive/client/Makefile
 516 ./src/client/Makefile
 517 ./src/client/bug-replay/Makefile
 518 ./src/client/cmdline/Makefile
 519 ./src/client/gnomevfs/Makefile
 520 ./src/client/lufs/Makefile
 521 ./src/client/sandbox-server/Makefile
 522 ./src/install/Makefile
 523 ./src/install/libcaptive-install/Makefile
 524 ./src/install/fstab/Makefile
 525 ./src/install/acquire/Makefile
 526 ./src/TraceFS/Makefile
 527 ./src/w32-mod/Makefile
 528 ./doc/Makefile
 529 ./doc/apiref/Makefile
 530 ])
 531
 532 dnl FIXME: Why is "po/POTFILES" being substituted?
 533 make -C src distfiles DISTFILES_PRINT=1 \
 534                 |sed -n 's/^:DISTFILES: *\(.*\)$/\1/p'|tr ' ' '\n'|grep . >po/POTFILES.in
 535 make -C po Makefile
 536
 537 echo done.