src/client/lufs/mount.captive.in

   1 #! /usr/bin/perl -w
   2 #
   3 # $Id$
   4 # External mount command for mount(8) to interface lufsmount(1)
   5 # Copyright (C) 2003 Jan Kratochvil <project-captive@jankratochvil.net>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; exactly version 2 of June 1991 is required
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19
  20
  21 use strict;
  22 use Carp qw(cluck confess);
  23 use Getopt::Long;
  24 # Do not use any non-core Perl modules here.
  25 # Be perl-5.0 compatible (is it needed if we require Linux kernel >= 2.4 ?)
  26
  27
  28 my $vardir='@localstatedir@/lib/captive';
  29 $vardir=~s#\$\Q{prefix}\E#'@prefix@';#ge;
  30 $vardir="/var/lib/captive" if $vardir=~/^@/;
  31 my $lufsmount_bin='@bindir@/lufsmount';
  32 $lufsmount_bin=~s#\$\Q{exec_prefix}\E#'@exec_prefix@';#ge;
  33 $lufsmount_bin=~s#\$\Q{prefix}\E#'@prefix@';#ge;
  34 $lufsmount_bin="/usr/bin/lufsmount" if $lufsmount_bin=~/^@/;
  35 my $captive_sandbox_server_bin='@sbindir@/captive-sandbox-server';
  36 $captive_sandbox_server_bin=~s#\$\Q{exec_prefix}\E#'@exec_prefix@';#ge;
  37 $captive_sandbox_server_bin=~s#\$\Q{prefix}\E#'@prefix@';#ge;
  38 $captive_sandbox_server_bin="/usr/sbin/captive-sandbox-server" if $captive_sandbox_server_bin=~/^@/;
  39
  40
  41 my $ME=($0=~m#([^/]*)$#)[0] or die "Cannot detetect my basename from: $0";
  42 my $fsname=$ME;
  43 $fsname=~s/^mount[.]captive-// or die "Cannot detect captive filesystem module from my name: $fsname";
  44 my $image=shift @ARGV or die "Missing argv[1]: device or image pathname";
  45 -r $image or die "Image pathname not readable: $image";
  46 warn "warning: '-o loop' is not neccessary for Captive filesystem mounts"
  47                 if $image=~m#^/dev/loop#;
  48 my $dir=shift @ARGV or die "Missing argv[2]: mount point directory";
  49 -d $dir or die "Mount point directory not a valid directory: $dir";
  50 shift @ARGV if my $nomtab =$ARGV[0] && $ARGV[0] eq "-n";
  51 shift @ARGV if my $verbose=$ARGV[0] && $ARGV[0] eq "-v";
  52 my $oo="";
  53 do { shift @ARGV; $oo=shift @ARGV; } if $ARGV[0] && $ARGV[0] eq "-o";
  54 die "Excessive arguments: @ARGV" if @ARGV;
  55
  56 sub die_install
  57 {
  58         die
  59 "You should run captive-install-acquire(1) of 'captive-install' package,
  60 otherwise you can also acquire this file from URL:
  61 http://www.microsoft.com/WindowsXP/pro/downloads/servicepacks/sp1/checkedbuild.asp
  62 ";
  63 }
  64
  65 my $filesystem=$vardir."/".$fsname.".sys";
  66 if (!-r $filesystem) {
  67         warn "W32 filesystem .sys module not found: $filesystem";
  68         die_install();
  69         }
  70 my $ntoskrnl=$vardir."/ntoskrnl.exe";
  71 if (!-r $ntoskrnl) {
  72         warn "W32 ntoskrnl.exe not found: $ntoskrnl";
  73         die_install();
  74         }
  75
  76 # Shameless advertisement:
  77 if ($fsname eq "ntfs") {
  78         for my $fh (*STDERR,*STDOUT) {
  79                 if (-t $fh) {
  80                         print $fh 'Captive NTFS v@VERSION@.  Check new version: http://www.jankratochvil.net/'."\n";
  81                         last;
  82                         }
  83                 }
  84         }
  85
  86
  87 # Keep @opt_captive ordering
  88 # to let the options be overridable by user (such as 'ro').
  89 my @opt_captive=();
  90 my @opt_lufs=();
  91 my $opt_force;
  92 for (split /,/,$oo) {
  93         $_="--$_" if $_ eq "ro" || $_ eq "rw";
  94         $opt_force=1 if $_ eq "force";
  95         push @opt_captive,$_ if  /^--/;
  96         push @opt_lufs,$_    if !/^--/;
  97         }
  98
  99 if (!$opt_force) {
 100         local *MTAB;
 101         if (!open MTAB,"/etc/mtab") {
 102                 warn "Cannot open /etc/mtab: $!";
 103                 }
 104         else {
 105                 local $/=undef();
 106                 my $mtab=<MTAB>;
 107                 close MTAB;
 108                 die ""
 109                                                 ."$ME: $image already mounted\n"
 110                                                 ."$ME: according to mtab, $image is mounted on $1\n"
 111                                                 ."$ME: Use '-o force' to mount the image notwithstanding.\n"
 112                                 if $mtab=~/^\Q$image\E\s+(\S+)/m;
 113                 }
 114         }
 115
 116 $oo=""
 117                 ."mntent.mnt_fsname=$image,mntent.mnt_type=captive-$fsname,"    # Double-dashes forbidden.
 118                 ."dir_cache_entries=0,"
 119                 ."image=$image,"
 120                 .join(",",@opt_lufs).","
 121                 ."captive_options="
 122                                 .($fsname eq "cdfs" ? "--cdrom;--ro;" : "--disk;--rw;")
 123                                 ."--load-module=$ntoskrnl;--filesystem=$filesystem;"
 124                                 ."--sandbox-server=$captive_sandbox_server_bin;"
 125                                 ."--bug-pathname=$vardir/bug-%FT%T.captivebug.xml.gz;"
 126                                 ."--syslog;"
 127                                 .join(";",@opt_captive);
 128
 129 warn "$0: '-n' not supported - ignored" if $nomtab;
 130
 131 # Use "'$oo'" to permit another expansion by bash(1) during lufsmnt(8) execution.
 132 my @argv=($lufsmount_bin,"captivefs://",$dir,"-o","'$oo'");
 133
 134 print STDERR "$0: @argv\n" if $verbose;
 135 exec $lufsmount_bin @argv;
 136 die "Failed to execute: @argv";