Web.pm

   1 # $Id$
   2 # Common functions for HTML/XHTML output generation
   3 # Copyright (C) 2003 Jan Kratochvil <project-www.jankratochvil.net@jankratochvil.net>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; exactly version 2 of June 1991 is required
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18
  19 package My::Web;
  20 require 5.6.0;  # at least 'use warnings;' but we need some 5.6.0+ modules anyway
  21 our $VERSION=do { my @r=(q$Revision$=~/\d+/g); sprintf "%d.".("%03d"x$#r),@r; };
  22 our $CVS_ID=q$Id$;
  23 use strict;
  24 use warnings;
  25
  26 use Exporter;
  27 our @EXPORT=qw(&require &a_href &a_href_cz &vskip &img $W &top_dir);
  28 our @ISA=qw(Exporter);
  29
  30 use WebConfig;  # for %WebConfig
  31 require CGI;    # for &escapeHTML
  32 require Image::Size;    # for &imgsize
  33 use File::Basename;     # &basename
  34 use Carp qw(cluck confess);
  35 use URI::Escape;
  36 require HTTP::BrowserDetect;
  37 require HTTP::Negotiate;
  38 require Geo::IP;
  39 require CGI;
  40
  41
  42 # Undo 'www/engine/httpd-restart' as it may use obsolete Perl for 'mod_perl'
  43 delete $ENV{"PERLLIB"};
  44 delete $ENV{"LD_LIBRARY_PATH"};
  45
  46
  47 our $W;
  48                 # $W->{"title"}
  49                 # $W->{"head"}
  50                 # $W->{"head_css"}
  51                 # $W->{"force_charset"}
  52                 # %{$W->{"packages_used"}
  53                 # $W->{"heading_done"}
  54                 # $W->{"footer_passed"}
  55                 # %{$W->{"headers"}}
  56                 # %{$W->{"headers_lc"}} # maps lc($headers_key)=>$headers_key
  57                 # @{$W->{"packages_used"}{$Apache::Registry::curstash}}}
  58                 # %{$W->{"args"}}
  59
  60 sub init ($%)
  61 {
  62 my($class,%args)=@_;
  63
  64         $W={ %WebConfig,%args };        # override %WebConfig settings
  65
  66         $W->{"__PACKAGE__"}||="Apache::ROOT".$Apache::Registry::curstash;
  67
  68         $W->{"top_dir"}||=eval '$'.$W->{"__PACKAGE__"}.'::top_dir';
  69
  70         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_ent");
  71         do { $W->{$_}=0  if !defined $W->{$_}; } for ("detect_js");
  72         do { $W->{$_}=1  if !defined $W->{$_}; } for ("have_css");      # AFAIK it does not hurt anyone.
  73         do { $W->{$_}=1  if !defined $W->{$_}; } for ("heading");
  74         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer");
  75         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_delimit");
  76         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_mailme");
  77         do { $W->{$_}=1  if !defined $W->{$_}; } for ("footer_ids");
  78         do { $W->{$_}=1  if !defined $W->{$_}; } for ("indexme");
  79         do { $W->{$_}="" if !defined $W->{$_}; } for ("head");
  80         do { $W->{$_}="" if !defined $W->{$_}; } for ("head_css");
  81
  82         my $footer_any=0;
  83         for (qw(footer_mailme footer_ids)) {
  84                 $W->{$_}=0 if !$W->{"footer"};
  85                 $footer_any=1 if $W->{$_};
  86                 }
  87         $W->{"footer"}=0 if !$footer_any;
  88         $W->{"footer_delimit"}=0 if !$W->{"footer"};
  89
  90         $W->{"r"}=Apache->request();
  91
  92         $W->{"QUERY_STRING"}=$W->{"r"}->args() || "";
  93            if ($W->{"QUERY_STRING"}=~/[&]amp;have_ent/)
  94                 { $W->{"have_ent"}=0; }
  95         elsif ($W->{"QUERY_STRING"}=~    /[&]have_ent/)
  96                 { $W->{"have_ent"}=1; }
  97         else
  98                 { delete $W->{"have_ent"}; }
  99         if ($W->{"detect_ent"} && !defined $W->{"have_ent"} && $W->{"r"}->method() eq "GET") {
 100                 $W->{"head"}.='<meta http-equiv="Refresh" content="0; URL='
 101                                 .CGI::escapeHTML("http://".$W->{"r"}->hostname()."/".($W->{"r"}->uri()=~m#^/*(.*)$#)[0]
 102                                                 ."?".($W->{"QUERY_STRING"} || "detect_ent_glue=1").'&have_ent=detect')
 103                                 .'" />'."\n";
 104                 }
 105         $W->{"QUERY_STRING"}=~s/([&])amp;/$1/g;
 106         $W->{"r"}->args($W->{"QUERY_STRING"});
 107         $ENV{"QUERY_STRING"}=$W->{"QUERY_STRING"};
 108         # Do not: $W->{"r"}->args()
 109         # as it  parses only QUERY_STRING (not POST data).
 110         $W->{"args"}={ CGI->new()->Vars() };
 111
 112         do { $W->{$_}=$ENV{"HTTP_ACCEPT"} if !defined $W->{$_}; } for ("accept");
 113         do { $W->{$_}=$ENV{"HTTP_USER_AGENT"} if !defined $W->{$_}; } for ("user_agent");
 114
 115         $W->{"browser"}=HTTP::BrowserDetect->new($W->{"user_agent"});
 116
 117         if (!defined $W->{"have_style"}) {
 118                 $W->{"have_style"}=(!$W->{"browser"}->netscape() || $W->{"browser"}->major>4 ? 1 : 0);
 119                 }
 120
 121         $W->{"have_js"}=($W->{"args"}{"have_js"} ? 1 : 0);
 122         if ($W->{"detect_js"} && !$W->{"have_js"}) {
 123                 $W->{"head"}.='<script type="text/javascript" src="'.top_dir().'/have_js.js.pl"></script>'."\n";
 124                 }
 125
 126         do { args_check(%$_) if $_; } for ($W->{"args_check"});
 127
 128         return $W;
 129 }
 130
 131 sub top_dir ()
 132 {
 133         do { return $_ if $_; } for ($W->{"top_dir"});
 134         return $INC[0]; # fallback
 135 }
 136
 137 sub require ($)
 138 {
 139 my($file)=@_;
 140
 141         $file=~s#/#::#g;
 142         $file=~s/[.]pm$//;
 143         my $class=$file;
 144         $file=~s#::#/#g;
 145         $file.=".pm";
 146         my $aref=($W->{"packages_used"}{$Apache::Registry::curstash}||=[]);
 147         push @$aref,$class
 148                         if !{ map(($_=>1),@$aref) }->{$class};  # Prevent duplicated entries.
 149         CORE::require $file;
 150         1;      # Otherwise 'require' would already file above.
 151 }
 152
 153 sub fatal (;$);
 154
 155 sub args_check (%)
 156 {
 157 my(%tmpl)=@_;
 158
 159         while (my($name,$regex)=each(%tmpl)) {
 160                 my $name_html="Parametr <span class=\"quote\">".CGI::escapeHTML($name)."</span>";
 161                 my $val=$W->{"args"}{$name};
 162                 fatal "$name_html <span class=\"quote\">".CGI::escapeHTML($val)."</span>"
 163                                                 ." does not match required regex <span class=\"quote\">".CGI::escapeHTML($regex)."</span>"
 164                                 if defined $val && $val!~/$regex/;
 165                 fatal "$name_html is required"
 166                                 if !defined $val;
 167                 }
 168 }
 169
 170 sub vskip (;$)
 171 {
 172 my($height)=@_;
 173
 174         return '<p'.(!defined $height ? "" : ' style="height: '.$height.';"').'>&nbsp;</p>'."\n";
 175 }
 176
 177 sub fatal (;$)
 178 {
 179 my($msg)=@_;
 180
 181         $msg="UNKNOWN" if !$msg;
 182
 183 #       heading(false/*title*/,false/*indexme*/);       # notitle is always safe, don't index the error message
 184         print "\n".vskip("3ex")."<hr /><h1 class=\"error\">FATAL ERROR: $msg!</h1>\n"
 185                         ."<p>You can report this problem's details to"
 186                         ." ".a_href("mailto:".$W->{"admin_mail"},"admin of this website").".</p>\n";
 187         footer();
 188 }
 189
 190 sub footer (;$)
 191 {
 192         exit 1 if $W->{"footer_passed"}++;      # deadlock prevention:
 193
 194         print vskip if $W->{"footer_delimit"};
 195
 196         print "<hr />\n" if $W->{"footer"};
 197
 198         if ($W->{"footer_mailme"}) {
 199                 print '<form action="'.top_dir().'/SendMsg.pl" method="post" onsubmit="'
 200                                 ."this.elements['msgscript'].value=this.elements['msghtml'].value;"
 201                                 ."this.elements['msghtml'].value='';"
 202                                 ."this.submit();"
 203                                 .'">'."\n";
 204                         print '<p align="right">'."\n";
 205                                 print '<input name="msgscript" type="hidden" />'."\n";
 206                                 print '<input name="msghtml" type="text" size="32" alt="Message" />'."\n";
 207                                 print '<input name="submit" type="submit" value="Quick Note" />'."\n";
 208                         print '</p>'."\n";
 209                 print '</form>'."\n";
 210                 }
 211
 212         if ($W->{"footer_ids"}) {
 213                 print '<p class="cvs-id">';
 214                 print join("<br />\n",map({ my $package=$_;
 215                         my $cvs_id=(eval('$'.$package."::CVS_ID")
 216 #                                       || $package     # debug
 217                                         );
 218                         if (!$cvs_id) {
 219                                 ();
 220                                 }
 221                         else {
 222                                 $cvs_id='$'.$cvs_id.'$';        # Eaten by 'q' operator.
 223                                 my @cvs_id_split=split / +/,$cvs_id;
 224                                 if (@cvs_id_split==8) {
 225                                         my $file=$package;
 226                                         $file=~s#::#/#g;
 227                                         my $ext;
 228                                         for (qw(.html.pl .pl .pm),"") {
 229                                                 $ext=$_;
 230                                                 last if -r top_dir()."/$file$ext";
 231                                                 cluck "Class file $file not found" if !$ext;
 232                                                 }
 233                                         $file.=$ext;
 234                                         $cvs_id_split[2]=""
 235                                                         .a_href((map({ my $s=$_; $s=~s#/viewcvs/#$&~checkout~/#; $s; } $W->{"viewcvs"}))[0]."$file?rev=".$cvs_id_split[2],
 236                                                                         $cvs_id_split[2]);
 237                                         $cvs_id_split[1]=a_href($W->{"viewcvs"}.$file,
 238                                                         ($package!~/^Apache::/ ? $package : $cvs_id_split[1]));
 239                                         $cvs_id_split[5]=&{$W->{"cvs_id_author"}}($cvs_id_split[5]);
 240                                         }
 241                                 join " ",@cvs_id_split;
 242                                 }
 243                         } (
 244                                         $W->{"__PACKAGE__"},
 245                                         __PACKAGE__,
 246                                         "WebConfig",
 247                                         @{$W->{"packages_used"}{$Apache::Registry::curstash}},
 248                                         )));
 249                 print "</p>\n";
 250                 }
 251
 252         if ($W->{"heading"}) {
 253                 do { &{$_}() if $_; } for ($W->{"footing"});
 254                 }
 255
 256         print "</body></html>\n";
 257         exit(0);
 258 }
 259
 260 sub header (%)
 261 {
 262 my(%pairs)=@_;
 263
 264         while (my($key,$val)=each(%pairs)) {
 265                 do { cluck "Headers already sent"; next; } if $W->{"heading_done"};
 266                 for ($W->{"headers_lc"}{lc $key} || ()) {
 267                         delete $W->{"headers"}{$_};
 268                         }
 269                 $W->{"headers_lc"}{lc $key}=$key;
 270                 $W->{"headers"}{$key}=$val;
 271                 }
 272 }
 273
 274 sub size_display ($)
 275 {
 276 my($size)=@_;
 277
 278            if ($size<4096)
 279                 {}
 280         elsif ($size<1024*1024)
 281                 { $size=sprintf "%.1fK",$size/1024; }
 282         else
 283                 { $size=sprintf "%.1fM",$size/1024/1024; }
 284         $size.="B";
 285         return $size;
 286 }
 287
 288 sub url_is_local ($)
 289 {
 290 my($url)=@_;
 291
 292         return $url!~m#^[a-z]+://#;
 293 }
 294
 295 sub a_href ($;$%)
 296 {
 297 my($url,$contents,%args)=@_;
 298
 299         do { $$_=1 if !defined $$_; } for (\$args{"size"});
 300         $contents=CGI::escapeHTML($url) if !defined $contents;
 301
 302         my $r='<a href="';
 303         my $urlent=CGI::escapeHTML($url);
 304            if ($url eq $urlent)
 305                 { $r.=$url; }
 306         elsif (url_is_local $url)
 307                 { $r.=$urlent; }
 308         elsif (defined $W->{"have_ent"} && !$W->{"have_ent"})   # non-ent client
 309                 { $r.=$url; }
 310         elsif ($W->{"have_ent"})        # ent client
 311                 { $r.=$urlent; }
 312         else    # unknown client, &CGI::escapeHTML should not be needed here
 313                 { $r.=CGI::escapeHTML(top_dir()."/Redirect.pl?location=".uri_escape($url)); }
 314         $r.='">'.$contents.'</a>';
 315         if ($args{"size"} && url_is_local($url) && $url=~/[.](?:gz|Z|rpm|zip|deb|lha)/) {       # Downloadable?
 316                 if (!-r $url)
 317                         { cluck "File not readable: $url"; }
 318                 else {
 319                         $r.='&nbsp;('.size_display((stat($url))[7]).')';
 320                         }
 321                 }
 322         return $r;
 323 }
 324
 325 sub remote_ip ()
 326 {
 327         # Do not: PerlModule                 Apache::ForwardedFor
 328         #         PerlPostReadRequestHandler Apache::ForwardedFor
 329         # As 'Apache::ForwardedFor' takes the first of $ENV{"HTTP_X_FORWARDED_FOR"}
 330         # while the contents is '127.0.0.1, 213.220.195.171' if client has its own proxy.
 331         # We must take the last item ourselves.
 332         my $r=$ENV{"HTTP_X_FORWARDED_FOR"} || $W->{"r"}->get_remote_host();
 333         $r=~s/^.*,\s*//;
 334         return $r;
 335 }
 336
 337 sub is_cz ()
 338 {
 339         return "CZ" eq Geo::IP->new()->country_code_by_addr(remote_ip());
 340 }
 341
 342 sub a_href_cz ($$;%)
 343 {
 344 my($url,$contents,%args)=@_;
 345
 346         return a_href $url,$contents,%args if is_cz();
 347         return $contents;
 348 }
 349
 350 sub img_size ($$)
 351 {
 352 my($width,$height)=@_;
 353
 354         return ($W->{"have_style"} ? "style=\"border:0;width:${width}px;height:${height}px\"" : "border=\"0\"")
 355                         ." width=\"$width\" height=\"$height\"";
 356 }
 357
 358 sub negotiate_variant (%)
 359 {
 360 my(%args)=@_;
 361
 362         my @fields=("id","qs","content-type","encoding","charset","lang","size");
 363         return [ map(($args{$_}),@fields) ];
 364 }
 365
 366 my @img_variants=(
 367                 { "id"=>"png","qs"=>1.0,"content-type"=>"image/png" },
 368                 { "id"=>"gif","qs"=>0.9,"content-type"=>"image/gif" },
 369                 );
 370 my $img_variants_re='[.](?:'.join('|',map(($_->{"id"}),@img_variants)).')$';
 371
 372 sub img_src ($)
 373 {
 374 my($file_base)=@_;
 375
 376         return $file_base if !url_is_local($file_base)
 377                         # Known image extension?
 378                         || $file_base=~m#$img_variants_re#o;
 379
 380         my @nego_variants;
 381         for my $var (@img_variants) {
 382                 my $file=$file_base.".".$var->{"id"};
 383                 # TODO: Somehow quickly check dependencies?
 384                 system 'make >&2 -s --no-print-directory'
 385                                                 .' -C '."'".File::Basename::dirname($file)."' '".File::Basename::basename($file)."'"
 386                                 if !-f $file;
 387                 push @nego_variants,negotiate_variant(
 388                                 %$var,
 389                                 "size"=>(stat $file)[7],
 390                                 );
 391                 }
 392         # Do not: ,$W->{"r"});
 393         # but should we provide somehow either 'HTTP::Headers' or 'HTTP::Request' ?
 394         my $ext=HTTP::Negotiate::choose(\@nego_variants);
 395         $ext||=$img_variants[0]->{"id"};        # &HTTP::Negotiate::choose failed?
 396         return $file_base.".".$ext;
 397 }
 398
 399 sub img ($$;$)
 400 {
 401 my($file_base,$alt,$attrs)=@_;
 402
 403         my $file=img_src $file_base;
 404         my($width,$height)=Image::Size::imgsize($file);
 405         $alt=CGI::escapeHTML($alt);
 406         return "<img src=\"$file\" alt=\"$alt\" title=\"$alt\" ".img_size($width,$height)
 407                         .(!$attrs ? "" : " ".$attrs)." />";
 408 }
 409
 410 sub readfile ($$)
 411 {
 412 my($class,$filename)=@_;
 413
 414         local *F;
 415         open F,$filename or die "Cannot open \"$filename\": $!";
 416         local $/=undef();
 417         my $data=<F>;
 418         close F;
 419         return $data;
 420 }
 421
 422 sub arr_keys (@)
 423 {
 424 my(@arr)=@_;
 425
 426         my @r=();
 427         while (@arr) {
 428                 push @r,shift @arr;     # key
 429                 shift @arr;     # val
 430                 }
 431         return @r;
 432 }
 433
 434 sub heading ()
 435 {
 436 my($class)=@_;
 437
 438         # $ENV{"CLIENT_CHARSET"} ignored (mod_czech support dropped!)
 439         my $client_charset=$W->{"force_charset"} || "us-ascii";
 440         header("Content-Style-Type"=>"text/css");
 441         header("Content-Script-Type"=>"text/javascript");
 442
 443         while (my($key,$val)=each(%{$W->{"headers"}})) {
 444                 $W->{"r"}->header_out($key,$val);
 445                 }
 446         $W->{"r"}->send_http_header("text/html; charset=$client_charset");      # "Content-type"; do not use header()
 447
 448         return if $W->{"heading_done"}++;
 449         exit if $W->{"r"}->header_only();
 450
 451         if (1) { # || !$msie_major || $msie_major>=4) # TODO:dyn
 452                 print '<?xml version="1.0" encoding="'.$client_charset.'"?>'."\n";
 453                 }
 454         print '<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN" "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">'."\n";
 455         print '<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US">'."\n";
 456         print '<head><title>'.CGI::escapeHTML($W->{"title_prefix"})
 457                         .join("",map({ ': '.CGI::escapeHTML($_); } ($W->{"title"} || ())))
 458                         .'</title>'."\n";
 459
 460         if ($W->{"have_css"}) {
 461                 print <<'HERE';
 462 <style type="text/css"><!--
 463 .cvs-id   { font-family: monospace; }
 464 .error    { color: red;   background-color: transparent; }
 465 .quote    { font-family: monospace; }
 466 .nowrap   { white-space: nowrap; }
 467 .centered { text-align: center; }
 468 .tab-bold { font-weight: bold; }
 469 .tab-head { font-weight: bold; color: yellow; background-color: transparent; }
 470 body {
 471                 background-color: black;
 472                 color: white;
 473                 }
 474 :link    { color: aqua;   background-color: transparent; }
 475 :visited { color: teal;   background-color: transparent; }
 476 h1,h2    { color: yellow; background-color: transparent; }
 477 td       { padding: 2px; }
 478 caption  { caption-side: bottom; }
 479 .footer img { vertical-align: middle; }
 480 HERE
 481                 print $W->{"head_css"}."\n";
 482                 print "--></style>\n";
 483                 }
 484
 485         print '<meta name="robots" content="'.($W->{"indexme"} ? "" : "no" ).'index,follow" />'."\n";
 486         print $W->{"head"};
 487         print "</head><body";
 488         print ' bgcolor="black" text="white" link="aqua" vlink="teal"'
 489                         if $W->{"browser"}->netscape() && $W->{"browser"}->major<=4;
 490         print ">\n";
 491
 492         if ($W->{"heading"}) {
 493                 do { &{$_}() if $_; } for ($W->{"heading"});
 494                 }
 495 }
 496
 497 1;