configure.in

   1 # $Id$
   2 # Source file to generate "./configure" to prepare package for compilation
   3 # Copyright (C) 2002-2003 Jan Kratochvil <project-captive@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 AC_INIT(src/libcaptive/Makefile-libcaptive.am)
  20 dnl 2.53 for AM_GLIB_GNU_GETTEXT:
  21 AC_PREREQ(2.53)
  22 AM_INIT_AUTOMAKE(captive,1.0.2cvs)
  23 AM_CONFIG_HEADER(config.h)
  24 AM_MAINTAINER_MODE
  25 dnl Call AC_PROG_CC before AC_ISC_POSIX.
  26 AC_PROG_CC(gcc3 gcc-3.0 gcc cc)
  27 AC_TRY_CPP([
  28 #if __GNUC__ >= 3
  29 #else
  30 #error "GCC version 3.0+ required at least for ReactOS anonymous unions"
  31 #endif
  32 ],,[AC_MSG_ERROR([Captive requires GCC version 3.0+.])])
  33 dnl Prevent "AC_TRY_COMPILE was called before AC_ISC_POSIX":
  34 AC_ISC_POSIX
  35 AC_SYS_LARGEFILE
  36 AM_PROG_AS
  37 AM_DISABLE_STATIC
  38 AM_ENABLE_SHARED
  39 AM_PROG_LIBTOOL
  40
  41 dnl Workaround for autoconf-2.57:
  42 m4_pattern_allow([AC_MSG_WARN])
  43 m4_pattern_allow([AC_CHECK_LIB])
  44 m4_pattern_allow([AC_CHECK_HEADERS])
  45
  46 dnl gettext localization.
  47 dnl Use simpler AM_GLIB_GNU_GETTEXT instead of AM_GNU_GETTEXT
  48 dnl as we depend on glib and glib requires system installed gettext anyway.
  49 dnl http://lists.gnome.org/archives/gtk-devel-list/2003-April/msg00066.html
  50 dnl Special 'GETTEXT_PACKAGE' is required by glib gettext.
  51 ALL_LINGUAS="cs"
  52 GETTEXT_PACKAGE="$PACKAGE"
  53 AC_SUBST(GETTEXT_PACKAGE)
  54 AM_GLIB_GNU_GETTEXT
  55
  56 GTK_DOC_CHECK
  57 dnl AM_CONDITIONAL needs to be here explicitely for doc/apiref/Makefile rebuild
  58 AM_CONDITIONAL(ENABLE_GTK_DOC,[test x$enable_gtk_doc = xyes])
  59 AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL,[test -n "$LIBTOOL"])
  60
  61 dnl Do not discard 'CFLAGS' settings as they may have been passed us by rpmbuild(8)
  62
  63 dnl Define MAINTAINER_MODE in config.h.
  64 if test "$USE_MAINTAINER_MODE" = "yes";then
  65         AC_DEFINE(MAINTAINER_MODE,,[Turn even some software behaviour according to MAINTAINER_MODE.])
  66         CFLAGS="$CFLAGS -ggdb3 -Wall -Wstrict-prototypes -Wsign-compare"  ## FIXME: fix all sources: -Wsign-compare
  67         fi
  68 dnl Some Makefiles use additional tests etc.
  69 AM_CONDITIONAL(MAINTAINER_MODE,[test "$USE_MAINTAINER_MODE" = "yes"])
  70
  71
  72 AC_ARG_ENABLE(man-pages,
  73                 [  --enable-man-pages=no/yes/auto   pod2man(1) required for man pages (def.=yes)],,enable_man_pages=yes)
  74 AC_ARG_ENABLE(sbin-mountdir,
  75                 [  --enable-sbin-mountdir=DIR       mount(8) 'mount.captive' directory (def.=/sbin)],,
  76                 [ enable_sbin_mountdir="/sbin" ])
  77 AC_ARG_ENABLE(sbin-mount-fs,
  78                 [  --enable-sbin-mount-fs=FS1:FS2   sbin-mount pre-installed symlinks (def.=ntfs:fastfat:cdfs:ext2fsd)],,
  79                 [ enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd" ])
  80 AC_ARG_ENABLE(sandbox-setuid,
  81                 [  --enable-sandbox-setuid=USER     non-privileged user  for captive-sandbox-server (def.=captive)],
  82                 [ CAPTIVE_SANDBOX_SETUID="$enableval" ],[ CAPTIVE_SANDBOX_SETUID="captive" ])
  83 AC_ARG_ENABLE(sandbox-setgid,
  84                 [  --enable-sandbox-setgid=GROUP    non-privileged group for captive-sandbox-server (def.=captive)],
  85                 [ CAPTIVE_SANDBOX_SETGID="$enableval" ],[ CAPTIVE_SANDBOX_SETGID="captive" ])
  86 AC_ARG_ENABLE(sandbox-chroot,
  87                 [  --enable-sandbox-chroot=DIR      root-owned directory for captive-sandbox-server (def.=/var/lib/captive)],
  88                 [ CAPTIVE_SANDBOX_CHROOT="$enableval" ],[ CAPTIVE_SANDBOX_CHROOT="/var/lib/captive" ])
  89 AC_ARG_ENABLE(bug-replay,
  90                 [  --enable-bug-replay=no/yes/auto  compile debugging tool (def.=auto)],,enable_bug_replay=auto)
  91 AC_ARG_ENABLE(lufs,
  92                 [  --enable-lufs=no/yes/auto        compile LUFS filesystem module (def.=auto)],,enable_lufs=auto)
  93 AC_ARG_ENABLE(install-pkg,
  94                 [  --enable-install-pkg=no/yes/auto compile installation utils (def.=auto)],,enable_install_pkg=auto)
  95
  96
  97 # AC_ARG_ENABLE(sbin-mountdir,[--enable-sbin-mountdir=DIR],,[enable_sbin_mountdir="/sbin"])
  98 AM_CONDITIONAL(ENABLE_SBIN_MOUNT,[test "$enable_sbin_mount" != "no"])
  99 AC_SUBST(enable_sbin_mountdir)
 100
 101 # AC_ARG_ENABLE(sbin-mount-fs,[--enable-sbin-mount-fs=FS1:FS2],,[enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd"])
 102 AC_SUBST(enable_sbin_mount_fs)
 103
 104 # AC_ARG_ENABLE(sandbox-setuid,[--enable-sandbox-setuid=USER],,[CAPTIVE_SANDBOX_SETUID="captive"])
 105 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETUID,"$CAPTIVE_SANDBOX_SETUID",
 106                 [non-privileged user  for captive-sandbox-server])
 107
 108 # AC_ARG_ENABLE(sandbox-setgid,[--enable-sandbox-setgid=GROUP],,[CAPTIVE_SANDBOX_SETGID="captive"])
 109 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETGID,"$CAPTIVE_SANDBOX_SETGID",
 110                 [non-privileged group for captive-sandbox-server])
 111
 112 # AC_ARG_ENABLE(sandbox-chroot,[--enable-sandbox-chroot=DIR],,[CAPTIVE_SANDBOX_CHROOT="/var/lib/captive"])
 113 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_CHROOT,"$CAPTIVE_SANDBOX_CHROOT",
 114                 [root-owned directory for captive-sandbox-server])
 115 AC_SUBST(CAPTIVE_SANDBOX_CHROOT)
 116
 117 dnl Permit 'if NEVER' for Makefile.am-s; symbol 'FALSE' forbidden by automake
 118 AM_CONDITIONAL(NEVER,false)
 119
 120 PERL=
 121 AC_PATH_PROGS(PERL,perl5 perl)
 122 if test '!' -f ./src/libcaptive/ke/exports.c -a -z "$PERL";then
 123         AC_MSG_ERROR([perl(1) required as './src/libcaptive/ke/exports.c' is not found.])
 124 fi
 125 AM_CONDITIONAL(HAVE_PERL,test -n "$PERL")
 126
 127 POD2MAN=
 128 AC_PATH_PROGS(POD2MAN,pod2man)
 129 AM_CONDITIONAL(HAVE_POD2MAN,[ test -n "$POD2MAN" ])
 130 if test x$enable_man_pages = xyes;then
 131         if test -z "$POD2MAN";then
 132                 AC_MSG_ERROR([captive requires pod2man(1) for man pages; try --disable-man-pages.])
 133         fi
 134         if test -z "$PERL";then
 135                 AC_MSG_ERROR([captive requires perl(1) for man pages; try --disable-man-pages.])
 136         fi
 137 elif test x$enable_man_pages != xno;then
 138         if test -z "$POD2MAN";then
 139                 AC_MSG_WARN([captive requires pod2man(1) for man pages by --enable-man-pages; mans will not be installed.])
 140         fi
 141         if test -z "$PERL";then
 142                 AC_MSG_WARN([captive requires perl(1) for man pages by --enable-man-pages; mans will not be installed.])
 143         fi
 144 fi
 145 AM_CONDITIONAL(ENABLE_MAN_PAGES,[ test x$enable_man_pages != xno -a -n "$POD2MAN" -a -n "$PERL" ])
 146
 147 dnl Separate 'acconfig.h' is no longer recommended by autoconf
 148 AH_TOP([
 149 #ifndef _CAPTIVE_CONFIG_H
 150 #define _CAPTIVE_CONFIG_H 1
 151 ])
 152 AH_BOTTOM([
 153 /* Do not place any stuff to AH_TOP as some of its includes
 154  * would discard the effect of _FILE_OFFSET_BITS by AC_SYS_LARGEFILE.
 155  */
 156
 157 #ifdef ENABLE_NLS
 158 /* <libintl.h> is taken from "$(top_srcdir)/intl" if system doesn't provide intl */
 159 #       include <libintl.h>
 160 #ifdef LIBCAPTIVE
 161 #       define _(String) dgettext (PACKAGE,String)
 162 #else
 163 #       define _(String) gettext (String)
 164 #endif /* LIBCAPTIVE */
 165 #       ifdef gettext_noop
 166 #               define N_(String) gettext_noop (String)
 167 #       else
 168 #               define N_(String) (String)
 169 #       endif
 170 #else /* !ENABLE_NLS */
 171 /* Stubs that do something close enough.  */
 172 #       define textdomain(String) (String)
 173 #       define gettext(String) (String)
 174 #       define dgettext(Domain,Message) (Message)
 175 #       define dcgettext(Domain,Message,Type) (Message)
 176 #       define bindtextdomain(Domain,Directory) (Domain)
 177 #       define _(String) (String)
 178 #       define N_(String) (String)
 179 #endif /* !ENABLE_NLS */
 180
 181 #include <glib/gtypes.h>        /* for 'gchar' */
 182 #define G_LOG_DOMAIN ((const gchar *)"Captive")
 183
 184 /* Ensure we have proper -I options: */
 185 #if defined(CAPTIVE_USE_GNOME_VFS_MODULE) || defined(CAPTIVE_USE_GNOME_VFS)
 186 #ifndef HAVE_GNOME_VFS_READ_ENTIRE_FILE
 187 #include <libgnomevfs/gnome-vfs-result.h>
 188 GnomeVFSResult gnome_vfs_read_entire_file(const char *uri,int *file_size,char **file_contents);
 189 #endif
 190 #endif
 191
 192 /* Supplemental definitions not possible in this file. */
 193 #ifdef LIBCAPTIVE
 194 #include "captive/config2.h"
 195 #endif
 196
 197 #endif /* !_CAPTIVE_CONFIG_H */
 198 ])
 199
 200 dnl Do not use PKG_CHECK_MODULES() as it would not set 'GLIB_GENMARSHAL' etc.
 201 AM_PATH_GLIB_2_0(,,[AC_MSG_ERROR([Captive requires glib-2.0 library.])],[gmodule gobject gthread])
 202 dnl Force glib for the whole package
 203 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 204 LIBS="$LIBS $GLIB_LIBS"
 205
 206 dnl popt
 207 AC_CHECK_LIB(popt,poptParseArgvString,[POPT_LIBS="-lpopt"],[AC_MSG_ERROR([Captive requires popt library.])])
 208 AC_SUBST(POPT_LIBS)
 209
 210 AC_ARG_WITH(readline,[  --with-readline=[no/yes/auto]   clients with line editing (def.=auto)],,with_readline=auto)
 211 AC_CHECK_HEADERS(readline/history.h)
 212 dnl Check for libraries, if needed by configuration options.
 213 if test "$with_readline" != "no"
 214 then
 215         if test -d "/usr/lib/termcap"
 216         then
 217                 READLINE_LDFLAGS="$READLINE_LDFLAGS -L/usr/lib/termcap"
 218         fi
 219         have_libreadline=false
 220         need_failed=""
 221         for need in "" termcap ncurses; do
 222                 if test "x$need" != "x"
 223                 then
 224                         captive_save_LIBS="$LIBS"
 225                         AC_CHECK_LIB($need,main,,
 226                                 [ need_failed="$need_failed $need"
 227                                 continue ]
 228                                 )
 229                         LIBS="$captive_save_LIBS"
 230                         lneed="-l$need"
 231                 else
 232                         lneed=""
 233                 fi
 234                 dnl Prevent AC_CHECK_LIB() here as it would _cache_ the value ignoring
 235                 dnl our ever-changing "additiona libraries" parameter
 236                 captive_save_LIBS="$LIBS"
 237                 LIBS="-lreadline $lneed $READLINE_LIBS"
 238                 AC_TRY_LINK(,[ main() ],
 239                         [ have_libreadline=true
 240                         READLINE_LIBS="$LIBS" ])
 241                 LIBS="$captive_save_LIBS"
 242                 if $have_libreadline
 243                 then
 244                         break
 245                 fi
 246         done
 247         if $have_libreadline
 248         then
 249                 AC_DEFINE(HAVE_LIBREADLINE,,[Use functions from libreadline?])
 250                 AC_CHECK_LIB(readline,add_history,
 251                         AC_DEFINE(HAVE_ADD_HISTORY,,[Use 'history' extension of libreadline?]),,
 252                         $READLINE_LIBS)
 253         else
 254                 for need in $need_failed; do
 255                         AC_MSG_WARN(captive recommends $need library as your readline library
 256                         probably needs it.)
 257                 done
 258                 if test "$with_readline" = "yes"
 259                 then
 260                         AC_MSG_ERROR([captive did not find the requested readline library for its client line editing capability.])
 261                 else
 262                         AC_MSG_WARN([captive recommends readline library for its client line editing capability.])
 263                 fi
 264         fi
 265 fi
 266 AC_SUBST(READLINE_LIBS)
 267 AC_SUBST(READLINE_LDFLAGS)
 268
 269 PKG_CHECK_MODULES(GNOME_VFS_MODULE,gnome-vfs-module-2.0)
 270 GNOME_VFS_MODULE_CFLAGS="$GNOME_VFS_MODULE_CFLAGS -DCAPTIVE_USE_GNOME_VFS_MODULE=1"
 271 AC_SUBST(GNOME_VFS_MODULE_CFLAGS)
 272 AC_SUBST(GNOME_VFS_MODULE_LIBS)
 273 PKG_CHECK_MODULES(GNOME_VFS,gnome-vfs-2.0)
 274 GNOME_VFS_CFLAGS="$GNOME_VFS_CFLAGS -DCAPTIVE_USE_GNOME_VFS=1"
 275 AC_SUBST(GNOME_VFS_CFLAGS)
 276 AC_SUBST(GNOME_VFS_LIBS)
 277
 278 # AC_ARG_ENABLE(bug-replay,[--enable-bug-replay=[no/yes/auto]],,enable_bug_replay=auto)
 279 dnl Check for 2.5.9 for: http://bugzilla.gnome.org/show_bug.cgi?id=117702
 280 dnl Check the version - impossible to reliably check the missing feature.
 281 PKG_CHECK_MODULES(LIBXML,libxml-2.0 >= 2.5.9,[ have_libxml_buffering=true ],[
 282         dnl Disable bug-replay(1) build if not met; --bug-pathname would be still OK.
 283         PKG_CHECK_MODULES(LIBXML,libxml-2.0,[ have_libxml_buffering=false ])
 284         ])
 285 dnl We also condition 'HAVE_LIBXML_XMLREADER_H' by 'HAVE_LIBXML_BUFFERING'
 286 dnl as we have no use for xmlreader without working libxml buffering of 2.5.9.
 287 AM_CONDITIONAL(ENABLE_BUG_REPLAY,[$have_libxml_buffering && test x$enable_bug_replay != xno])
 288 if $have_libxml_buffering;then
 289         AC_DEFINE(HAVE_LIBXML_BUFFERING,,[libxml2 correctly reads textnodes by its xmlTextReader.])
 290 else
 291         if test x$enable_bug_replay = xyes;then
 292                 AC_MSG_ERROR([captive require libxml2 at least 2.5.9 for --enable-bug-replay feature.])
 293         elif test x$enable_bug_replay != xno;then
 294                 AC_MSG_WARN([libxml2 at least 2.5.9 required --enable-bug-replay feature; disabled now.])
 295         fi
 296 fi
 297 AC_SUBST(LIBXML_CFLAGS)
 298 AC_SUBST(LIBXML_LIBS)
 299
 300 PKG_CHECK_MODULES(OPENSSL,openssl,,[
 301         dnl At least Debian-3.0r1 has openssl but without its .pc module.
 302         AC_CHECK_LIB(crypto,MD5,[
 303                 OPENSSL_CFLAGS=""
 304                 OPENSSL_LIBS="-lcrypto"
 305                 ],[AC_MSG_ERROR([Captive requires crypto library (of openssl).])])
 306         ])
 307 AC_SUBST(OPENSSL_CFLAGS)
 308 AC_SUBST(OPENSSL_LIBS)
 309
 310 # AC_ARG_ENABLE(lufs,[--enable-lufs=[no/yes/auto]],,enable_lufs=auto)
 311 have_lufs_includes=false
 312 PATH_LUFSMOUNT=""
 313 if test x$enable_lufs != no;then
 314         have_lufs_includes=true
 315         dnl If ACTION-IF-NOT-FOUND is given, it is executed when one of the header
 316         dnl files is not found.
 317         AC_CHECK_HEADERS(lufs/fs.h lufs/proto.h,,[ have_lufs_includes=false ])
 318         if test x$have_lufs_includes = xfalse;then
 319                 if test x$enable_lufs = xyes;then
 320                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 321                 else
 322                         AC_MSG_WARN([LUFS client not being compiled as no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 323                 fi
 324         fi
 325         AC_CHECK_TYPES([struct lufs_sbattr],,[
 326                 dnl FIXME: Include 'lufs' version when 'lufs_sbattr' gets integrated:
 327                 if $have_lufs_includes && test x$enable_lufs = xyes;then
 328                         AC_MSG_ERROR([Although LUFS include files were found they are too old. You may also use --enable-lufs=auto.])
 329                 else
 330                         AC_MSG_WARN([Although LUFS include files were found they are too old. df(1) will not show available NTFS disk space.])
 331                 fi
 332                 ],[#include <lufs/proto.h>])
 333         AC_PATH_PROGS(PATH_LUFSMOUNT,lufsmount)
 334         if test x$PATH_LUFSMOUNT = x;then
 335                 if test x$enable_lufs = xyes;then
 336                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no lufsmount(1) binary was found. Install 'lufs-*-*captive*' package.])
 337                 else
 338                         AC_MSG_WARN([LUFS client not being compiled as no lufsmount(1) binary was found. Install 'lufs-*-*captive*' package.])
 339                 fi
 340         fi
 341 fi
 342 AM_CONDITIONAL(ENABLE_LUFS,[ $have_lufs_includes && test x$PATH_LUFSMOUNT != x -a x$enable_lufs != no ])
 343 AC_SUBST(PATH_LUFSMOUNT)
 344
 345 dnl for $(top_srcdir)/src/libcaptive/client/
 346 dnl Do not use '[client server]' as $4 to prevent: configure: test: too many arguments
 347 dnl  - currently this argument is not used by 'orbit2-config' in any way anyway
 348 dnl Do not use PKG_CHECK_MODULES() as it would not set 'ORBIT_IDL' etc.
 349 AM_PATH_ORBIT2(,,[AC_MSG_ERROR([Captive requires ORBit2 library.])])
 350
 351 AC_ARG_WITH(orbit-line,[  --with-orbit-line=[link/linc/auto]    Use 'link' for ORBit2 >=2.7.x+ (def.=auto)],,with_orbit_line=auto)
 352 captive_save_CFLAGS="$CFLAGS"
 353 captive_save_LIBS="$LIBS"
 354 CFLAGS="$CFLAGS $ORBIT_CFLAGS"
 355 LIBS="$LIBS $ORBIT_LIBS"
 356 AC_CHECK_FUNC(link_get_tmpdir,[
 357                 AC_DEFINE(HAVE_ORBIT_LINK,,[ORBit2 is 2.7.x+ and therefore includes its own 'link' library])
 358                 found_orbit_line=link
 359                 ],
 360         found_orbit_line=linc
 361         )
 362 CFLAGS="$captive_save_CFLAGS"
 363 LIBS="$captive_save_LIBS"
 364 if test "x$with_orbit_line" != "xauto" -a "x$with_orbit_line" != "x$found_orbit_line";then
 365         AC_MSG_ERROR([--with-orbit-line=$with_orbit_line specified but the detected line is $found_orbit_line])
 366 fi
 367
 368 if test "x$found_orbit_line" = "xlinc";then
 369         PKG_CHECK_MODULES(LINC,linc)
 370 fi
 371
 372 # AC_ARG_ENABLE(install-pkg,[--enable-install-pkg=[no/yes/auto]],,enable_install_pkg=auto)
 373 GLADE_W_INIT([
 374         ./src/install/acquire/ui-gnome-interface.c
 375         ./src/install/acquire/ui-gnome-interface.h
 376         ./src/install/acquire/ui-gnome-callbacks.h
 377         ./src/install/acquire/ui-gnome-support.c
 378         ./src/install/acquire/ui-gnome-support.h
 379         ],[$enable_install_pkg],[
 380                 AC_CHECK_LIB(ntfs,ntfs_mount,[
 381                         LIBNTFS_LIBS="-lntfs"
 382
 383                         have_libntfs_includes=true
 384                         AC_CHECK_HEADERS
 385                         # '#include "config.h"' may be required by <ntfs/*> include files.
 386                         test -r config.h || touch config.h
 387                         captive_save_CPPFLAGS="$CPPFLAGS"
 388                         CPPFLAGS="$CPPFLAGS -I."        # for "config.h" touched above
 389                         AC_CHECK_HEADERS(ntfs/types.h ntfs/volume.h,,[ have_libntfs_includes=false ])
 390                         CPPFLAGS="$captive_save_CPPFLAGS"
 391                         if $have_libntfs_includes;then
 392
 393                                 captive_save_CPPFLAGS="$CPPFLAGS"
 394                                 CPPFLAGS="$CPPFLAGS $LIBXML_CFLAGS"
 395                                 AC_CHECK_HEADERS(libxml/xmlreader.h,
 396                                         [ glade_addon=yes ],
 397                                         [ AC_MSG_WARN([Captive requires libxml >= 2.4.29 for --enable-install-pkg.]) ])
 398                                 CPPFLAGS="$captive_save_CPPFLAGS"
 399
 400                         else
 401                                 AC_MSG_WARN([Captive requires ntfs/* include files (of ntfsprogs-devel) for --enable-install-pkg.])
 402                         fi
 403                         ],[ AC_MSG_WARN([Captive requires libntfs (of ntfsprogs-devel) for --enable-install-pkg.]) ])
 404                 ])
 405 AC_SUBST(GNOMEUI_CFLAGS)
 406 AC_SUBST(GNOMEUI_LIBS)
 407 AC_SUBST(LIBNTFS_LIBS)
 408 dnl Do not: AM_CONDITIONAL(HAVE_LIBNTFS,[ test -n "$LIBNTFS_LIBS" ])
 409 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 410 AM_CONDITIONAL(HAVE_GLADE_WRITESOURCE,[ test "x$PATH_GLADE" != "x" ])
 411 dnl Do not: AM_CONDITIONAL(BUILD_GLADESRC,[ test "xyes" = "x$BUILD_GLADESRC" ])
 412 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 413 GNOME_ADDON_LIBS=""
 414 if test "x$BUILD_GLADESRC_TRUE" = "x"
 415 then
 416         AC_CHECK_LIB(Xi,XOpenDevice,GNOME_ADDON_LIBS="$GNOME_ADDON_LIBS -lXi")
 417 fi
 418 AC_SUBST(GNOME_ADDON_LIBS)
 419 dnl $BUILD_GLADESRC is already conditioned by $enable_install_pkg by GLADE_W_INIT()
 420 AM_CONDITIONAL(ENABLE_INSTALL_PKG,[ test "xyes" = "x$BUILD_GLADESRC" ])
 421
 422 dnl Do not use AC_REPLACE_FUNCS() as we need to link it selectively:
 423 GNOME_VFS_READ_ENTIRE_FILE_O=""
 424 captive_save_CFLAGS="$CFLAGS"
 425 captive_save_LIBS="$LIBS"
 426 CFLAGS="$CFLAGS $GNOME_VFS_MODULE_CFLAGS"
 427 LIBS="$LIBS $GNOME_VFS_MODULE_LIBS"
 428 AC_CHECK_FUNCS(gnome_vfs_read_entire_file,,
 429         [ GNOME_VFS_READ_ENTIRE_FILE_O='gnome_vfs_read_entire_file.$(OBJEXT)' ])
 430 CFLAGS="$captive_save_CFLAGS"
 431 LIBS="$captive_save_LIBS"
 432 AC_SUBST(GNOME_VFS_READ_ENTIRE_FILE_O)
 433
 434 AC_SUBST(CFLAGS)
 435 AC_SUBST(LIBS)
 436
 437 dnl "Makefile" output files MUST have pathnames incl./excl. "./" prefix as specified!
 438 dnl FIXME: Why the rule above was written here?
 439 AC_OUTPUT([
 440 captive.spec
 441 ./src/libcaptive/captive.pod.pl
 442 ./src/libcaptive/client/options.pod.pl
 443 ./src/client/cmdline/captive-cmdline.pod.pl
 444 ./src/client/lufs/lufs-captivefs.pod.pl
 445 ./src/client/lufs/mount.captive.pod.pl
 446 ./src/client/lufs/mount.captive
 447 ./src/client/sandbox-server/captive-sandbox-server.pod.pl
 448 ./src/install/fstab/captive-install-fstab.pod.pl
 449 ./src/install/acquire/captive-install-acquire.pod.pl
 450 ./src/client/gnomevfs/captive.conf
 451 ./po/Makefile.in
 452 ./macros/glade-w.sh
 453 ./debian/changelog
 454 Makefile
 455 ./macros/Makefile
 456 ./src/Makefile
 457 ./src/libcaptive/Makefile
 458 ./src/libcaptive/include/Makefile
 459 ./src/libcaptive/include/captive/Makefile
 460 ./src/libcaptive/include/reactos/Makefile
 461 ./src/libcaptive/include/reactos/ddk/Makefile
 462 ./src/libcaptive/include/reactos/ddk/i386/Makefile
 463 ./src/libcaptive/include/reactos/internal/Makefile
 464 ./src/libcaptive/include/reactos/internal/i386/Makefile
 465 ./src/libcaptive/include/reactos/napi/Makefile
 466 ./src/libcaptive/include/reactos/ntos/Makefile
 467 ./src/libcaptive/reactos/Makefile
 468 ./src/libcaptive/reactos/include/Makefile
 469 ./src/libcaptive/reactos/hal/Makefile
 470 ./src/libcaptive/reactos/hal/halx86/Makefile
 471 ./src/libcaptive/reactos/ntoskrnl/Makefile
 472 ./src/libcaptive/reactos/ntoskrnl/dbg/Makefile
 473 ./src/libcaptive/reactos/ntoskrnl/ex/Makefile
 474 ./src/libcaptive/reactos/ntoskrnl/fs/Makefile
 475 ./src/libcaptive/reactos/ntoskrnl/io/Makefile
 476 ./src/libcaptive/reactos/ntoskrnl/ke/Makefile
 477 ./src/libcaptive/reactos/ntoskrnl/ldr/Makefile
 478 ./src/libcaptive/reactos/ntoskrnl/mm/Makefile
 479 ./src/libcaptive/reactos/ntoskrnl/nt/Makefile
 480 ./src/libcaptive/reactos/ntoskrnl/ob/Makefile
 481 ./src/libcaptive/reactos/ntoskrnl/ps/Makefile
 482 ./src/libcaptive/reactos/ntoskrnl/rtl/Makefile
 483 ./src/libcaptive/reactos/ntoskrnl/rtl/i386/Makefile
 484 ./src/libcaptive/reactos/ntoskrnl/se/Makefile
 485 ./src/libcaptive/halcaptive/Makefile
 486 ./src/libcaptive/cc/Makefile
 487 ./src/libcaptive/cm/Makefile
 488 ./src/libcaptive/ex/Makefile
 489 ./src/libcaptive/fs/Makefile
 490 ./src/libcaptive/io/Makefile
 491 ./src/libcaptive/kd/Makefile
 492 ./src/libcaptive/ke/Makefile
 493 ./src/libcaptive/ldr/Makefile
 494 ./src/libcaptive/mm/Makefile
 495 ./src/libcaptive/nt/Makefile
 496 ./src/libcaptive/ob/Makefile
 497 ./src/libcaptive/po/Makefile
 498 ./src/libcaptive/ps/Makefile
 499 ./src/libcaptive/rtl/Makefile
 500 ./src/libcaptive/se/Makefile
 501 ./src/libcaptive/storage/Makefile
 502 ./src/libcaptive/sandbox/Makefile
 503 ./src/libcaptive/client/Makefile
 504 ./src/client/Makefile
 505 ./src/client/bug-replay/Makefile
 506 ./src/client/cmdline/Makefile
 507 ./src/client/gnomevfs/Makefile
 508 ./src/client/lufs/Makefile
 509 ./src/client/sandbox-server/Makefile
 510 ./src/install/Makefile
 511 ./src/install/libcaptive-install/Makefile
 512 ./src/install/fstab/Makefile
 513 ./src/install/acquire/Makefile
 514 ./src/TraceFS/Makefile
 515 ./src/w32-mod/Makefile
 516 ./doc/Makefile
 517 ./doc/apiref/Makefile
 518 ])
 519
 520 dnl FIXME: Why is "po/POTFILES" being substituted?
 521 make -C src distfiles DISTFILES_PRINT=1 \
 522                 |sed -n 's/^:DISTFILES: *\(.*\)$/\1/p'|tr ' ' '\n'|grep . >po/POTFILES.in
 523 make -C po Makefile
 524
 525 echo done.