configure.in

   1 # $Id$
   2 # Source file to generate "./configure" to prepare package for compilation
   3 # Copyright (C) 2002-2003 Jan Kratochvil <project-captive@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 AC_INIT(src/libcaptive/Makefile-libcaptive.am)
  20 dnl 2.53 for AM_GLIB_GNU_GETTEXT:
  21 AC_PREREQ(2.53)
  22 AM_INIT_AUTOMAKE(captive,1.0.2cvs)
  23 AM_CONFIG_HEADER(config.h)
  24 AM_MAINTAINER_MODE
  25 dnl Call AC_PROG_CC before AC_ISC_POSIX.
  26 AC_PROG_CC(gcc3 gcc-3.0 gcc cc)
  27 AC_TRY_CPP([
  28 #if __GNUC__ >= 3
  29 #else
  30 #error "GCC version 3.0+ required at least for ReactOS anonymous unions"
  31 #endif
  32 ],,[AC_MSG_ERROR([Captive requires GCC version 3.0+.])])
  33 dnl Prevent "AC_TRY_COMPILE was called before AC_ISC_POSIX":
  34 AC_ISC_POSIX
  35 AC_SYS_LARGEFILE
  36 AM_PROG_AS
  37 AM_DISABLE_STATIC
  38 AM_ENABLE_SHARED
  39 AM_PROG_LIBTOOL
  40
  41 dnl gettext localization.
  42 dnl Use simpler AM_GLIB_GNU_GETTEXT instead of AM_GNU_GETTEXT
  43 dnl as we depend on glib and glib requires system installed gettext anyway.
  44 dnl http://lists.gnome.org/archives/gtk-devel-list/2003-April/msg00066.html
  45 dnl Special 'GETTEXT_PACKAGE' is required by glib gettext.
  46 ALL_LINGUAS="cs"
  47 GETTEXT_PACKAGE="$PACKAGE"
  48 AC_SUBST(GETTEXT_PACKAGE)
  49 AM_GLIB_GNU_GETTEXT
  50
  51 GTK_DOC_CHECK
  52 dnl AM_CONDITIONAL needs to be here explicitely for doc/apiref/Makefile rebuild
  53 AM_CONDITIONAL(ENABLE_GTK_DOC,[test x$enable_gtk_doc = xyes])
  54 AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL,[test -n "$LIBTOOL"])
  55
  56 dnl Do not discard 'CFLAGS' settings as they may have been passed us by rpmbuild(8)
  57
  58 dnl Define MAINTAINER_MODE in config.h.
  59 if test "$USE_MAINTAINER_MODE" = "yes";then
  60         AC_DEFINE(MAINTAINER_MODE,,[Turn even some software behaviour according to MAINTAINER_MODE.])
  61         CFLAGS="$CFLAGS -ggdb3 -Wall -Wstrict-prototypes -Wsign-compare"  ## FIXME: fix all sources: -Wsign-compare
  62         fi
  63 dnl Some Makefiles use additional tests etc.
  64 AM_CONDITIONAL(MAINTAINER_MODE,[test "$USE_MAINTAINER_MODE" = "yes"])
  65
  66
  67 AC_ARG_ENABLE(man-pages,
  68                 [  --enable-man-pages=no/yes/auto   pod2man(1) required for man pages (def.=yes)],,enable_man_pages=yes)
  69 AC_ARG_ENABLE(sbin-mountdir,
  70                 [  --enable-sbin-mountdir=DIR       mount(8) 'mount.captive' directory (def.=/sbin)],,
  71                 [ enable_sbin_mountdir="/sbin" ])
  72 AC_ARG_ENABLE(sbin-mount-fs,
  73                 [  --enable-sbin-mount-fs=FS1:FS2   sbin-mount pre-installed symlinks (def.=ntfs:fastfat:cdfs:ext2fsd)],,
  74                 [ enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd" ])
  75 AC_ARG_ENABLE(sandbox-setuid,
  76                 [  --enable-sandbox-setuid=USER     non-privileged user  for captive-sandbox-server (def.=captive)],
  77                 [ CAPTIVE_SANDBOX_SETUID="$enableval" ],[ CAPTIVE_SANDBOX_SETUID="captive" ])
  78 AC_ARG_ENABLE(sandbox-setgid,
  79                 [  --enable-sandbox-setgid=GROUP    non-privileged group for captive-sandbox-server (def.=captive)],
  80                 [ CAPTIVE_SANDBOX_SETGID="$enableval" ],[ CAPTIVE_SANDBOX_SETGID="captive" ])
  81 AC_ARG_ENABLE(sandbox-chroot,
  82                 [  --enable-sandbox-chroot=DIR      root-owned directory for captive-sandbox-server (def.=/var/lib/captive)],
  83                 [ CAPTIVE_SANDBOX_CHROOT="$enableval" ],[ CAPTIVE_SANDBOX_CHROOT="/var/lib/captive" ])
  84 AC_ARG_ENABLE(bug-replay,
  85                 [  --enable-bug-replay=no/yes/auto  compile debugging tool (def.=auto)],,enable_bug_replay=auto)
  86 AC_ARG_ENABLE(lufs,
  87                 [  --enable-lufs=no/yes/auto        compile LUFS filesystem module (def.=auto)],,enable_lufs=auto)
  88 AC_ARG_ENABLE(install-pkg,
  89                 [  --enable-install-pkg=no/yes/auto compile installation utils (def.=auto)],,enable_install_pkg=auto)
  90
  91
  92 # AC_ARG_ENABLE(sbin-mountdir,[--enable-sbin-mountdir=DIR],,[enable_sbin_mountdir="/sbin"])
  93 AM_CONDITIONAL(ENABLE_SBIN_MOUNT,[test "$enable_sbin_mount" != "no"])
  94 AC_SUBST(enable_sbin_mountdir)
  95
  96 # AC_ARG_ENABLE(sbin-mount-fs,[--enable-sbin-mount-fs=FS1:FS2],,[enable_sbin_mount_fs="ntfs:fastfat:cdfs:ext2fsd"])
  97 AC_SUBST(enable_sbin_mount_fs)
  98
  99 # AC_ARG_ENABLE(sandbox-setuid,[--enable-sandbox-setuid=USER],,[CAPTIVE_SANDBOX_SETUID="captive"])
 100 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETUID,"$CAPTIVE_SANDBOX_SETUID",
 101                 [non-privileged user  for captive-sandbox-server])
 102
 103 # AC_ARG_ENABLE(sandbox-setgid,[--enable-sandbox-setgid=GROUP],,[CAPTIVE_SANDBOX_SETGID="captive"])
 104 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_SETGID,"$CAPTIVE_SANDBOX_SETGID",
 105                 [non-privileged group for captive-sandbox-server])
 106
 107 # AC_ARG_ENABLE(sandbox-chroot,[--enable-sandbox-chroot=DIR],,[CAPTIVE_SANDBOX_CHROOT="/var/lib/captive"])
 108 AC_DEFINE_UNQUOTED(CAPTIVE_SANDBOX_CHROOT,"$CAPTIVE_SANDBOX_CHROOT",
 109                 [root-owned directory for captive-sandbox-server])
 110 AC_SUBST(CAPTIVE_SANDBOX_CHROOT)
 111
 112 dnl Permit 'if NEVER' for Makefile.am-s; symbol 'FALSE' forbidden by automake
 113 AM_CONDITIONAL(NEVER,false)
 114
 115 PERL=
 116 AC_PATH_PROGS(PERL,perl5 perl)
 117 if test '!' -f ./src/libcaptive/ke/exports.c -a -z "$PERL";then
 118         AC_MSG_ERROR([perl(1) required as './src/libcaptive/ke/exports.c' is not found.])
 119 fi
 120 AM_CONDITIONAL(HAVE_PERL,test -n "$PERL")
 121
 122 POD2MAN=
 123 AC_PATH_PROGS(POD2MAN,pod2man)
 124 AM_CONDITIONAL(HAVE_POD2MAN,[ test -n "$POD2MAN" ])
 125 if test x$enable_man_pages = xyes;then
 126         if test -z "$POD2MAN";then
 127                 AC_MSG_ERROR([captive requires pod2man(1) for man pages; try --disable-man-pages.])
 128         fi
 129         if test -z "$PERL";then
 130                 AC_MSG_ERROR([captive requires perl(1) for man pages; try --disable-man-pages.])
 131         fi
 132 elif test x$enable_man_pages != xno;then
 133         if test -z "$POD2MAN";then
 134                 AC_MSG_WARN([captive requires pod2man(1) for man pages by --enable-man-pages; mans will not be installed.])
 135         fi
 136         if test -z "$PERL";then
 137                 AC_MSG_WARN([captive requires perl(1) for man pages by --enable-man-pages; mans will not be installed.])
 138         fi
 139 fi
 140 AM_CONDITIONAL(ENABLE_MAN_PAGES,[ test x$enable_man_pages != xno -a -n "$POD2MAN" -a -n "$PERL" ])
 141
 142 dnl Separate 'acconfig.h' is no longer recommended by autoconf
 143 AH_TOP([
 144 #ifndef _CAPTIVE_CONFIG_H
 145 #define _CAPTIVE_CONFIG_H 1
 146 ])
 147 AH_BOTTOM([
 148 /* Do not place any stuff to AH_TOP as some of its includes
 149  * would discard the effect of _FILE_OFFSET_BITS by AC_SYS_LARGEFILE.
 150  */
 151
 152 #ifdef ENABLE_NLS
 153 /* <libintl.h> is taken from "$(top_srcdir)/intl" if system doesn't provide intl */
 154 #       include <libintl.h>
 155 #ifdef LIBCAPTIVE
 156 #       define _(String) dgettext (PACKAGE,String)
 157 #else
 158 #       define _(String) gettext (String)
 159 #endif /* LIBCAPTIVE */
 160 #       ifdef gettext_noop
 161 #               define N_(String) gettext_noop (String)
 162 #       else
 163 #               define N_(String) (String)
 164 #       endif
 165 #else /* !ENABLE_NLS */
 166 /* Stubs that do something close enough.  */
 167 #       define textdomain(String) (String)
 168 #       define gettext(String) (String)
 169 #       define dgettext(Domain,Message) (Message)
 170 #       define dcgettext(Domain,Message,Type) (Message)
 171 #       define bindtextdomain(Domain,Directory) (Domain)
 172 #       define _(String) (String)
 173 #       define N_(String) (String)
 174 #endif /* !ENABLE_NLS */
 175
 176 #include <glib/gtypes.h>        /* for 'gchar' */
 177 #define G_LOG_DOMAIN ((const gchar *)"Captive")
 178
 179 /* Ensure we have proper -I options: */
 180 #if defined(CAPTIVE_USE_GNOME_VFS_MODULE) || defined(CAPTIVE_USE_GNOME_VFS)
 181 #ifndef HAVE_GNOME_VFS_READ_ENTIRE_FILE
 182 #include <libgnomevfs/gnome-vfs-result.h>
 183 GnomeVFSResult gnome_vfs_read_entire_file(const char *uri,int *file_size,char **file_contents);
 184 #endif
 185 #endif
 186
 187 /* Supplemental definitions not possible in this file. */
 188 #ifdef LIBCAPTIVE
 189 #include "captive/config2.h"
 190 #endif
 191
 192 #endif /* !_CAPTIVE_CONFIG_H */
 193 ])
 194
 195 AM_PATH_GLIB_2_0(,,[AC_MSG_ERROR([Captive requires glib-2.0 library.])],[gmodule gobject])
 196 dnl Force glib for the whole package
 197 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 198 LIBS="$LIBS $GLIB_LIBS"
 199
 200 dnl popt
 201 AC_CHECK_LIB(popt,poptParseArgvString,[POPT_LIBS="-lpopt"],[AC_MSG_ERROR([Captive requires popt library.])])
 202 AC_SUBST(POPT_LIBS)
 203
 204 AC_ARG_WITH(readline,[  --with-readline=[no/yes/auto]   clients with line editing (def.=auto)],,with_readline=auto)
 205 AC_CHECK_HEADERS(readline/history.h)
 206 dnl Check for libraries, if needed by configuration options.
 207 if test "$with_readline" != "no"
 208 then
 209         if test -d "/usr/lib/termcap"
 210         then
 211                 READLINE_LDFLAGS="$READLINE_LDFLAGS -L/usr/lib/termcap"
 212         fi
 213         have_libreadline=false
 214         need_failed=""
 215         for need in "" termcap ncurses; do
 216                 if test "x$need" != "x"
 217                 then
 218                         captive_save_LIBS="$LIBS"
 219                         AC_CHECK_LIB($need,main,,
 220                                 [ need_failed="$need_failed $need"
 221                                 continue ]
 222                                 )
 223                         LIBS="$captive_save_LIBS"
 224                         lneed="-l$need"
 225                 else
 226                         lneed=""
 227                 fi
 228                 dnl Prevent AC_CHECK_LIB() here as it would _cache_ the value ignoring
 229                 dnl our ever-changing "additiona libraries" parameter
 230                 captive_save_LIBS="$LIBS"
 231                 LIBS="-lreadline $lneed $READLINE_LIBS"
 232                 AC_TRY_LINK(,[ main() ],
 233                         [ have_libreadline=true
 234                         READLINE_LIBS="$LIBS" ])
 235                 LIBS="$captive_save_LIBS"
 236                 if $have_libreadline
 237                 then
 238                         break
 239                 fi
 240         done
 241         if $have_libreadline
 242         then
 243                 AC_DEFINE(HAVE_LIBREADLINE,,[Use functions from libreadline?])
 244                 AC_CHECK_LIB(readline,add_history,
 245                         AC_DEFINE(HAVE_ADD_HISTORY,,[Use 'history' extension of libreadline?]),,
 246                         $READLINE_LIBS)
 247         else
 248                 for need in $need_failed; do
 249                         AC_MSG_WARN(captive recommends $need library as your readline library
 250                         probably needs it.)
 251                 done
 252                 if test "$with_readline" = "yes"
 253                 then
 254                         AC_MSG_ERROR([captive did not find the requested readline library for its client line editing capability.])
 255                 else
 256                         AC_MSG_WARN([captive recommends readline library for its client line editing capability.])
 257                 fi
 258         fi
 259 fi
 260 AC_SUBST(READLINE_LIBS)
 261 AC_SUBST(READLINE_LDFLAGS)
 262
 263 PKG_CHECK_MODULES(GNOME_VFS_MODULE,gnome-vfs-module-2.0)
 264 GNOME_VFS_MODULE_CFLAGS="$GNOME_VFS_MODULE_CFLAGS -DCAPTIVE_USE_GNOME_VFS_MODULE=1"
 265 AC_SUBST(GNOME_VFS_MODULE_CFLAGS)
 266 AC_SUBST(GNOME_VFS_MODULE_LIBS)
 267 PKG_CHECK_MODULES(GNOME_VFS,gnome-vfs-2.0)
 268 GNOME_VFS_CFLAGS="$GNOME_VFS_CFLAGS -DCAPTIVE_USE_GNOME_VFS=1"
 269 AC_SUBST(GNOME_VFS_CFLAGS)
 270 AC_SUBST(GNOME_VFS_LIBS)
 271
 272 # AC_ARG_ENABLE(bug-replay,[--enable-bug-replay=[no/yes/auto]],,enable_bug_replay=auto)
 273 dnl Check for 2.5.9 for: http://bugzilla.gnome.org/show_bug.cgi?id=117702
 274 dnl Check the version - impossible to reliably check the missing feature.
 275 PKG_CHECK_MODULES(LIBXML,libxml-2.0 >= 2.5.9,[ have_libxml_buffering=true ],[
 276         dnl Disable bug-replay(1) build if not met; --bug-pathname would be still OK.
 277         PKG_CHECK_MODULES(LIBXML,libxml-2.0,[ have_libxml_buffering=false ])
 278         ])
 279 dnl We also condition 'HAVE_LIBXML_XMLREADER_H' by 'HAVE_LIBXML_BUFFERING'
 280 dnl as we have no use for xmlreader without working libxml buffering of 2.5.9.
 281 AM_CONDITIONAL(ENABLE_BUG_REPLAY,[$have_libxml_buffering && test x$enable_bug_replay != xno])
 282 if $have_libxml_buffering;then
 283         AC_DEFINE(HAVE_LIBXML_BUFFERING,,[libxml2 correctly reads textnodes by its xmlTextReader.])
 284 else
 285         if test x$enable_bug_replay = xyes;then
 286                 AC_MSG_ERROR([captive require libxml2 at least 2.5.9 for --enable-bug-replay feature.])
 287         elif test x$enable_bug_replay != xno;then
 288                 AC_MSG_WARN([libxml2 at least 2.5.9 required --enable-bug-replay feature; disabled now.])
 289         fi
 290 fi
 291 AC_SUBST(LIBXML_CFLAGS)
 292 AC_SUBST(LIBXML_LIBS)
 293
 294 PKG_CHECK_MODULES(OPENSSL,openssl,,[
 295         dnl At least Debian-3.0r1 has openssl but without its .pc module.
 296         AC_CHECK_LIB(crypto,MD5,[
 297                 OPENSSL_CFLAGS=""
 298                 OPENSSL_LIBS="-lcrypto"
 299                 ],[AC_MSG_ERROR([Captive requires crypto library (of openssl).])])
 300         ])
 301 AC_SUBST(OPENSSL_CFLAGS)
 302 AC_SUBST(OPENSSL_LIBS)
 303
 304 # AC_ARG_ENABLE(lufs,[--enable-lufs=[no/yes/auto]],,enable_lufs=auto)
 305 have_lufs_includes=false
 306 PATH_LUFSMOUNT=""
 307 if test x$enable_lufs != no;then
 308         have_lufs_includes=true
 309         dnl If ACTION-IF-NOT-FOUND is given, it is executed when one of the header
 310         dnl files is not found.
 311         AC_CHECK_HEADERS(lufs/fs.h lufs/proto.h,,[ have_lufs_includes=false ])
 312         if test x$have_lufs_includes = xfalse;then
 313                 if test x$enable_lufs = xyes;then
 314                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 315                 else
 316                         AC_MSG_WARN([LUFS client not being compiled as no LUFS include files were found. Install 'lufs-*-*captive*' package.])
 317                 fi
 318         fi
 319         AC_CHECK_TYPES([struct lufs_sbattr],,[
 320                 dnl FIXME: Include 'lufs' version when 'lufs_sbattr' gets integrated:
 321                 if $have_lufs_includes && test x$enable_lufs = xyes;then
 322                         AC_MSG_ERROR([Although LUFS include files were found they are too old. You may also use --enable-lufs=auto.])
 323                 else
 324                         AC_MSG_WARN([Although LUFS include files were found they are too old. df(1) will not show available NTFS disk space.])
 325                 fi
 326                 ],[#include <lufs/proto.h>])
 327         AC_PATH_PROGS(PATH_LUFSMOUNT,lufsmount)
 328         if test x$PATH_LUFSMOUNT = x;then
 329                 if test x$enable_lufs = xyes;then
 330                         AC_MSG_ERROR([LUFS client was requested (--enable-lufs) but no lufsmount(1) binary was found. Install 'lufs-*-*captive*' package.])
 331                 else
 332                         AC_MSG_WARN([LUFS client not being compiled as no lufsmount(1) binary was found. Install 'lufs-*-*captive*' package.])
 333                 fi
 334         fi
 335 fi
 336 AM_CONDITIONAL(ENABLE_LUFS,[ $have_lufs_includes && test x$PATH_LUFSMOUNT != x -a x$enable_lufs != no ])
 337 AC_SUBST(PATH_LUFSMOUNT)
 338
 339 dnl for $(top_srcdir)/src/libcaptive/sandbox/split-sandbox.c
 340 AM_PATH_LINC(,,[AC_MSG_ERROR([Captive requires linc library used by ORBit.])])
 341
 342 dnl for $(top_srcdir)/src/libcaptive/client/
 343 dnl Do not use '[client server]' as $4 to prevent: configure: test: too many arguments
 344 dnl  - currently this argument is not used by 'orbit2-config' in any way anyway
 345 AM_PATH_ORBIT2(,,[AC_MSG_ERROR([Captive requires ORBit library.])])
 346
 347 # AC_ARG_ENABLE(install-pkg,[--enable-install-pkg=[no/yes/auto]],,enable_install_pkg=auto)
 348 GLADE_W_INIT([
 349         ./src/install/acquire/ui-gnome-interface.c
 350         ./src/install/acquire/ui-gnome-interface.h
 351         ./src/install/acquire/ui-gnome-callbacks.h
 352         ./src/install/acquire/ui-gnome-support.c
 353         ./src/install/acquire/ui-gnome-support.h
 354         ],[$enable_install_pkg],[
 355                 AC_CHECK_LIB(ntfs,ntfs_mount,[
 356                         LIBNTFS_LIBS="-lntfs"
 357
 358                         captive_save_CPPFLAGS="$CPPFLAGS"
 359                         CPPFLAGS="$CPPFLAGS $LIBXML_CFLAGS"
 360                         AC_CHECK_HEADERS(libxml/xmlreader.h,
 361                                 [ glade_addon=yes ],
 362                                 [ AC_MSG_WARN([Captive requires libxml >= 2.4.29 for --enable-install-pkg.]) ])
 363                         CPPFLAGS="$captive_save_CPPFLAGS"
 364                         ])
 365                 ])
 366 AC_SUBST(GNOMEUI_CFLAGS)
 367 AC_SUBST(GNOMEUI_LIBS)
 368 AC_SUBST(LIBNTFS_LIBS)
 369 dnl Do not: AM_CONDITIONAL(HAVE_LIBNTFS,[ test -n "$LIBNTFS_LIBS" ])
 370 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 371 AM_CONDITIONAL(HAVE_GLADE_WRITESOURCE,[ test "x$PATH_GLADE" != "x" ])
 372 dnl Do not: AM_CONDITIONAL(BUILD_GLADESRC,[ test "xyes" = "x$BUILD_GLADESRC" ])
 373 dnl as we do not need it as we are conditioned by ENABLE_INSTALL_PKG
 374 GNOME_ADDON_LIBS=""
 375 if test "x$BUILD_GLADESRC_TRUE" = "x"
 376 then
 377         AC_CHECK_LIB(Xi,XOpenDevice,GNOME_ADDON_LIBS="$GNOME_ADDON_LIBS -lXi")
 378 fi
 379 AC_SUBST(GNOME_ADDON_LIBS)
 380 dnl $BUILD_GLADESRC is already conditioned by $enable_install_pkg by GLADE_W_INIT()
 381 AM_CONDITIONAL(ENABLE_INSTALL_PKG,[ test "xyes" = "x$BUILD_GLADESRC" ])
 382
 383 dnl Do not use AC_REPLACE_FUNCS() as we need to link it selectively:
 384 GNOME_VFS_READ_ENTIRE_FILE_O=""
 385 captive_save_CFLAGS="$CFLAGS"
 386 captive_save_LIBS="$LIBS"
 387 CFLAGS="$CFLAGS $GNOME_VFS_MODULE_CFLAGS"
 388 LIBS="$LIBS $GNOME_VFS_MODULE_LIBS"
 389 AC_CHECK_FUNCS(gnome_vfs_read_entire_file,,
 390         [ GNOME_VFS_READ_ENTIRE_FILE_O='gnome_vfs_read_entire_file.$(OBJEXT)' ])
 391 CFLAGS="$captive_save_CFLAGS"
 392 LIBS="$captive_save_LIBS"
 393 AC_SUBST(GNOME_VFS_READ_ENTIRE_FILE_O)
 394
 395 AC_SUBST(CFLAGS)
 396 AC_SUBST(LIBS)
 397
 398 dnl "Makefile" output files MUST have pathnames incl./excl. "./" prefix as specified!
 399 dnl FIXME: Why the rule above was written here?
 400 AC_OUTPUT([
 401 captive.spec
 402 ./src/libcaptive/captive.pod.pl
 403 ./src/libcaptive/client/options.pod.pl
 404 ./src/client/cmdline/captive-cmdline.pod.pl
 405 ./src/client/lufs/lufs-captivefs.pod.pl
 406 ./src/client/lufs/mount.captive.pod.pl
 407 ./src/client/lufs/mount.captive
 408 ./src/client/sandbox-server/captive-sandbox-server.pod.pl
 409 ./src/install/fstab/captive-install-fstab.pod.pl
 410 ./src/install/acquire/captive-install-acquire.pod.pl
 411 ./src/client/gnomevfs/captive.conf
 412 ./po/Makefile.in
 413 ./macros/glade-w.sh
 414 ./debian/changelog
 415 Makefile
 416 ./macros/Makefile
 417 ./src/Makefile
 418 ./src/libcaptive/Makefile
 419 ./src/libcaptive/include/Makefile
 420 ./src/libcaptive/include/captive/Makefile
 421 ./src/libcaptive/include/reactos/Makefile
 422 ./src/libcaptive/include/reactos/ddk/Makefile
 423 ./src/libcaptive/include/reactos/ddk/i386/Makefile
 424 ./src/libcaptive/include/reactos/internal/Makefile
 425 ./src/libcaptive/include/reactos/internal/i386/Makefile
 426 ./src/libcaptive/include/reactos/napi/Makefile
 427 ./src/libcaptive/include/reactos/ntos/Makefile
 428 ./src/libcaptive/reactos/Makefile
 429 ./src/libcaptive/reactos/include/Makefile
 430 ./src/libcaptive/reactos/hal/Makefile
 431 ./src/libcaptive/reactos/hal/halx86/Makefile
 432 ./src/libcaptive/reactos/ntoskrnl/Makefile
 433 ./src/libcaptive/reactos/ntoskrnl/dbg/Makefile
 434 ./src/libcaptive/reactos/ntoskrnl/ex/Makefile
 435 ./src/libcaptive/reactos/ntoskrnl/fs/Makefile
 436 ./src/libcaptive/reactos/ntoskrnl/io/Makefile
 437 ./src/libcaptive/reactos/ntoskrnl/ke/Makefile
 438 ./src/libcaptive/reactos/ntoskrnl/ldr/Makefile
 439 ./src/libcaptive/reactos/ntoskrnl/mm/Makefile
 440 ./src/libcaptive/reactos/ntoskrnl/nt/Makefile
 441 ./src/libcaptive/reactos/ntoskrnl/ob/Makefile
 442 ./src/libcaptive/reactos/ntoskrnl/ps/Makefile
 443 ./src/libcaptive/reactos/ntoskrnl/rtl/Makefile
 444 ./src/libcaptive/reactos/ntoskrnl/rtl/i386/Makefile
 445 ./src/libcaptive/reactos/ntoskrnl/se/Makefile
 446 ./src/libcaptive/halcaptive/Makefile
 447 ./src/libcaptive/cc/Makefile
 448 ./src/libcaptive/cm/Makefile
 449 ./src/libcaptive/ex/Makefile
 450 ./src/libcaptive/fs/Makefile
 451 ./src/libcaptive/io/Makefile
 452 ./src/libcaptive/kd/Makefile
 453 ./src/libcaptive/ke/Makefile
 454 ./src/libcaptive/ldr/Makefile
 455 ./src/libcaptive/mm/Makefile
 456 ./src/libcaptive/nt/Makefile
 457 ./src/libcaptive/ob/Makefile
 458 ./src/libcaptive/po/Makefile
 459 ./src/libcaptive/ps/Makefile
 460 ./src/libcaptive/rtl/Makefile
 461 ./src/libcaptive/se/Makefile
 462 ./src/libcaptive/storage/Makefile
 463 ./src/libcaptive/sandbox/Makefile
 464 ./src/libcaptive/client/Makefile
 465 ./src/client/Makefile
 466 ./src/client/bug-replay/Makefile
 467 ./src/client/cmdline/Makefile
 468 ./src/client/gnomevfs/Makefile
 469 ./src/client/lufs/Makefile
 470 ./src/client/sandbox-server/Makefile
 471 ./src/install/Makefile
 472 ./src/install/libcaptive-install/Makefile
 473 ./src/install/fstab/Makefile
 474 ./src/install/acquire/Makefile
 475 ./src/TraceFS/Makefile
 476 ./src/w32-mod/Makefile
 477 ./doc/Makefile
 478 ./doc/apiref/Makefile
 479 ])
 480
 481 dnl FIXME: Why is "po/POTFILES" being substituted?
 482 make -C src distfiles DISTFILES_PRINT=1 \
 483                 |sed -n 's/^:DISTFILES: *\(.*\)$/\1/p'|tr ' ' '\n'|grep . >po/POTFILES.in
 484 make -C po Makefile
 485
 486 echo done.