kernel/Linux/prepmod.in

   1 #! /usr/bin/perl -w
   2 #
   3 # $Id$
   4 # Check and possibly rebuild lufs kernel module for the current kernel.
   5 # Copyright (C) 2003 Jan Kratochvil <project-captive@jankratochvil.net>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; exactly version 2 of June 1991 is required
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19
  20
  21 use strict;
  22 use Carp qw(cluck confess);
  23 use Getopt::Long;
  24 # Do not use any non-core Perl modules here.
  25 # Be perl-5.0 compatible (is it needed if we require Linux kernel >= 2.4 ?)
  26
  27
  28 my $basedir='@datadir@/lufs';
  29 my $vardir='@localstatedir@/lib/lufs';
  30 $basedir=~s#\$\Q{prefix}\E#'@prefix@';#ge;
  31 $vardir=~s#\$\Q{prefix}\E#'@prefix@';#ge;
  32 $vardir="" if $vardir=~/^@/;
  33 sub srcdir { my($uname_r)=@_; $basedir."/".($uname_r lt "2.5" ? "2.4" : "2.5"); }
  34 my $modbindir=$basedir."/modbin";
  35 my @sources=qw(proc.c inode.c dir.c file.c symlink.c);
  36 my $tmp_dir="prepmod-tmp-dir";
  37
  38 my $quiet;
  39 my $kernel;
  40 my $prebuild;
  41 my $kernel_gcc_args="";
  42
  43 my $lufsmnt_bin;
  44 if ($0 eq "lufsmnt" || $0=~m#/lufsmnt$#) {
  45         $quiet=1;
  46         $lufsmnt_bin='@bindir@/lufsmnt-bin';
  47         $lufsmnt_bin=~s#\$\Q{exec_prefix}\E#'@exec_prefix@';#ge;
  48         $lufsmnt_bin=~s#\$\Q{prefix}\E#'@prefix@';#ge;
  49         }
  50 else {
  51         die if !GetOptions(
  52                         "q|quiet",\$quiet,
  53                           "kernel",\$kernel,    # it must contain "include" subdir
  54                           "modbindir=s",\$modbindir,
  55                           "basedir=s",\$basedir,
  56                           "prebuild",\&prebuild,
  57                           "kernel-gcc-args=s",\$kernel_gcc_args,
  58                         );
  59         }
  60
  61
  62 sub _readfile
  63 {
  64 my($filename,$optional)=@_;
  65
  66         local $/=undef();
  67         local *F;
  68         open F,$filename or do { cluck "Open \"$filename\": $!" if !$optional; return ""; };
  69         my $r=<F>;
  70         close F or cluck "Close \"$filename\": $!";
  71         return $r;
  72 }
  73
  74 sub _system
  75 {
  76 my(@args)=@_;
  77
  78         print STDERR "+ ".join(" ",@args)."\n" if !$quiet;
  79         return system @args;
  80 }
  81
  82 sub _pass
  83 {
  84 my($load)=@_;
  85
  86         my $modproberc;
  87         if ($load) {
  88                 do { ($modproberc=_system $_) and cluck "$_ failed - ignoring"; } for ("depmod -aq","modprobe lufs");
  89                 }
  90         exit ($modproberc ? 1 : 0) if !$lufsmnt_bin;
  91         do { exec $lufsmnt_bin,@ARGV; };
  92         confess "Failed to exec '$lufsmnt_bin': $!";
  93 }
  94
  95
  96 my $filesystems=_readfile "/proc/filesystems";  # 'lufs' may be built-in
  97 _pass if $filesystems=~/\blufs$/m;
  98 my $modules=_readfile "/proc/modules";  # 'lufs' may be already loaded
  99 _pass if $modules=~/^lufs\b/m;
 100 _pass if !_system "modprobe lufs 2>/dev/null";
 101
 102 my $proc_version=_readfile "/proc/version";
 103 my $uname_r=($proc_version=~/^Linux version (\S+)/)[0] || _readfile "uname -r|";
 104 chomp $uname_r;
 105 confess "Failed to detect kernel version" if !$uname_r;
 106 my $uname_r_base=($uname_r=~/^([^-]+)/)[0];
 107 print STDERR "Running kernel version: $uname_r (base version $uname_r_base)\n" if !$quiet;
 108
 109 my $moduledir="/lib/modules/$uname_r/kernel/fs/lufs";
 110 print STDERR "Destination module directory: $moduledir\n" if !$quiet;
 111
 112 do { $kernel||=$_ if -d $_; } for ("/lib/modules/$uname_r/build");
 113 do { $kernel||=$_ if -d $_; } for ("/usr/src/kernel-headers-$uname_r");
 114 do { $kernel||=$_ if -d $_; } for ("/usr/src/linux-$uname_r");
 115 do { $kernel||=$_ if -d $_; } for ("/usr/src/linux-$uname_r_base");
 116 do { $kernel||=$_ if -d $_; } for ("/usr/src/linux");
 117 if (!$kernel) {
 118         print STDERR "Failed to find kernel headers for $uname_r\n" if !$kernel && !$quiet;
 119         }
 120 else {
 121         # We need /usr/include/lufs/* for standard package compilation.
 122         # There is no sense to make separate 'devel' package.
 123         for ("$vardir/lufs.o") {
 124                 next if !$vardir;
 125                 # Create the 'lufs.o' in our /var/lib directory and only link it
 126                 # to prevent using obsolete modules after upgrading 'lufs' package.
 127                 # depmod(1) will take the larget symlink name - we must create directory for  it.
 128                 if (build($kernel,$uname_r,$_)) {
 129                         do { cluck "Failed to symlink $_"; next; }
 130                                         if _system "rm -rf $moduledir; mkdir -p $moduledir; ln -s $_ $moduledir/lufs.o";
 131                         _pass 1;
 132                         }
 133                 }
 134         }
 135
 136 local $_;
 137 for (<$modbindir/*-$uname_r/*.o>,<$modbindir/*-${uname_r_base}/*.o>,<$modbindir/*/*.o>) {
 138         next if _system "rmmod lufs 2>/dev/null; insmod -o lufs -p $_ 2>/dev/null";
 139         do { cluck "Failed to symlink $_"; next; } if _system "rm -rf $moduledir; mkdir -p $moduledir; ln -s $_ $moduledir/lufs.o";
 140         _pass 1;
 141         }
 142 confess "lufs module not loaded: Try running $basedir/prepmod to see more.";
 143
 144
 145 sub build
 146 {
 147 my($kernel,$uname_r,$destmodule)=@_;
 148
 149         print STDERR "Using kernel sources: $kernel\n" if !$quiet;
 150         confess "Kernel sources $kernel do not contain 'include' subdirectory" if ! -d $kernel."/include";
 151
 152         my $kdebug="";
 153         do { $kdebug=$_ if !/^@/; } for ('@KDEBUG_FLAGS@');
 154         my $cmdline="gcc"
 155                         .($quiet ? " 2>/dev/null" : "")
 156                         ." -O2 -pipe -fomit-frame-pointer -fno-strict-aliasing -mpreferred-stack-boundary=2 -Wall"
 157                         ." -D__KERNEL__ -DMODULE -DLINUX -DKBUILD_MODNAME=lufs"
 158                         ." ".$kdebug
 159                         ." ".$kernel_gcc_args
 160                         ." -I$kernel/include"
 161                         ." -I$kernel/include/asm-i386/mach-default";    # gcc should not care if this 2.5 dir does not exist
 162
 163         my $config=_readfile "$kernel/.config","optional";
 164         my $autoconf=_readfile "$kernel/include/linux/autoconf.h","optional";
 165         $cmdline.=" -DMODVERSIONS -include $kernel/include/linux/modversions.h"
 166                         if 0
 167                                         || $config=~/^CONFIG_MODVERSIONS=y\b/m
 168                                         || $autoconf=~/^#define CONFIG_MODVERSIONS\b/m
 169                                         || (!$config && !$autoconf);    # assume modversions if not known
 170
 171         my @objects=map({ my $o=$_; $o=~s/[.]c$/.o/; $o; } @sources);
 172         return !_system "set -e; mkdir -p `dirname $destmodule`; rm -f $destmodule;"
 173                         .(!$vardir ? "" : " cd $vardir;")
 174                         ." $cmdline -c ".join(" ",map({ srcdir($uname_r)."/".$_; } @sources)).";"
 175                         ." ld -r -o $destmodule ".join(" ",@objects).";"
 176                         ." rm -f ".join(" ",@objects);
 177 }
 178
 179
 180 sub prebuild_kernel
 181 {
 182 my($dir,$vendor,$uname_r)=@_;
 183
 184         confess "Unrecognized vendor for dir: $dir" if !$vendor;
 185         confess "Unrecognized uname_r for dir: $dir" if !$uname_r;
 186         confess "Failed to build $dir" if !build $dir,$uname_r,$modbindir."/lufs-$vendor-$uname_r.o";
 187 }
 188
 189
 190 sub prebuild_rpm
 191 {
 192 my($rpm)=@_;
 193
 194         my $vendor=_readfile "rpm 2>/dev/null --qf '%{VENDOR}' -qp '$rpm' |";
 195         $vendor=~s/,.*//;
 196         $vendor=~tr/ //d;
 197         my $uname_r;
 198         $uname_r||=($rpm=~m#/kernel-source-([^-]+-[^-]+)[.][^.]+[.]rpm$#)[0];
 199         my $uname_r_base=($uname_r=~/^([^-]+)/)[0];
 200         _system "rm -rf $tmp_dir; mkdir $tmp_dir; set -e;"
 201                         # Here we will extract even some false 'include's but we filter dirs just for speed/space.
 202                         ." rpm2cpio '$rpm' | (cd $tmp_dir; cpio -id --quiet ./usr/src/linux*/{.config,include/*})"
 203                         and confess "Extraction of: $rpm";
 204         my $dir;
 205         do { $dir||=$_ if -d $_; } for ($tmp_dir."/usr/src/linux-$uname_r");
 206         do { $dir||=$_ if -d $_; } for ($tmp_dir."/usr/src/linux-$uname_r_base");       # older RedHat kernels
 207         $dir or confess "Kernel source tree not found in: $rpm";
 208         prebuild_kernel $dir,$vendor,$uname_r;
 209         _system "rm -rf $tmp_dir" and confess "Deletion of: $tmp_dir";
 210 }
 211
 212 sub prebuild_dir
 213 {
 214 my($dir)=@_;
 215
 216         my $vendor;
 217         chomp (my $debian=_readfile "/etc/debian_version","optional");
 218         $vendor="Debian".$debian if $debian && $dir=~m#^/usr/src/#;
 219         my $uname_r;
 220         $uname_r||=($dir=~m#/kernel-headers-([^/]+)/*$#)[0];
 221         $uname_r||=($dir=~m#/linux-([^/]+)/*$#)[0];
 222         $uname_r||=($dir=~m#^/lib/modules/([^/]+)/build/*$#)[0];
 223         prebuild_kernel $dir,$vendor,$uname_r;
 224 }
 225
 226 sub prebuild
 227 {
 228         $vardir=undef();        # we may not yet have /var/lib/lufs
 229         for (@ARGV) {
 230                 do { prebuild_rpm $_; next; } if /[.]rpm$/;
 231                 do { prebuild_dir $_; next; } if -d $_;
 232                 confess "Unrecognized kernel: $_";
 233                 }
 234         exit 0;
 235 }